Wolfram言語＆システムドキュメントセンター

CreateDataSystemModel

CreateDataSystemModel[{v₁,v₂,…}]

値 v_iの信号を生成するSystemModelを作る．

CreateDataSystemModel[{{t₁,v₁},…}]

時間と値のペア {t_i,v_i}のモデルを作る．

CreateDataSystemModel[obj]

TimeSeriesあるいはInterpolatingFunction obj のモデルを作る．

CreateDataSystemModel[fun,tmin,tmax]

関数 fun の tmin から tmax までのサンプルでモデルを作る．

CreateDataSystemModel[data,"dspec"]

データ指定"dspec"でモデルを作る．

CreateDataSystemModel

CreateDataSystemModel[{v₁,v₂,…}]

値 v_iの信号を生成するSystemModelを作る．

CreateDataSystemModel[{{t₁,v₁},…}]

時間と値のペア {t_i,v_i}のモデルを作る．

CreateDataSystemModel[obj]

TimeSeriesあるいはInterpolatingFunction obj のモデルを作る．

CreateDataSystemModel[fun,tmin,tmax]

関数 fun の tmin から tmax までのサンプルでモデルを作る．

CreateDataSystemModel[data,"dspec"]

データ指定"dspec"でモデルを作る．

詳細とオプション

CreateDataSystemModelは，主に他のモデルに対する柔軟な入力として使われる補間曲線を作る．
CreateDataSystemModelは他のモデルに接続可能なSystemModel[…]オブジェクトを返す．
CreateDataSystemModel["NewModel",…]は，作成されたモデルに"NewModel"という名前を与える．
CreateDataSystemModel["PackageA.NewModel",…]は"NewModel"を"PackageA"に挿入する．
次は，使用可能なオプションである．

InterpolationOrder	Automatic	補間次数
SamplingPeriod	Automatic	サンプル間の時間
GeneratedAssetLocation	None	データファイルの場所

入力によるInterpolationOrderのデフォルト値
{v₁,v₂,…},{{t₁,v₁},…} 1

TimeSeries, InterpolatingFunction 保存された値

fun 3
値 v_iのリストについてのSamplingPeriodのデフォルトは1である．
TimeSeriesとInterpolatingFunctionのサンプル点は保存される．
次は，"dspec"の可能な値である．
"Time" 時間の列と値の列

"1D" 引数の列と値の列

"2D" 引数の行と列と値の行列
対応するデータ配列は以下のレイアウトを持つ．

デフォルトの"dspec"は"Time"である．

例題

すべて開くすべて閉じる

例 (3)

時間と値のペアのリストからモデルを作る：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: model = CreateDataSystemModel[data]

データモデルのシミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10]

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

TimeSeriesからモデルを作る：

Wolfram Language code: ts = TimeSeries[{{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}}]

Wolfram Language code: model = CreateDataSystemModel[ts];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

0秒から10秒までで関数のサンプルを取ってデータのモデルを作る：

Wolfram Language code: model = CreateDataSystemModel[Sin, 0, 10];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

スコープ (18)

値のリスト (4)

値のリストからデータのモデルを作る：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};

Wolfram Language code: model = CreateDataSystemModel[data];

サンプル区間は1秒であると仮定される：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

カスタムのサンプル周期を指定する：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};

Wolfram Language code: model = CreateDataSystemModel[data, SamplingPeriod -> 0.1];

シミュレーションを1秒間行い，プロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 1];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

カスタムのInterpolationOrderを使う：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

SparseArrayは，対応するNormal配列であると解釈される：

Wolfram Language code: s = SparseArray[{{1} -> 1, {2} -> 3, {5} -> 2, {7} -> 1}];

Wolfram Language code: model = CreateDataSystemModel[s];

サンプル区間は1秒であると仮定される：

Wolfram Language code: sim = SystemModelSimulate[model, 7];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

時間と値のペア (3)

時間と値のペアのリストからモデルを作る：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: model = CreateDataSystemModel[data];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

カスタムのInterpolationOrderを使う：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

各時点について複数の値があるデータを作る：

Wolfram Language code:

data = {{0, 8, 4}, {1, 5, 2}, {2, 9, 6}, {3, 10, 2}, {4, 4, 1}, {5, 0, 4}, {6, 6, 8}, {7, 3, 6}, {8, 1, 3}, {9, 0, 1}, {10, 6, 1}};

Wolfram Language code: model = CreateDataSystemModel[data];

シミュレーションを行い，2つの出力曲線をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

時系列 (3)

TimeSeriesからデータモデルを作る：

Wolfram Language code: ts = TimeSeries[{{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}}]

Wolfram Language code: model = CreateDataSystemModel[ts];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

TimeSeriesからのInterpolationOrderは保存される：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: ts = TimeSeries[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]

Wolfram Language code: model = CreateDataSystemModel[ts];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

データモデルを作るときは，InterpolationOrderをオーバーライドする：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: ts = TimeSeries[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]

Wolfram Language code: model = CreateDataSystemModel[ts, InterpolationOrder -> 3];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

補間関数 (2)

InterpolatingFunctionからモデルを作る：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: if = Interpolation[data];

Wolfram Language code: model = CreateDataSystemModel[if];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

モデルを作る前にInterpolatingFunctionをリサンプルする：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: if = Interpolation[data];

Wolfram Language code: model = CreateDataSystemModel[if, SamplingPeriod -> 2];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

関数 (3)

関数のサンプルを10秒間取って，データモデルを作る：

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10];

サンプル点は自動的に決定される：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolationOrderを選択する：

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10, InterpolationOrder -> 0];

シミュレーションを2秒間行い，データ出力をプロットして補間次数を示す：

Wolfram Language code: sim = SystemModelSimulate[model, 2];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

モデルを作成する際にサンプル周期を設定する：

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10, InterpolationOrder -> 1, SamplingPeriod -> 1];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

データ指定 (3)

時間を取って2つの値の列についてこれを補間するデータモデルを作る：

Wolfram Language code: data = {#, Cos[#], Sin[#]}& /@ Range[0, 2π, 0.1];

データの最初の行を示す：

Wolfram Language code: Take[data, 5]//MatrixForm

時間を使ってデータを補間するモデルを作る：

Wolfram Language code: model = CreateDataSystemModel[data, "Time"];

モデルのシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulate[model, π];

補間された変数をプロットする：

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

入力を取って2つの値の列でこれを補間するデータモデルを作る：

Wolfram Language code: data = {#, Cos[#], Sin[#]}& /@ Range[0, 2π, 0.1];

データの最初の行を示す：

Wolfram Language code: Take[data, 5]//MatrixForm

このデータでモデルを作る：

Wolfram Language code: model = CreateDataSystemModel[data, "1D"];

時間の2倍の速度でサンプルを取る入力でシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulate[model, π, <|"Inputs" -> {"u" -> Function[t, 2t]}|>];

補間された変数をプロットする：

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

2つのスカラー入力を取り，二変量補間を通してそれらを実行するデータを作る：

Wolfram Language code:

data = (⁠|     |     |     |     |     |
| --- | --- | --- | --- | --- |
| 0.0 | 0.1 | 0.2 | 0.3 | 0.4 |
| 0.1 | 0.3 | 0.5 | 0.7 | 0.9 |
| 0.2 | 0.4 | 0.6 | 0.8 | 1.0 |
| 0.3 | 0.5 | 0.7 | 0.9 | 1.1 |
| 0.4 | 0.6 | 0.8 | 1.0 | 1.2 |⁠);

座標と値を分割してデータを3Dプロットで示す：

Wolfram Language code: xcoords = data[[2 ;; , 1]];

Wolfram Language code: ycoords = data[[1, 2 ;; ]];

Wolfram Language code: values = data[[2 ;; , 2 ;; ]];

データ点を示す：

Wolfram Language code: points = Join@@Table[{xcoords[[x]], ycoords[[y]], values[[x, y]]}, {x, Length[xcoords]}, {y, Length[ycoords]}];

Wolfram Language code: p1 = ListPointPlot3D[points]

このデータでモデルを作る：

Wolfram Language code: model = CreateDataSystemModel[data, "2D"];

この入力でシミュレーションを行う：

Wolfram Language code: inputx = Function[t, 0.2 + 0.4t Cos[50 t]];

Wolfram Language code: inputy = Function[t, 0.2 + 0.4t Sin[50 t]];

Wolfram Language code: sim = SystemModelSimulate[model, 0.3, <|"Inputs" -> {"u1" -> inputx, "u2" -> inputy}|>];

補間の結果をもとのデータと一緒にプロットする：

Wolfram Language code: p2 = ParametricPlot3D[{inputx[t], inputy[t], sim["y", t]}, {t, 0, 0.3}];

Wolfram Language code: Show[p1, p2]

オプション (7)

InterpolationOrder (3)

InterpolationOrderを0にすると，サンプル間は一定長の線分になる：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 5];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolationOrderを1にすると，サンプル間は直線になる：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 1];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 5];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolationOrderを3にすると，連続微分による平滑化された線が与えられる：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 3];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 5];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

SamplingPeriod (3)

データのリストについて，SamplingPeriodはデータ点間の周期を決定する：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6};

Wolfram Language code: model = CreateDataSystemModel[data, SamplingPeriod -> 2];

出力のサンプル間は，2秒間の直線になる：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

関数について，SamplingPeriodは関数がどの頻度でサンプルされるかを決定する：

Wolfram Language code: model1 = CreateDataSystemModel[Sin, 0, 10, SamplingPeriod -> 0.5, InterpolationOrder -> 0];

Wolfram Language code: model2 = CreateDataSystemModel[Sin, 0, 10, SamplingPeriod -> 2, InterpolationOrder -> 0];

サンプル周期0.5秒と2秒でシミュレーションを行う：

Wolfram Language code: sim1 = SystemModelSimulate[model1, 10];

Wolfram Language code: sim2 = SystemModelSimulate[model2, 10];

各シミュレーションの出力を比較する：

Wolfram Language code: SystemModelPlot[{sim1, sim2}, "y[1]"]

TimeSeriesについて，SamplingPeriodは一様リサンプリングを行う：

Wolfram Language code: data = {{0, 5}, {1, 4}, {2, 2}, {3, 9}, {4, 1}, {5, 9}, {6, 4}, {7, 3}, {8, 9}, {9, 2}, {10, 0}};

Wolfram Language code: ts = TimeSeries[data]

Wolfram Language code: ListLinePlot[ts]

データモデルの作成の際に時系列のダウンサンプリングを行う：

Wolfram Language code: model = CreateDataSystemModel[ts, SamplingPeriod -> 3];

シミュレーションを行い，出力をプロットする：

Wolfram Language code: sim = SystemModelSimulate[model, 10];

Wolfram Language code: SystemModelPlot[sim, "y[1]"]

GeneratedAssetLocation (1)

デフォルトで，データはモデルに保存される：

Wolfram Language code: model = CreateDataSystemModel[Range[3]];

Wolfram Language code: model["ModelicaDisplay"]

GeneratedAssetLocationを使ってデータファイルをモデルによって参照される指定の場所にエキスポートする：

Wolfram Language code: model = CreateDataSystemModel[Range[3], GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "data.txt"}]];

Wolfram Language code: model["ModelicaDisplay"]

アプリケーション (1)

雑音の多い出力の5秒間のデータモデルを作る：

Wolfram Language code: noise = CreateDataSystemModel[RandomFunction[WienerProcess[], {0., 5, 5 / 400}]];

これをローパスフィルタに接続する：

Wolfram Language code:

filteredModel = ConnectSystemModelComponents[{"noise"∈noise, "filter"∈"Modelica.Blocks.Continuous.LowpassButterworth"}, {"noise.y[1]" -> "filter.u"}]

フィルタリングモデルのシミュレーションを行う：

Wolfram Language code: sim = SystemModelSimulate[filteredModel, 5]

フィルタリングの前と後の信号を示す：

Wolfram Language code: SystemModelPlot[sim, {"filter.u", "filter.y"}]

特性と関係 (2)

作成したモデルをパッケージに挿入する：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};

Wolfram Language code: CreateDataSystemModel["MyPackage.DataModel", data];

Wolfram Language code: CreateDataSystemModel["MyPackage.TimeSeriesModel", TimeSeries[data]];

このパッケージには作成したモデルが両方とも入っている：

Wolfram Language code: SystemModels["MyPackage.*"]

"CombiTimeTable"のModelicaコンポーネントで使うファイルとしてエキスポートする：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};

Wolfram Language code: Export[FileNameJoin[{$TemporaryDirectory, "data.txt"}], {"var1", data}, "MCTT"]

考えられる問題 (1)

モデル中でより大きいデータ集合を使うとシミュレーションが遅くなる可能性がある：

Wolfram Language code: data = Table[{t, RandomReal[10]}, {t, 0, 1000}];

Wolfram Language code: dataModel = CreateDataSystemModel[data];

Wolfram Language code: AbsoluteTiming[SystemModelSimulate[dataModel, 1000]]

MCTT Exportでエキスポートしたデータを使ったシミュレーションの方が速い：

Wolfram Language code: fileModel = "DocumentationExamples.Simulation.FileInput";

Wolfram Language code: AbsoluteTiming[SystemModelSimulate[fileModel, 1000]]

GeneratedAssetLocationを使ってデータファイルをモデルが参照している指定の場所にエキスポートする：

Wolfram Language code: assetModel = CreateDataSystemModel[data, GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "data.txt"}]];

Wolfram Language code: AbsoluteTiming[SystemModelSimulate[assetModel, 1000]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CreateDataSystemModel

詳細とオプション

例題

例 (3)

スコープ (18)

値のリスト (4)

時間と値のペア (3)

時系列 (3)

補間関数 (2)

関数 (3)

データ指定 (3)

オプション (7)

InterpolationOrder (3)

SamplingPeriod (3)

GeneratedAssetLocation (1)

アプリケーション (1)

特性と関係 (2)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

	{v₁,v₂,…},{{t₁,v₁},…}	1
	TimeSeries, InterpolatingFunction	保存された値
	fun	3

	"Time"	時間の列と値の列
	"1D"	引数の列と値の列
	"2D"	引数の行と列と値の行列

CreateDataSystemModel

詳細とオプション

例題

例 (3)

スコープ (18)

値のリスト (4)

時間と値のペア (3)

時系列 (3)

補間関数 (2)

関数 (3)

データ指定 (3)

オプション (7)

InterpolationOrder (3)

SamplingPeriod (3)

GeneratedAssetLocation (1)

アプリケーション (1)

特性と関係 (2)

考えられる問題 (1)

関連項目

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX