WOLFRAM

Wolfram 语言与系统参考资料中心

CreateDataSystemModel[{v1,v2,…}]

创建一个 SystemModel，生成值为 vi 的信号.

CreateDataSystemModel[{{t1,v1},…}]

为时间-数值对 {ti,vi} 创建模型.

CreateDataSystemModel[obj]

为 TimeSeries 或 InterpolatingFunction obj 创建模型.

CreateDataSystemModel[fun,tmin,tmax]

用函数 fun 在 tmin 和 tmax 之间的采样创建模型.

CreateDataSystemModel[data,"dspec"]

创建数据规范为 "dspec" 的模型.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
数值列表  
时间-数值对  
时间序列  
InterpolatingFunction  
函数  
数据规范  
选项  
InterpolationOrder  
SamplingPeriod  
GeneratedAssetLocation  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
相关链接
历史
按以下格式引用：

CreateDataSystemModel

CreateDataSystemModel[{v1,v2,…}]

创建一个 SystemModel，生成值为 vi 的信号.

CreateDataSystemModel[{{t1,v1},…}]

为时间-数值对 {ti,vi} 创建模型.

CreateDataSystemModel[obj]

为 TimeSeries 或 InterpolatingFunction obj 创建模型.

CreateDataSystemModel[fun,tmin,tmax]

用函数 fun 在 tmin 和 tmax 之间的采样创建模型.

CreateDataSystemModel[data,"dspec"]

创建数据规范为 "dspec" 的模型.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

根据时间-数值对列表创建模型：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: model = CreateDataSystemModel[data]

仿真并绘制数据模型的输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10]
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

根据 TimeSeries 创建模型：

Wolfram Language code: ts = TimeSeries[{{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}}]
Wolfram Language code: model = CreateDataSystemModel[ts];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

创建函数在 0 和 10 秒之间采样的数据模型：

Wolfram Language code: model = CreateDataSystemModel[Sin, 0, 10];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

范围  (18)

数值列表  (4)

根据数值列表创建数据模型：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};
Wolfram Language code: model = CreateDataSystemModel[data];

假定采样间隔为 1 秒：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

自定义采样周期：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};
Wolfram Language code: model = CreateDataSystemModel[data, SamplingPeriod -> 0.1];

仿真 1 秒的情况并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 1];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

使用自定义的 InterpolationOrder：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6, 1, 8, 0, 2, 9};
Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

SparseArray 被解释为相应的 Normal 数组：

Wolfram Language code: s = SparseArray[{{1} -> 1, {2} -> 3, {5} -> 2, {7} -> 1}];
Wolfram Language code: model = CreateDataSystemModel[s];

假定采样间隔为 1 秒：

Wolfram Language code: sim = SystemModelSimulate[model, 7];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

时间-数值对  (3)

根据时间-数值对创建模型：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: model = CreateDataSystemModel[data];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

使用自定义的 InterpolationOrder：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

每个时间点都有多个值，据此创建数据模型：

Wolfram Language code: data = {{0, 8, 4}, {1, 5, 2}, {2, 9, 6}, {3, 10, 2}, {4, 4, 1}, {5, 0, 4}, {6, 6, 8}, {7, 3, 6}, {8, 1, 3}, {9, 0, 1}, {10, 6, 1}};
Wolfram Language code: model = CreateDataSystemModel[data];

仿真并绘制两条输出曲线：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

时间序列  (3)

根据 TimeSeries 创建数据模型：

Wolfram Language code: ts = TimeSeries[{{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}}]
Wolfram Language code: model = CreateDataSystemModel[ts];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

TimeSeries 的 InterpolationOrder 被保留：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: ts = TimeSeries[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]
Wolfram Language code: model = CreateDataSystemModel[ts];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

创建数据模型时，覆盖 InterpolationOrder：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: ts = TimeSeries[data, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 0}]
Wolfram Language code: model = CreateDataSystemModel[ts, InterpolationOrder -> 3];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolatingFunction  (2)

根据 InterpolatingFunction 创建模型：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: if = Interpolation[data];
Wolfram Language code: model = CreateDataSystemModel[if];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

创建模型前对 InterpolatingFunction 进行重新采样：

Wolfram Language code: data = {{0, 6}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: if = Interpolation[data];
Wolfram Language code: model = CreateDataSystemModel[if, SamplingPeriod -> 2];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

函数  (3)

创建一个采样了 10 秒的函数的数据模型：

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10];

自动确定采样点：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

选择 InterpolationOrder：

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10, InterpolationOrder -> 0];

仿真并绘制 2 秒的数据输出以显示插值次数：

Wolfram Language code: sim = SystemModelSimulate[model, 2];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

在创建模型时设置采样周期：

Wolfram Language code: model = CreateDataSystemModel[Cos, 0, 10, InterpolationOrder -> 1, SamplingPeriod -> 1];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

数据规范  (3)

创建数据模型，接受时间并将其插值到两个值列上：

Wolfram Language code: data = {#, Cos[#], Sin[#]}& /@ Range[0, 2π, 0.1];

显示数据的前几行：

Wolfram Language code: Take[data, 5]//MatrixForm

创建一个模型，使用时间对数据进行插值：

Wolfram Language code: model = CreateDataSystemModel[data, "Time"];

模拟模型：

Wolfram Language code: sim = SystemModelSimulate[model, π];

绘制插值变量：

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

创建一个数据模型，接受输入并将其插值到两个值列上：

Wolfram Language code: data = {#, Cos[#], Sin[#]}& /@ Range[0, 2π, 0.1];

显示数据的前几行：

Wolfram Language code: Take[data, 5]//MatrixForm

使用数据创建模型：

Wolfram Language code: model = CreateDataSystemModel[data, "1D"];

对输入进行仿真，该输入以两倍于时间的速度对数据进行采样；

Wolfram Language code: sim = SystemModelSimulate[model, π, <|"Inputs" -> {"u" -> Function[t, 2t]}|>];

绘制插值变量：

Wolfram Language code: SystemModelPlot[sim, {"y[1]", "y[2]"}]

创建一个数据模型，接受两个标量输入，并通过双变量插值运行它们：

Wolfram Language code: data = (⁠| | | | | | | --- | --- | --- | --- | --- | | 0.0 | 0.1 | 0.2 | 0.3 | 0.4 | | 0.1 | 0.3 | 0.5 | 0.7 | 0.9 | | 0.2 | 0.4 | 0.6 | 0.8 | 1.0 | | 0.3 | 0.5 | 0.7 | 0.9 | 1.1 | | 0.4 | 0.6 | 0.8 | 1.0 | 1.2 |⁠);

拆分坐标和值，以在三维图中显示数据：

Wolfram Language code: xcoords = data[[2 ;; , 1]];
Wolfram Language code: ycoords = data[[1, 2 ;; ]];
Wolfram Language code: values = data[[2 ;; , 2 ;; ]];

显示数据点：

Wolfram Language code: points = Join@@Table[{xcoords[[x]], ycoords[[y]], values[[x, y]]}, {x, Length[xcoords]}, {y, Length[ycoords]}];
Wolfram Language code: p1 = ListPointPlot3D[points]

使用数据创建模型：

Wolfram Language code: model = CreateDataSystemModel[data, "2D"];

用输入模拟：

Wolfram Language code: inputx = Function[t, 0.2  + 0.4t Cos[50 t]];
Wolfram Language code: inputy = Function[t, 0.2  + 0.4t Sin[50 t]];
Wolfram Language code: sim = SystemModelSimulate[model, 0.3, <|"Inputs" -> {"u1" -> inputx, "u2" -> inputy}|>];

将插值结果与原始数据一起绘制：

Wolfram Language code: p2 = ParametricPlot3D[{inputx[t], inputy[t], sim["y", t]}, {t, 0, 0.3}];
Wolfram Language code: Show[p1, p2]

选项  (7)

InterpolationOrder  (3)

InterpolationOrder 值为 0 时给出固定采样间隔：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};
Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 0];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 5];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolationOrder 值为 1 时，在采样信号间给出直线：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};
Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 1];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 5];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

InterpolationOrder 值为 3 时给出一个具有连续导数的平滑线：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};
Wolfram Language code: model = CreateDataSystemModel[data, InterpolationOrder -> 3];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 5];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

SamplingPeriod  (3)

对于数据列表，SamplingPeriod 确定了数据点之间的周期：

Wolfram Language code: data = {6, 9, 1, 9, 7, 6};
Wolfram Language code: model = CreateDataSystemModel[data, SamplingPeriod -> 2];

输出的采样信号间有 2 秒长的线性部分：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

对于函数，SamplingPeriod 确定了一个函数的采样频率：

Wolfram Language code: model1 = CreateDataSystemModel[Sin, 0, 10, SamplingPeriod -> 0.5, InterpolationOrder -> 0];
Wolfram Language code: model2 = CreateDataSystemModel[Sin, 0, 10, SamplingPeriod -> 2, InterpolationOrder -> 0];

仿真采样周期为 0.5 秒和 2 秒的情况：

Wolfram Language code: sim1 = SystemModelSimulate[model1, 10];
Wolfram Language code: sim2 = SystemModelSimulate[model2, 10];

比较每次仿真的输出：

Wolfram Language code: SystemModelPlot[{sim1, sim2}, "y[1]"]

对于 TimeSeries，SamplingPeriod 进行均匀重新采样：

Wolfram Language code: data = {{0, 5}, {1, 4}, {2, 2}, {3, 9}, {4, 1}, {5, 9}, {6, 4}, {7, 3}, {8, 9}, {9, 2}, {10, 0}};
Wolfram Language code: ts = TimeSeries[data]
Wolfram Language code: ListLinePlot[ts]

创建数据模型时对时间序列进行降采样：

Wolfram Language code: model = CreateDataSystemModel[ts, SamplingPeriod -> 3];

仿真并绘制输出：

Wolfram Language code: sim = SystemModelSimulate[model, 10];
Wolfram Language code: SystemModelPlot[sim, "y[1]"]

GeneratedAssetLocation  (1)

数据默认存储在模型中：

Wolfram Language code: model = CreateDataSystemModel[Range[3]];
Wolfram Language code: model["ModelicaDisplay"]

使用 GeneratedAssetLocation 将数据文件导出到模型引用的指定地址：

Wolfram Language code: model = CreateDataSystemModel[Range[3], GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "data.txt"}]];
Wolfram Language code: model["ModelicaDisplay"]

应用  (1)

创建 5 秒带有噪音输出的数据模型：

Wolfram Language code: noise = CreateDataSystemModel[RandomFunction[WienerProcess[], {0., 5, 5 / 400}]];

将其连接到低通滤波器上：

Wolfram Language code: filteredModel = ConnectSystemModelComponents[{"noise"∈noise, "filter"∈"Modelica.Blocks.Continuous.LowpassButterworth"}, {"noise.y[1]" -> "filter.u"}]

仿真滤波模型：

Wolfram Language code: sim = SystemModelSimulate[filteredModel, 5]

显示滤波前和滤波后的信号：

Wolfram Language code: SystemModelPlot[sim, {"filter.u", "filter.y"}]

属性和关系  (2)

把创建的模型插入模型包中：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}};
Wolfram Language code: CreateDataSystemModel["MyPackage.DataModel", data];
Wolfram Language code: CreateDataSystemModel["MyPackage.TimeSeriesModel", TimeSeries[data]];

模型包含有两个已创建的模型：

Wolfram Language code: SystemModels["MyPackage.*"]

导出为一个文件，以便在 "CombiTimeTable" Modelica 组件中使用：

Wolfram Language code: data = {{0, 6}, {1, 9}, {2, 1}, {3, 9}, {4, 7}, {5, 6}, {6, 1}, {7, 8}, {8, 0}, {9, 2}, {10, 9}};
Wolfram Language code: Export[FileNameJoin[{$TemporaryDirectory, "data.txt"}], {"var1", data}, "MCTT"]

可能存在的问题  (1)

模型中较大的数据集可能使仿真变慢：

Wolfram Language code: data = Table[{t, RandomReal[10]}, {t, 0, 1000}];
Wolfram Language code: dataModel = CreateDataSystemModel[data];
Wolfram Language code: AbsoluteTiming[SystemModelSimulate[dataModel, 1000]]

用通过 MCTT Export 导出的数据进行仿真会比较快：

Wolfram Language code: fileModel = "DocumentationExamples.Simulation.FileInput";
Wolfram Language code: AbsoluteTiming[SystemModelSimulate[fileModel, 1000]]

使用 GeneratedAssetLocation 将数据文件导出到模型所引用的指定位置：

Wolfram Language code: assetModel = CreateDataSystemModel[data, GeneratedAssetLocation -> FileNameJoin[{$TemporaryDirectory, "data.txt"}]];
Wolfram Language code: AbsoluteTiming[SystemModelSimulate[assetModel, 1000]]
Wolfram Research (2018)，CreateDataSystemModel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CreateDataSystemModel.html （更新于 2020 年）.

文本

Wolfram Research (2018)，CreateDataSystemModel，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CreateDataSystemModel.html （更新于 2020 年）.

CMS

Wolfram 语言. 2018. "CreateDataSystemModel." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/CreateDataSystemModel.html.

APA

Wolfram 语言. (2018). CreateDataSystemModel. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CreateDataSystemModel.html 年

BibTeX

@misc{reference.wolfram_2026_createdatasystemmodel, author="Wolfram Research", title="{CreateDataSystemModel}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CreateDataSystemModel.html}", note=[Accessed: 07-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_createdatasystemmodel, organization={Wolfram Research}, title={CreateDataSystemModel}, year={2020}, url={https://reference.wolfram.com/language/ref/CreateDataSystemModel.html}, note=[Accessed: 07-October-2026]}