WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CriticalityFailureImportance[rdist,t]

ReliabilityDistribution rdist の時間 t におけるすべての成分のクリティカリティ故障重要度を与える．

CriticalityFailureImportance[fdist,t]

FailureDistribution fdist の時間 t におけるすべての成分のクリティカリティ故障重要度を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
ReliabilityDistributionモデル  
FailureDistributionモデル  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CriticalityFailureImportance

CriticalityFailureImportance[rdist,t]

ReliabilityDistribution rdist の時間 t におけるすべての成分のクリティカリティ故障重要度を与える．

CriticalityFailureImportance[fdist,t]

FailureDistribution fdist の時間 t におけるすべての成分のクリティカリティ故障重要度を与える．

詳細

  • CriticalityFailureImportanceは故障致命度あるいはクリティカリティ重要度因子としても知られている．
  • 成分 のクリティカリティ故障重要度は 成分が系の故障の原因となった確率である．ただし，系は時間 で故障するものとする．
  • 時間 における成分 のクリティカリティ故障重要度は で与えられる．ただし， は成分 のBirnbaum重要度，は成分 が故障した確率，は系が故障した確率である．
  • 結果は rdist または fdist の分布リストでの成分順で与えられる．

例題

すべて開く すべて閉じる

例  (3)

異なる寿命分布を持ち，直接接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

結果はReliabilityDistributionにおける分布リストと同じ順で与えられる：

Wolfram Language code: {Subscript[cf, x], Subscript[cf, y]} = CriticalityFailureImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[cf, x], Subscript[cf, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

並列成分は両方とも系の故障に関係がある：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalityFailureImportance[ℛ, t]

故障の木に基づいたモデリングを使って系を定義する：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[3, 2]}}];
Wolfram Language code: CriticalityFailureImportance[ℱ, t]
Wolfram Language code: Plot[Evaluate@%, {t, 0, 7}, Filling -> Axis]

スコープ  (17)

ReliabilityDistributionモデル  (9)

等しい寿命分布を持ち，並列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらの成分も同じように系の故障を引き起こす可能性がある：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]

等しい寿命分布を持ち，直列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらの成分も同じように系の故障を引き起こす可能性がある：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

寿命分布が等しい3つの成分のうち2つが動作に必要な系：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

どの成分についても系の故障の原因になる確率は等しい：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

寿命分布が等しい単純な混合系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]//Simplify

成分 が系の故障を引き起こす可能性が最も高い：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

1つの成分と並列で接続されている直列接続の系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]

故障した系では，成分 が常に故障していた．したがって，これが系の故障を引き起こす確率は1である：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}]

単純な混合系で母数の変更の影響を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]//Simplify

並列成分の一つ， を悪化させたときの重要度の変化を示す：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {cf /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

分布が異なる他の2つと並列接続している1つの成分：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

時間のある特定の点における重要性尺度を厳密な結果として求める：

Wolfram Language code: CriticalityFailureImportance[ℛ, 3 / 2]//Simplify

機械精度の結果として：

Wolfram Language code: CriticalityFailureImportance[ℛ, 1.5]

記号式で：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

任意の有効なReliabilityDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

待機成分が系の故障を引き起こした可能性は低い：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 4}, Filling -> Axis, PlotRange -> All]

部分系の重要性尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]

時間に沿って重要度をプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {z, r}}], {t, 0, 4}]

FailureDistributionモデル  (8)

2つの基本事象のどちらかが頂点事象を引き起こす：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらの事象も同じように頂上事象を起こす可能性がある：

Wolfram Language code: CriticalityFailureImportance[ℱ, t]//Simplify

両方の基本事象が一緒になるとはじめて頂上事象が引き起こされる：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

頂上事象が起った場合，これに貢献した確率は と の両方とも1になる：

Wolfram Language code: CriticalityFailureImportance[ℱ, t]

基本事象の分布が等しいボーティングゲート：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

ボーティングゲートの事象が等しいと頂上事象を引き起こす確率も等しくなる：

Wolfram Language code: CriticalityFailureImportance[ℱ, t]//Simplify

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

クリティカリティ重要度を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]

頂上事象が起ったときは，事象 が常に起っている：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を示す：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]//Simplify

事象 が頂上事象を引き起こした可能性が最も高い：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

単純な混合系で母数の変化が与える影響を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]//Simplify

基本事象の一つ， を悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[Plot[Evaluate@MapThread[Tooltip, {cf /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k], {k, 1, 5, 2}]

任意の有効なFailureDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalityFailureImportance[ℱ, t]

待機のモデル化された事象よりもあまり信頼性の高くない事象が，頂上事象を引き起こした可能性が高い：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 4}, Filling -> Axis, PlotRange -> All]

部分系の重要性尺度を得るために系を段階を追ってモデル化する：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]

時間に沿って重要度をプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {z, f}}], {t, 0, 4}]

アプリケーション  (4)

水中のパイプラインの修理は水面下のドライメンテナンスキャビンを使って行われる．このキャビンへの生命維持装置は次の分布に従う：

Wolfram Language code: Evaluate[Table[Subscript[𝒟, i], {i, 1, 15}]] = ExponentialDistribution[1 / #]& /@ {3571, 3571, 4667, 4667, 50000, 9802, 9802, 9802, 9802, 9802, 4667, 9802, 8633, 4667, 5000};
Wolfram Language code: ℱ = FailureDistribution[(Subscript[s, 1]∧Subscript[s, 2])∨Or@@Table[Subscript[s, i], {i, 3, 15}], Table[{Subscript[s, i], Subscript[𝒟, i]}, {i, 15}]];

典型的な作業時間は24時間である．このような作業のクリティカリティ故障重要度を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, 24]//N;
Wolfram Language code: Sort[Table[{Subscript[s, i], cf[[i]]}, {i, 15}], #1[[2]] > #2[[2]]&]//TableForm

指揮官が1人，情報部員が1人，武器，工学，医学，通信の専門員がそれぞれ2名の特殊部隊について考える．この部隊は各分野の専門員が1人いる限り機能すると仮定する：

Wolfram Language code: team = command∧intelligence∧(weapons1∨weapons2)∧(eng1∨eng2)∧(med1∨med2)∧(com1∨com2);

次の寿命分布を仮定する：

Wolfram Language code: vars = {command, intelligence, weapons1, weapons2, eng1, eng2, med1, med2, com1, com2};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {10^-4, 3×10^-4, 10^-5, 10^-5, 10^-3, 10^-3, 10^-4, 10^-4, 2×10^-5, 2×10^-5};
Wolfram Language code: dists = Transpose[{vars, lifetimes}];
Wolfram Language code: ℛ = ReliabilityDistribution[team, dists];

10時間の作戦で成功する確率を計算する：

Wolfram Language code: SurvivalFunction[ℛ, 10]//N

作戦を失敗に導く可能性が最も高い役割を求める：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, 10]//N

結果を重要度でソートする：

Wolfram Language code: Sort[Transpose[{vars, cf}], #1[[2]] > #2[[2]]&]

情報部員を1人追加することで部隊を強化する：

Wolfram Language code: team2 = team /. intelligence -> (int1∨int2);
Wolfram Language code: vars2 = {command, int1, int2, weapons1, weapons2, eng1, eng2, med1, med2, com1, com2};
Wolfram Language code: lifetimes2 = ExponentialDistribution /@ {10^-4, 3×10^-4, 3×10^-4, 10^-5, 10^-5, 10^-3, 10^-3, 10^-4, 10^-4, 2×10^-5, 2×10^-5};
Wolfram Language code: dists2 = Transpose[{vars2, lifetimes2}];
Wolfram Language code: ℛ2 = ReliabilityDistribution[team2, dists2];

生存確率が99.6%から99.9%に上がった：

Wolfram Language code: SurvivalFunction[ℛ2, 10]//N

航空機の離陸時の際に故障致命度が最も高い成分は何かを分析する．格納扉は電動・手動のどちらで開けることもできる：

Wolfram Language code: hangarDoor = power∨manual;

2つの燃料ポンプを動かすためには動力が必要である：

Wolfram Language code: fuelTransferA2 = power∧pumpA2;
Wolfram Language code: fuelTransferB2 = power∧pumpB2;

さらに，次の燃料移送構造で，2つのポンプを信頼できる電池を使って動かすことができる：

Wolfram Language code: fuelTransfer = (pumpA1∧(pumpB1∨fuelTransferB2))∨(fuelTransferA2∧(pumpB1∨fuelTransferB2));

航空機の除氷装置と燃料の収蔵タンクも必要である：

Wolfram Language code: launch = fuelStorage∧fuelTransfer∧hangarDoor∧deicing;

寿命分布を定義する：

Wolfram Language code: vars = {deicing, fuelStorage, manual, power, pumpA1, pumpB1, pumpA2, pumpB2};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {10^-7, 10^-8, 10^-3, 2×10^-4, 5×10^-4, 5×10^-4, 5×10^-4, 5×10^-4};
Wolfram Language code: dists = Transpose[{vars, lifetimes}];
Wolfram Language code: ℛ = ReliabilityDistribution[launch, dists];

重要度を計算する：

Wolfram Language code: cfi = RiskAchievementImportance[ℛ, t];

航空機の離陸失敗には燃料貯蔵と動力が最も関係している：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cfi, vars}], {t, 0, 2500}]

3時間の作業時間の中で最も重要な成分を求める：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[2], WeibullDistribution[1, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℱ = FailureDistribution[(x∨y)∧(z∨v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: cfi = CriticalityFailureImportance[ℱ, t]

時間に沿って重要度を示す：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cfi, {x, y, z, v}}], {t, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

3時間の作業時間中，成分 が故障を引き起こした可能性が最も高い：

Wolfram Language code: PieChart[cfi /. t -> 3//N, ChartLabels -> {x, y, z, v}]

特性と関係  (5)

故障に基づいたクリティカリティ重要度はProbabilityで定義することができる：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, 𝒟1}, {y, 𝒟2}}];

すべての成分のBirnbaumImportance：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]//Simplify

成分の信頼性の欠如を系の信頼性の欠如で割った成分の重み：

Wolfram Language code: cw = Table[Probability[τ ≤ t, τ𝒟] / Probability[τ ≤ t, τℛ], {𝒟, {𝒟1, 𝒟2}}]//Refine[#, t > 0]&

結果のクリティカリティ故障重要度：

Wolfram Language code: bi cw

定義と比較する：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

故障に基づいたクリティカリティ重要度はRiskReductionImportanceと関係がある：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: 1 - (1/RiskReductionImportance[ℛ, t])

定義と比較する：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

故障に基づいたクリティカリティ重要度はImprovementImportanceと関係がある：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];

ImprovementImportanceを計算する：

Wolfram Language code: ii = ImprovementImportance[ℛ, t];

改善の重要度を系の信頼性の欠如で割る：

Wolfram Language code: ii / CDF[ℛ, t]//Refine[#, t > 0]&

定義と比較する：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

並列の系では，故障に基づいたクリティカリティ重要度はすべての成分について常に1である：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y∨z, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, WeibullDistribution[α, β]}, {z, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalityFailureImportance[ℛ, t]

無関係の成分の重要度は0である：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: CriticalityFailureImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]
Wolfram Research (2012), CriticalityFailureImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html.

テキスト

Wolfram Research (2012), CriticalityFailureImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html.

CMS

Wolfram Language. 2012. "CriticalityFailureImportance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html.

APA

Wolfram Language. (2012). CriticalityFailureImportance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html

BibTeX

@misc{reference.wolfram_2026_criticalityfailureimportance, author="Wolfram Research", title="{CriticalityFailureImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_criticalityfailureimportance, organization={Wolfram Research}, title={CriticalityFailureImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html}, note=[Accessed: 04-September-2026]}