WOLFRAM

Wolfram 语言与系统参考资料中心

CriticalityFailureImportance[rdist,t]

给出 ReliabilityDistribution rdist 中所有组件在时刻 t 的关键故障重要度.

CriticalityFailureImportance[fdist,t]

给出 FailureDistribution fdist 中所有组件在时刻 t 的关键故障重要度.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
ReliabilityDistribution 模型  
FailureDistribution 模型  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CriticalityFailureImportance

CriticalityFailureImportance[rdist,t]

给出 ReliabilityDistribution rdist 中所有组件在时刻 t 的关键故障重要度.

CriticalityFailureImportance[fdist,t]

给出 FailureDistribution fdist 中所有组件在时刻 t 的关键故障重要度.

更多信息

  • CriticalityFailureImportance 也被称为失效关键性（Failure Criticality）或关键重要度系数（Criticality Importance Factor）.
  • 组件 的关键故障重要度指的是当系统在时刻 发生故障时，由组件 造成系统故障的概率.
  • 组件 在时刻 的关键故障重要度由 给出，其中 是组件 的 Birnbaum 重要度， 是组件 发生故障的概率， 是系统发生故障的概率.
  • 结果按照 rdist 或 fdist 分布列表中组件的顺序返回.

范例

打开所有单元 关闭所有单元

基本范例  (3)

两个组件串联，分别具有不同的寿命分布：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

给出结果的顺序与 ReliabilityDistribution 中分布列表的顺序相同：

Wolfram Language code: {Subscript[cf, x], Subscript[cf, y]} = CriticalityFailureImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[cf, x], Subscript[cf, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

这两个并联组件共同导致系统故障：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalityFailureImportance[ℛ, t]

使用基于故障树的建模，定义系统：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[3, 2]}}];
Wolfram Language code: CriticalityFailureImportance[ℱ, t]
Wolfram Language code: Plot[Evaluate@%, {t, 0, 7}, Filling -> Axis]

范围  (17)

ReliabilityDistribution 模型  (9)

两个具有相同寿命分布的组件并联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

这两个组件造成系统故障的可能性相等：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]

两个具有相同寿命分布的组件串联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

这两个组件造成系统故障的可能性相等：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

由三个具有相同寿命分布的组件构成的系统，要求其中两个组件正常工作：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

这三个组件造成系统故障的可能性相等：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

一个具有相同寿命分布的简单混合系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]//Simplify

组件 造成系统故障的可能性最大：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

串联后再与一个组件并联的系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]

对于一个故障系统，组件 总是失效. 因此它造成系统故障的概率为1：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

计算重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]//Simplify

显示当并联组件之一 恶化时重要度的变化：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {cf /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

具有不同分布的一个组件与另外两个并联：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

求在特定时间点处重要度的精确结果：

Wolfram Language code: CriticalityFailureImportance[ℛ, 3 / 2]//Simplify

给出机器精度的结果：

Wolfram Language code: CriticalityFailureImportance[ℛ, 1.5]

给出符号式表达式：

Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

可以使用任意有效的 ReliabilityDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalityFailureImportance[ℛ, t]//Simplify

待机组件是不太可能造成系统故障：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 4}, Filling -> Axis, PlotRange -> All]

分布模拟系统，得到子系统的重要度：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]

绘制重要度随时间变化的曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {z, r}}], {t, 0, 4}]

FailureDistribution 模型  (8)

两个基本事件之一引发了顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

两个事件引发顶事件的可能性相同：

Wolfram Language code: CriticalityFailureImportance[ℱ, t]//Simplify

两个基本事件共同引发顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

当顶事件发生时， 和 共同导致的概率为1：

Wolfram Language code: CriticalityFailureImportance[ℱ, t]

一个投票门，其中基本事件具有相同的分布：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

投票门中的相同事件引起顶事件发生的概率相同：

Wolfram Language code: CriticalityFailureImportance[ℱ, t]//Simplify

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

计算关键重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]

当顶事件发生时， 总是出现：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

显示重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]//Simplify

事件 最有可能导致了顶事件：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

计算重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]//Simplify

显示当基本事件之一 恶化时重要度的变化：

Wolfram Language code: Table[Plot[Evaluate@MapThread[Tooltip, {cf /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k], {k, 1, 5, 2}]

可以使用任意有效的 FailureDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalityFailureImportance[ℱ, t]

可靠度较低的事件比待机模拟事件引发顶事件的可能性大：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 4}, Filling -> Axis, PlotRange -> All]

分布模拟系统，得到子系统的重要度：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: cf = CriticalityFailureImportance[ℱ, t]

绘制重要度随时间变化的曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cf, {z, f}}], {t, 0, 4}]

应用  (4)

水下干式维修舱用来修复水下管道. 该维修舱的寿命支持系统服从如下分配：

Wolfram Language code: Evaluate[Table[Subscript[𝒟, i], {i, 1, 15}]] = ExponentialDistribution[1 / #]& /@ {3571, 3571, 4667, 4667, 50000, 9802, 9802, 9802, 9802, 9802, 4667, 9802, 8633, 4667, 5000};
Wolfram Language code: ℱ = FailureDistribution[(Subscript[s, 1]∧Subscript[s, 2])∨Or@@Table[Subscript[s, i], {i, 3, 15}], Table[{Subscript[s, i], Subscript[𝒟, i]}, {i, 15}]];

典型的任务时间为24小时. 计算如下任务的关键故障重要度：

Wolfram Language code: cf = CriticalityFailureImportance[ℱ, 24]//N;
Wolfram Language code: Sort[Table[{Subscript[s, i], cf[[i]]}, {i, 15}], #1[[2]] > #2[[2]]&]//TableForm

考虑一个特种部队，由一个指挥官、一个情报官和两位分别在武器、工程、医疗和通信领域的专家组成. 假设该团队要执行任务，只要有一名在各领域的专家就行：

Wolfram Language code: team = command∧intelligence∧(weapons1∨weapons2)∧(eng1∨eng2)∧(med1∨med2)∧(com1∨com2);

假定以下寿命分布：

Wolfram Language code: vars = {command, intelligence, weapons1, weapons2, eng1, eng2, med1, med2, com1, com2};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {10^-4, 3×10^-4, 10^-5, 10^-5, 10^-3, 10^-3, 10^-4, 10^-4, 2×10^-5, 2×10^-5};
Wolfram Language code: dists = Transpose[{vars, lifetimes}];
Wolfram Language code: ℛ = ReliabilityDistribution[team, dists];

计算一个10小时任务成功的概率：

Wolfram Language code: SurvivalFunction[ℛ, 10]//N

求最有可能造成任务失败的角色：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, 10]//N

按重要度对结果排序：

Wolfram Language code: Sort[Transpose[{vars, cf}], #1[[2]] > #2[[2]]&]

增加一名辅助情报官以改善团队：

Wolfram Language code: team2 = team /. intelligence -> (int1∨int2);
Wolfram Language code: vars2 = {command, int1, int2, weapons1, weapons2, eng1, eng2, med1, med2, com1, com2};
Wolfram Language code: lifetimes2 = ExponentialDistribution /@ {10^-4, 3×10^-4, 3×10^-4, 10^-5, 10^-5, 10^-3, 10^-3, 10^-4, 10^-4, 2×10^-5, 2×10^-5};
Wolfram Language code: dists2 = Transpose[{vars2, lifetimes2}];
Wolfram Language code: ℛ2 = ReliabilityDistribution[team2, dists2];

生存概率从99.6%提高至99.9%:

Wolfram Language code: SurvivalFunction[ℛ2, 10]//N

分析在飞机启动过程中哪个组件具有最高的失效关键性. 机库门可以通过电子或手工方式打开：

Wolfram Language code: hangarDoor = power∨manual;

两个燃油泵需要电力来运行：

Wolfram Language code: fuelTransferA2 = power∧pumpA2;
Wolfram Language code: fuelTransferB2 = power∧pumpB2;

在提供以下的燃料传输结构时，另有两个泵运行需要可靠的电池：

Wolfram Language code: fuelTransfer = (pumpA1∧(pumpB1∨fuelTransferB2))∨(fuelTransferA2∧(pumpB1∨fuelTransferB2));

此外，还需要对飞机除冰和一个燃料储存罐：

Wolfram Language code: launch = fuelStorage∧fuelTransfer∧hangarDoor∧deicing;

定义寿命分布：

Wolfram Language code: vars = {deicing, fuelStorage, manual, power, pumpA1, pumpB1, pumpA2, pumpB2};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {10^-7, 10^-8, 10^-3, 2×10^-4, 5×10^-4, 5×10^-4, 5×10^-4, 5×10^-4};
Wolfram Language code: dists = Transpose[{vars, lifetimes}];
Wolfram Language code: ℛ = ReliabilityDistribution[launch, dists];

计算重要度：

Wolfram Language code: cfi = RiskAchievementImportance[ℛ, t];

燃料储存罐和电源最有可能导致启动失败：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cfi, vars}], {t, 0, 2500}]

求在三个小时的任务时间内，哪个组件是最重要的：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[2], WeibullDistribution[1, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℱ = FailureDistribution[(x∨y)∧(z∨v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: cfi = CriticalityFailureImportance[ℱ, t]

绘制重要度随时间变化的曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cfi, {x, y, z, v}}], {t, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

在三个小时的任务时间内，组件 最有可能导致故障：

Wolfram Language code: PieChart[cfi /. t -> 3//N, ChartLabels -> {x, y, z, v}]

属性和关系  (5)

基于故障的关键重要度可以用 Probability 的形式定义：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, 𝒟1}, {y, 𝒟2}}];

所有组件的 BirnbaumImportance：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]//Simplify

用组件不可靠度除以系统不可靠度作为组件权重：

Wolfram Language code: cw = Table[Probability[τ ≤ t, τ𝒟] / Probability[τ ≤ t, τℛ], {𝒟, {𝒟1, 𝒟2}}]//Refine[#, t > 0]&

得到的关键故障重要度：

Wolfram Language code: bi cw

与定义比较：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

基于故障的关键重要度与 RiskReductionImportance 相关：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: 1 - (1/RiskReductionImportance[ℛ, t])

与定义比较：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

基于故障的关键重要度与 ImprovementImportance 相关：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];

计算 ImprovementImportance：

Wolfram Language code: ii = ImprovementImportance[ℛ, t];

改善重要度除以系统的不可靠度：

Wolfram Language code: ii / CDF[ℛ, t]//Refine[#, t > 0]&

与定义比较：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

对于并联系统，所有组件的基于故障的关键重要度始终为1：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y∨z, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, WeibullDistribution[α, β]}, {z, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalityFailureImportance[ℛ, t]

不相关组件的重要度为0：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: CriticalityFailureImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]
Wolfram Research (2012)，CriticalityFailureImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html.

文本

Wolfram Research (2012)，CriticalityFailureImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html.

CMS

Wolfram 语言. 2012. "CriticalityFailureImportance." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html.

APA

Wolfram 语言. (2012). CriticalityFailureImportance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html 年

BibTeX

@misc{reference.wolfram_2026_criticalityfailureimportance, author="Wolfram Research", title="{CriticalityFailureImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html}", note=[Accessed: 12-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_criticalityfailureimportance, organization={Wolfram Research}, title={CriticalityFailureImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/CriticalityFailureImportance.html}, note=[Accessed: 12-October-2026]}