WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CriticalitySuccessImportance[rdist,t]

時間 t におけるReliabilityDistribution rdist のすべての成分のクリティカリティ成功重要度を与える．

CriticalitySuccessImportance[fdist,t]

時間 t におけるFailureDistribution fdist のすべての成分のクリティカリティ成功重要度を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
ReliabilityDistributionモデル  
FailureDistributionモデル  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CriticalitySuccessImportance

CriticalitySuccessImportance[rdist,t]

時間 t におけるReliabilityDistribution rdist のすべての成分のクリティカリティ成功重要度を与える．

CriticalitySuccessImportance[fdist,t]

時間 t におけるFailureDistribution fdist のすべての成分のクリティカリティ成功重要度を与える．

詳細

  • CriticalitySuccessImportanceはクリティカリティ重要度因子としても知られている．
  • 成分 のクリティカリティ成功重要度は，系が動いていると仮定して， が系の成功に貢献している成分である確率である．
  • 時間 における成分 のクリティカリティ成功重要度は で与えられる．ただし，は成分 のBirnbaum重要度であり， は成分 が動いている確率であり， は系が動いている確率である．
  • 結果は rdist あるいは fdist における分布リストの成分順で返される．

例題

すべて開く すべて閉じる

例  (3)

異なる寿命分布を持ち，並列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

結果はReliabilityDistributionの分布リストと同じ順で与えられる：

Wolfram Language code: {Subscript[cs, x], Subscript[cs, y]} = CriticalitySuccessImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[cs, x], Subscript[cs, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

連続成分のどちらも，系の稼働に貢献している：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalitySuccessImportance[ℛ, t]

故障の木に基づいたモデリングを使って系を定義する：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: CriticalitySuccessImportance[ℱ, t]
Wolfram Language code: Plot[%, {t, 0, 11}, Filling -> Axis]

スコープ  (17)

ReliabilityDistributionモデル  (9)

等しい寿命分布を持ち，並列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらの成分も動いている系に同じように貢献している：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

等しい寿命分布を持ち，直列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

と は両方とも確率1で，直列の系の稼働に貢献している：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

動くためには寿命分布が等しい3つの成分のうち2つが必要な系：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

すべての成分が系の稼働に等しく貢献している：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

寿命分布が等しい単純な混合系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]//Simplify

成分 は常に系の稼働に貢献している：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

1つの成分と並列で接続されている直列接続の系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]//Simplify

成分 が系の稼働に最も貢献している：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}]

単純な混合系でパラメータを変更することの効果を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]//Simplify

並列成分の1つである を悪化させることによる重要度の変化を示す：

Wolfram Language code: Table[Plot[Evaluate@MapThread[Tooltip, {cs /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k], {k, 1, 5, 2}]

分布が異なる2つの他の成分と並列の1つの成分：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

時間のある1点での重要性尺度を厳密な結果として求める：

Wolfram Language code: CriticalitySuccessImportance[ℛ, 3 / 2]//Simplify

機械精度による結果：

Wolfram Language code: CriticalitySuccessImportance[ℛ, 1.5]

記号式による結果：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

任意の有効なReliabilityDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

重要性尺度をプロットする：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 10}, Filling -> Axis, PlotRange -> All]

部分系の重要性尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∨r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]

重要度を時間に沿ってプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {z, r}}], {t, 0, 4}]

FailureDistributionモデル  (8)

2つの基本事象のどちらかが頂上事象に繋がる：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらの事象も頂上事象の発生防止に貢献している：

Wolfram Language code: CriticalitySuccessImportance[ℱ, t]//Simplify

両方の基本事象が一緒になってはじめて頂上事象に至る：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

両方の事象が同じように頂上事象に繋がる可能性がある：

Wolfram Language code: CriticalitySuccessImportance[ℱ, t]//Simplify

基本事象の分布が等しいボーティングゲート：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

ボーティングゲートの同一事象は故障を防ぐための確率が等しい：

Wolfram Language code: CriticalitySuccessImportance[ℱ, t]//Simplify

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

クリティカリティ重要度を計算する：

Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]//Simplify

頂上事象がまだ発生していない場合，事象 が最も頂上事象を防ぐ可能性がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を示す：

Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]//Simplify

頂上事象がまだ発生していない場合は，事象 は確率1でそれが発生していないことに貢献していない：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

単純な混合系におけるパラメータの変更の効果を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]//Simplify

基本事象の1つである を悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[Plot[Evaluate@MapThread[Tooltip, {cs /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k], {k, 1, 5, 2}]

任意の有効なFailureDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalitySuccessImportance[ℱ, t]

重要性尺度をプロットする：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 10}, Filling -> Axis, PlotRange -> All]

部分系の重要性尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℱsub = FailureDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∨f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]

時間に沿って重要度をプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {z, f}}], {t, 0, 4}]

アプリケーション  (3)

作業時間が3時間のとき，どの成分が成功に最も貢献する可能性があるか求める：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[2], WeibullDistribution[1, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℱ = FailureDistribution[(x∨y)∧(z∨v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: csi = CriticalitySuccessImportance[ℱ, t]

時間に沿って重要度を示す：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {csi, {x, y, z, v}}], {t, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

作業時間が3時間のとき，成分 が系の成功に最も貢献する可能性がある：

Wolfram Language code: csi /. t -> 3//N

1つの成分が直列で2つの成分が並列の系について調べる．クリティカリティ成功重要性尺度に照らしてどの成分が最も重要であるかを判断する：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = {ExponentialDistribution[5], ExponentialDistribution[1.2], ExponentialDistribution[1]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∨y)∧z, {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];
Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]

成分 は系の成功に常に貢献する：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 0.5}, Filling -> Axis]

次の系を仮定する：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = {ExponentialDistribution[1], ExponentialDistribution[2], ExponentialDistribution[3]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

重要度を計算する：

Wolfram Language code: csi = CriticalitySuccessImportance[ℛ, t]//FullSimplify

すべての について，重要度の順序は であると言える：

Wolfram Language code: Refine[Reduce[csi[[1]] ≥ csi[[2]] ≥ csi[[3]], t, Reals], t ≥ 0]

特性と関係  (3)

CriticalitySuccessImportanceはProbabilityによって定義することができる：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, 𝒟1}, {y, 𝒟2}}];

すべての成分のBirnbaumImportance：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

成分の信頼性を系の信頼性で割った成分の重み：

Wolfram Language code: cw = Map[Probability[τ > t, τ#] / Probability[τ > t, τℛ]&, {𝒟1, 𝒟2}]//Refine[#, t > 0]&

結果の成功に基づいたクリティカリティ重要度：

Wolfram Language code: bi cw

定義と比較する：

Wolfram Language code: FullSimplify[% - CriticalitySuccessImportance[ℛ, t]]

直列の系では，成功に基づいたクリティカリティ重要度はすべての成分について常に1である：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y∧z, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, WeibullDistribution[α, β]}, {z, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalitySuccessImportance[ℛ, t]

無関係な成分の重要度は0である：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: CriticalitySuccessImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]
Wolfram Research (2012), CriticalitySuccessImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html.

テキスト

Wolfram Research (2012), CriticalitySuccessImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html.

CMS

Wolfram Language. 2012. "CriticalitySuccessImportance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html.

APA

Wolfram Language. (2012). CriticalitySuccessImportance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html

BibTeX

@misc{reference.wolfram_2026_criticalitysuccessimportance, author="Wolfram Research", title="{CriticalitySuccessImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_criticalitysuccessimportance, organization={Wolfram Research}, title={CriticalitySuccessImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html}, note=[Accessed: 09-September-2026]}