WOLFRAM

Wolfram 语言与系统参考资料中心

CriticalitySuccessImportance[rdist,t]

给出 ReliabilityDistribution rdist 中所有组件在时刻 t 的关键成功重要度.

CriticalitySuccessImportance[fdist,t]

给出 FailureDistribution fdist 中所有组件在时刻 t 的关键成功重要度.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
ReliabilityDistribution 模型  
FailureDistribution 模型  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CriticalitySuccessImportance

CriticalitySuccessImportance[rdist,t]

给出 ReliabilityDistribution rdist 中所有组件在时刻 t 的关键成功重要度.

CriticalitySuccessImportance[fdist,t]

给出 FailureDistribution fdist 中所有组件在时刻 t 的关键成功重要度.

更多信息

  • CriticalitySuccessImportance 也被称为关键重要度系数（Criticality Importance Factor）.
  • 组件 的关键成功重要度指的是当系统正常运行时，组件 是促成系统成功的组件的概率.
  • 组件 在时刻 的关键成功重要度由 给出，其中 是组件 的 Birnbaum 重要度， 是组件 正常运行的概率， 是系统正常运行的概率.
  • 结果按照 rdist 或 fdist 分布列表中组件的顺序返回.

范例

打开所有单元 关闭所有单元

基本范例  (3)

两个组件并联，分别具有不同的寿命分布：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

给出结果的顺序与 ReliabilityDistribution 中分布列表的顺序相同：

Wolfram Language code: {Subscript[cs, x], Subscript[cs, y]} = CriticalitySuccessImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[cs, x], Subscript[cs, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

这两个串联组件共同促成系统的正常运行：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalitySuccessImportance[ℛ, t]

使用基于故障树的建模，定义系统：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: CriticalitySuccessImportance[ℱ, t]
Wolfram Language code: Plot[%, {t, 0, 11}, Filling -> Axis]

范围  (17)

ReliabilityDistribution 模型  (9)

两个具有相同寿命分布的组件并联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

这两个组件促成系统正常运行的可能性相等：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

两个具有相同寿命分布的组件串联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

对于一个正常运行的系统， 和 导致成功的概率为1：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

由三个具有相同寿命分布的组件构成的系统，要求其中两个组件正常工作：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

这三个组件促成系统成功的可能性相等：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

一个具有相同寿命分布的简单混合系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]//Simplify

对于正常运行的系统，组件 的正常运行总是对系统有贡献：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

串联后再与一个组件并联的系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]//Simplify

组件 最有可能促成了系统的正常运行：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

计算重要度：

Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]//Simplify

显示当并联组件之一 恶化时重要度的变化：

Wolfram Language code: Table[Plot[Evaluate@MapThread[Tooltip, {cs /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k], {k, 1, 5, 2}]

具有不同分布的一个组件与另外两个并联：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

求在特定时间点处重要度的精确结果：

Wolfram Language code: CriticalitySuccessImportance[ℛ, 3 / 2]//Simplify

给出机器精度的结果：

Wolfram Language code: CriticalitySuccessImportance[ℛ, 1.5]

给出符号式表达式：

Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

可以使用任意有效的 ReliabilityDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalitySuccessImportance[ℛ, t]//Simplify

绘制重要度的图形：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 10}, Filling -> Axis, PlotRange -> All]

分布模拟系统，得到子系统的重要度：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∨r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]

绘制重要度随时间变化的曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {z, r}}], {t, 0, 4}]

FailureDistribution 模型  (8)

两个基本事件之一引发了顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

两个事件防止顶事件发生的可能性相同：

Wolfram Language code: CriticalitySuccessImportance[ℱ, t]//Simplify

两个基本事件共同引发顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

两个事件引发顶事件的可能性相同：

Wolfram Language code: CriticalitySuccessImportance[ℱ, t]//Simplify

一个投票门，其中基本事件具有相同的分布：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

投票门中的相同事件防止故障发生的概率相同：

Wolfram Language code: CriticalitySuccessImportance[ℱ, t]//Simplify

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

计算关键重要度：

Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]//Simplify

如果顶事件尚未发生，事件 最有可能防止其发生：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

显示重要度：

Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]//Simplify

当顶事件尚未发生时，事件 导致其尚未发生的概率为1：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

计算重要度：

Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]//Simplify

显示当基本事件之一 恶化时重要度的变化：

Wolfram Language code: Table[Plot[Evaluate@MapThread[Tooltip, {cs /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k], {k, 1, 5, 2}]

可以使用任意有效的 FailureDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: CriticalitySuccessImportance[ℱ, t]

绘制重要度的图形：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 10}, Filling -> Axis, PlotRange -> All]

分布模拟系统，得到子系统的重要度：

Wolfram Language code: ℱsub = FailureDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∨f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: cs = CriticalitySuccessImportance[ℱ, t]

绘制重要度随时间变化的曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {z, f}}], {t, 0, 4}]

应用  (3)

找出哪个组件是最有可能促成了为时3小时的任务的成功：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[2], WeibullDistribution[1, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℱ = FailureDistribution[(x∨y)∧(z∨v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: csi = CriticalitySuccessImportance[ℱ, t]

显示重要度随时间的变化：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {csi, {x, y, z, v}}], {t, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

对于为时3小时的任务，组件 最有可能促成了系统的成功：

Wolfram Language code: csi /. t -> 3//N

研究一个由一个串联组件和两个并联组件的组成的系统. 根据关键成功重要度，确定哪个组件是最重要的：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = {ExponentialDistribution[5], ExponentialDistribution[1.2], ExponentialDistribution[1]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∨y)∧z, {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];
Wolfram Language code: cs = CriticalitySuccessImportance[ℛ, t]

组件 总是促成系统的成功：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {cs, {x, y, z}}], {t, 0, 0.5}, Filling -> Axis]

假设如下系统：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = {ExponentialDistribution[1], ExponentialDistribution[2], ExponentialDistribution[3]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

计算重要度：

Wolfram Language code: csi = CriticalitySuccessImportance[ℛ, t]//FullSimplify

对于所有 的情况，重要度的顺序确实是 ：

Wolfram Language code: Refine[Reduce[csi[[1]] ≥ csi[[2]] ≥ csi[[3]], t, Reals], t ≥ 0]

属性和关系  (3)

CriticalitySuccessImportance 可以用 Probability 的形式定义：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, 𝒟1}, {y, 𝒟2}}];

所有组件的 BirnbaumImportance：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

用组件可靠度除以系统可靠度作为组件权重：

Wolfram Language code: cw = Map[Probability[τ > t, τ#] / Probability[τ > t, τℛ]&, {𝒟1, 𝒟2}]//Refine[#, t > 0]&

得到的基于成功的关键重要度：

Wolfram Language code: bi cw

与定义比较：

Wolfram Language code: FullSimplify[% - CriticalitySuccessImportance[ℛ, t]]

对于串联系统的所有组件而言，基于成功的关键重要度始终为1：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y∧z, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, WeibullDistribution[α, β]}, {z, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: CriticalitySuccessImportance[ℛ, t]

不相关组件的重要度为0：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: CriticalitySuccessImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]
Wolfram Research (2012)，CriticalitySuccessImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html.

文本

Wolfram Research (2012)，CriticalitySuccessImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html.

CMS

Wolfram 语言. 2012. "CriticalitySuccessImportance." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html.

APA

Wolfram 语言. (2012). CriticalitySuccessImportance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html 年

BibTeX

@misc{reference.wolfram_2026_criticalitysuccessimportance, author="Wolfram Research", title="{CriticalitySuccessImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_criticalitysuccessimportance, organization={Wolfram Research}, title={CriticalitySuccessImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/CriticalitySuccessImportance.html}, note=[Accessed: 09-September-2026]}