Csc

Csc[z]

z の余割を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
Cscの引数はラジアンで与える（度数の角度は，係数Degreeを掛け合せラジアン角にしてから使う）．
1/Sin[z]は自動的にCsc[z]に変換される．分解するときはTrigFactorList[expr]を使う．
特別な引数の場合，Cscは自動的に厳密値を計算する．
Cscは任意の数値精度で評価できる．
Cscは自動的にりストに縫い込まれる． »
CscはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

Cscは，三角法で出会う基本関数の1つの余割関数である．これは，正弦関数の逆関数として定義され，実数について，を単位円の外周に沿って軸から反時計回りにラジアン角として測ることで定義される．Csc[x]は，したがって，弧長の端点の垂直座標の逆数を与える．直角三角形における角の余割についての，学校教科書での同等の定義は，と向かい合う辺の長さと斜辺の長さの比である．
Cscは，引数がの単純な有理倍数の場合は，自動的に厳密値に評価される．より複雑な有理倍数については，FunctionExpandを使って明示的な厳密値が得られることがある．TrigFactorListを使ってCscを含む式をSinおよびCosを含む項に因子分解することができる．度で測られた角を使って引数を指定するときは，記号Degreeを乗数として使うことができる（例：Csc[30 Degree])）．引数として厳密な数式が与えられると，Cscは任意の数値精度に評価できることがある．Cscを含む記号式の役に立つ操作には，TrigToExp，TrigExpand，Simplify，FullSimplify等がある．
Cscは要素単位でリストおよび行列に縫い込まれる．対照的に，MatrixFunctionを使って正方行列の余割（通常のベキを行列ベキで置換した，余割関数についてのベキ級数）を個々の行列要素の余割に対立するものとして得ることができる．
Cscは，FunctionPeriodにあるように，を周期として周期的である．Cscは，恒等式を満足する．これは，ピタゴラスの定理に等しい．正割関数の定義は，定義を使って複素引数にまで拡張することができる．ただし，は自然対数の底である．Cscは整数についてに極を持ち，これらの点で評価するとComplexInfinityになる．Csc[z]は原点付近で級数展開 $sum_(k=0)^infty((-1)^(k+1) 2(2^(2 k-1)-1) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ 持つ．これは，ベルヌーイ(Bernoulli)数BernoulliBによって表すことができる．
Cscの逆関数はArcCscである．双曲線余割はCschで与えられる．他の関連する数学関数にはSec，Sin等がある．

例題

すべて開くすべて閉じる

例 (6)

引数はラジアンで与えられる：

Wolfram Language code: Csc[Pi / 3]

Degreeを用いて引数を度で指定する：

Wolfram Language code: Csc[60Degree]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Csc[x], {x, -Pi / 2, 3 / 2Pi}]

複素数数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Csc[z], {z, -π - I, π + I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[Csc[x], {x, 0, 10}]

特異点における漸近展開：

Wolfram Language code: Series[Csc[x], {x, π, 5}]

スコープ (47)

数値評価 (6)

数値的に評価する：

Wolfram Language code: Csc[1.2]

高精度で評価する：

Wolfram Language code: N[Csc[12 / 10], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: Csc[1.2000000000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: Csc[2.5 + I]

Cscを高精度で効率よく評価する：

Wolfram Language code: Csc[1.2`500]//Timing

Wolfram Language code: Csc[1.2`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Csc[ {{π / 3, π}, {π / 6, -π / 2}}]

MatrixFunctionを使って行列のCsc関数を計算することもできる：

Wolfram Language code: MatrixFunction[Csc[#]&, {{π / 3, π}, {π / 6, -π / 2}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Csc[Interval[{Pi / 6, Pi / 3}]]

Wolfram Language code: Csc[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Csc[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Csc[Around[2, 0.01]]

特定の値 (6)

固定点におけるCscの値：

Wolfram Language code: Table[Csc[n (π/6)], {n, 1, 12, 2}]

無限大における値：

Wolfram Language code: Csc[Infinity]

Wolfram Language code: Csc[ComplexInfinity]

Cscの特異点：

Wolfram Language code: Assuming[m∈Integers, Refine[Csc[π m]]]

Cscの極値：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Csc[π ((1/2) + m)]]]]

Cscの極小値を，極小値の近傍におけるの根として求める：

Wolfram Language code: sol = Solve[D[Csc[x], x] == 0 && 0 < x < π, x]

結果を代入する：

Wolfram Language code: xmin = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[Csc[x], {x, 0, π}, Epilog -> Style[Point[{xmin, Csc[xmin]}], PointSize[Large], Red]]

簡単な厳密値は自動的に生成される：

Wolfram Language code: Csc[Pi / 5]

より複雑な場合にはFunctionExpandを明示的に使う必要がある：

Wolfram Language code: Csc[Pi / 30]

Wolfram Language code: FunctionExpand[%]

可視化 (3)

Csc関数をプロットする：

Wolfram Language code: Plot[Csc[x], {x, 0, 4π}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Csc[z]], {z, -π - π I, π + π I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Sec[z]], {z, -π - π I, π + π I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code:

Table[PolarPlot[Csc[k ϕ], {ϕ, -2π, 2π}, Sequence[Frame -> True, Exclusions -> All, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-5, 5}, {-5, 5}}]], {k, 1, 6}]

関数の特性 (13)

Cscの実領域：

Wolfram Language code: FunctionDomain[Csc[x], x]

複素領域：

Wolfram Language code: FunctionDomain[Csc[z], z, Complexes]

Cscは，開区間からのものを除くすべての実数値に達する：

Wolfram Language code: FunctionRange[Csc[x], x, y]

Cscは，を周期とする周期関数である：

Wolfram Language code: FunctionPeriod[Csc[x], x]

Cscは奇関数である：

Wolfram Language code: Csc[-x]

Cscは鏡特性を有する：

Wolfram Language code: FullSimplify[Csc[Conjugate[z]] == Conjugate[Csc[z]]]

Cscは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Csc[x], x]

しかし，有理型ではある：

Wolfram Language code: FunctionMeromorphic[Csc[x], x]

Cscは特定の値域で単調である：

Wolfram Language code: FunctionMonotonicity[Csc[x], x]

Wolfram Language code: FunctionMonotonicity[{Csc[x], 0 < x < π / 2}, x]

Cscは単射ではない：

Wolfram Language code: FunctionInjective[Csc[x], x]

Wolfram Language code: Plot[{Csc[x], 2}, {x, -2π, 2π}]

Cscは全射ではない：

Wolfram Language code: FunctionSurjective[Csc[x], x]

Wolfram Language code: Plot[{Csc[x], .5}, {x, -2π, 2π}]

Cscは非負でも非正でもない：

Wolfram Language code: FunctionSign[Csc[x], x]

x が π の倍数のとき，特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Csc[x], x]

Wolfram Language code: FunctionDiscontinuities[Csc[x], x]

凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Csc[x], x]

[0,3]の x について凸である：

Wolfram Language code: FunctionConvexity[{Csc[x], 0 < x < 3}, x]

Wolfram Language code: Plot[Csc[x], {x, 0, 3}]

TraditionalFormによる表示：

Wolfram Language code: Csc[z]//TraditionalForm

微分 (3)

一次導関数：

Wolfram Language code: D[Csc[x], x]

高次導関数：

Wolfram Language code: Table[D[Csc[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -2π, 2π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[Csc[x], {x, n}]

積分 (3)

Cscの不定積分：

Wolfram Language code: Integrate[Csc[x], x]

周期上のCscの定積分は0である：

Wolfram Language code: Integrate[Csc[x], {x, π / 6, π / 6 + 2π}, PrincipalValue -> True]

その他の積分例：

Wolfram Language code: Integrate[Csc[x]Cos[x], x]

Wolfram Language code: Integrate[Csc[z]^a, z]

級数展開 (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Csc[x], {x, π / 2, 8}]

の周りのCscの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@Table[Series[Csc[x], {x, π / 2, m}], {m, 2, 6, 2}];
Plot[{Csc[x], terms}, {x, 0, π}, PlotRange -> {0, 4}]

Cscの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Csc[x], {x, 0, n}]

Cscはベキ級数に適用できる：

Wolfram Language code: Csc[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

関数の恒等式と簡約 (6)

倍角のCsc：

Wolfram Language code: Expand[Csc[2x] , Trig -> True]

総和のCsc：

Wolfram Language code: Expand[Csc[x + y] , Trig -> True]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Csc[4x]]

Wolfram Language code: TrigReduce[%]

三角関数の和を積に変換する：

Wolfram Language code: TrigFactor[Csc[x] + Csc[y]]

実変数およびを仮定して展開する：

Wolfram Language code: ComplexExpand[Csc[x + I y]]

複素指数関数に変換する：

Wolfram Language code: TrigToExp[Csc[z]]

関数表現 (4)

Sinを介した表現：

Wolfram Language code: Simplify[1 / Sin[x]]

ベッセル(Bessel)関数を介した表現：

Wolfram Language code: Simplify[Sqrt[ 2 / π / x] / BesselJ[(1/2), x], x ≥ 0]

Wolfram Language code: Simplify[I Sqrt[ 2 / (π I x)] / BesselI[(1/2), I x], x ≥ 0]

SphericalHarmonicYを介した表現：

Wolfram Language code: Simplify[Sqrt[3 / 8 / π] / SphericalHarmonicY[1, -1, θ, 0]]

MeijerGによる表現：

Wolfram Language code: 1 / MeijerGReduce[Sin[x], x]

Wolfram Language code: Activate[%]

アプリケーション (3)

極を自動的に除いてプロットを生成する：

Wolfram Language code: Plot[Csc[x], {x, -2, 6}]

複素引数平面上にプロットを生成する：

Wolfram Language code: Plot3D[Re[Csc[x + I y]], {x, -Pi, 2Pi}, {y, 0, 3}]

微分方程式を解く：

Wolfram Language code: DSolve[(a + x Cot[x]) y[x] + (x + 2 x^2 Cot[x]) Derivative[1][y][x] + x^2 Derivative[2][y][x] == 0, y[x], x]

特性と関係 (12)

余割関数の基本的なパリティと周期性の性質は自動的に適用される：

Wolfram Language code: Csc[x + Pi]

Wolfram Language code: Csc[-x]

Wolfram Language code: Csc[I x]

Wolfram Language code: 1 / Csc[x]

CscをSinとCosに因数分解するのにはTrigFactorListを用いる：

Wolfram Language code: 1 / Sin[x]

Wolfram Language code: TrigFactorList[Csc[x]]

三角関数を含む複雑な式は自動的には簡約されない：

Wolfram Language code: 1 / Csc[Subscript[z, 1] + Subscript[z, 2]] - 2Sin[Subscript[z, 2]]Cos[Subscript[z, 1]]

Wolfram Language code: Simplify[%]

Wolfram Language code: Csc[Conjugate[z]] - Conjugate[Csc[z]]

Wolfram Language code: FullSimplify[%]

追加的な仮定をして簡約する：

Wolfram Language code: Csc[-x + k Pi]

Wolfram Language code: Simplify[%, k∈Integers]

逆関数を用いた構築物：

Wolfram Language code: {Csc[ArcCsc[z]], Csc[2ArcCsc[z]], Csc[3ArcCsc[z]]}

Wolfram Language code: FunctionExpand[%]//Together

1ラジアンは度である：

Wolfram Language code: Csc[1] == CscDegrees[180 / π]//Simplify

三角方程式を解く：

Wolfram Language code: Reduce[3Csc[z]^2 - 6Csc[z - Pi / 6] == -8, z]

ゼロと極について解く：

Wolfram Language code: Reduce[Csc[α x + β] == 0, x]

Wolfram Language code: Reduce[1 / Csc[α x + β] == 0, x]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Csc[z]^2 + 3 Csc[z + Pi / 3] + z == 4, {z, 5}]

多くの数学関数でCscは特殊形として自動的に返される：

Wolfram Language code:

{BesselJ[1 / 2, z]^-1, StruveH[-1 / 2, z]^-1, 1 / MathieuS[1, 0, z], JacobiDS[z, 0], JacobiNS[z, 0], HypergeometricPFQ[{}, {(3/2)}, -z]^-1, MeijerG[{{}, {}}, {{(1/2)}, {0}}, z]^-1}

剰余を記号的・数値的に計算する：

Wolfram Language code: Table[Residue[Csc[z]^k, {z, 0}], {k, 5}]

Wolfram Language code: (1/2π I)NIntegrate[Csc[z], {z, -(1/4), -(I/4), +(1/4), +(I/4), -(1/4)}]

Cscは数値関数である：

Wolfram Language code: Attributes[Csc]

Wolfram Language code: NumericQ[Csc[2 + E]]

考えられる問題 (4)

機械精度の入力では正解を出すのに不十分である：

Wolfram Language code: Csc[10. ^ 30]

代りに任意精度で評価する：

Wolfram Language code: N[Csc[10 ^ 30], 10]

関数の値を正確に近似するためには$MaxExtraPrecisionの設定値を大きくする必要がある：

Wolfram Language code: N[Csc[10 ^ 65], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 70}, N[Csc[10 ^ 65], 20]]

出力精度が入力精度よりはるかに低いあるいは高いことがある：

Wolfram Language code: Csc[3.141592653589793238462643383279502884297]

Wolfram Language code: Csc[1.5707963267948966192213216916397514421]

慣用形では引数の周りに丸カッコが必要である：

Wolfram Language code: csc x

Wolfram Language code: csc(x)

おもしろい例題 (6)

さまざまな積分を計算する：

Wolfram Language code: Integrate[Csc[x], x]

Wolfram Language code: ∫Sin[b z] Csc[c z]ⅆz

Wolfram Language code: ∫z^2 E^b zCsc[a z]ⅆz

余割の積を計算する：

Wolfram Language code: Underoverscript[∏, k = 1, n - 1] Csc[z + (k π/n)]

整数点でCscをプロットする：

Wolfram Language code: ArrayPlot[Table[ArcTan[Abs[Csc[x y]]], {x, -20, 20}, {y, -20, 20}]]

ネストした根基表現を与える：

Wolfram Language code: Csc[(π/2^12)]//FunctionExpand

積分と総和からCscを生成する：

Wolfram Language code: (1/z)Underoverscript[∏, k = 1, ∞](π^2 k^2/π^2 k^2 - z^2)

Wolfram Language code: -2I Underoverscript[∑, k = 1, ∞] (E^I z)^2 k - 1//FullSimplify

Wolfram Language code: Sum[(I I^-1 + 2 k 2^2 k (-1 + 2^1 - 2 k) z^-1 + 2 k BernoulliB[2 k]/(2 k)!), {k, 1, ∞}]//TrigToExp//FullSimplify

Csc[n]は，整数 n における超越数である：

Wolfram Language code: Element[Csc[1], Algebraics]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Csc

詳細

予備知識

例題

例 (6)

スコープ (47)

数値評価 (6)

特定の値 (6)

可視化 (3)

関数の特性 (13)

微分 (3)

積分 (3)

級数展開 (3)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (3)

特性と関係 (12)

考えられる問題 (4)

おもしろい例題 (6)

テキスト

CMS

APA

BibTeX

BibLaTeX

Csc

詳細

予備知識

例題

例 (6)

スコープ (47)

数値評価 (6)

特定の値 (6)

可視化 (3)

関数の特性 (13)

微分 (3)

積分 (3)

級数展開 (3)

関数の恒等式と簡約 (6)

関数表現 (4)

アプリケーション (3)

特性と関係 (12)

考えられる問題 (4)

おもしろい例題 (6)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX