Wolfram 语言与系统参考资料中心

Csc

Csc[z]

给出 z 的余割.

背景

Csc 是余割函数，三角学中的基本函数之一. 它被定义为正弦函数的倒数：. 对于实数变量它的定义如下：设是一个点从轴出发，沿着单位圆的圆周逆时针走过的弧度值，则 Csc[x] 给出了圆弧上这个点纵坐标的倒数. 直角三角形中一个锐角的余割值在教科书上的等价定义是弦长与角对边长的比值.
当变量是的简单有理数倍时，Csc 会自动计算出精确值. 对一些更复杂的有理倍数，FunctionExpand 有时可用于算得显式的精确值. TrigFactorList 可将包含 Csc 的表达式因式分解为包含 Sin 和 Cos 的单项式. 若要使用角度值的变量，则可用符号 Degree 作为乘数（例如 Csc[30 Degree]）. 当给出精确数值表达式作为变量时，Csc 可以算出任意精度的数值结果. 对包含 Csc 的符号表达式，其他适用的操作运算有 TrigToExp、TrigExpand、Simplify 和 FullSimplify.
Csc 自动逐项作用于列表和矩阵. 相比之下，MatrixFunction 则可用于给出整个方阵的余割值（即用矩阵幂次代替普通幂次的余割函数的幂级数）而不是单个矩阵元素的余割值.
Csc 是周期函数，周期为，可由 FunctionPeriod 算出. Csc 满足恒等式，这其实与勾股定理等价. 余割函数的定义可由等式扩展到复数变量上，其中是自然对数的底数. Csc 在且是整数的这些点处取得极值 ComplexInfinity. Csc[z] 在原点处的级数展开为 $sum_(k=0)^infty((-1)^(k+1) 2(2^(2 k-1)-1) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)$ ，可由伯努利数 BernoulliB 构成的项表示.
Csc 的反函数是 ArcCsc. 双曲余割函数是 Csch. 其他相关的数学函数有 Sec 和 Sin.

范例

打开所有单元关闭所有单元

基本范例 (6)

自变量以弧度为单位：

Wolfram Language code: Csc[Pi / 3]

用 Degree 指定自变量以度为单位：

Wolfram Language code: Csc[60Degree]

在实数的一个子集上进行绘图：

Wolfram Language code: Plot[Csc[x], {x, -Pi / 2, 3 / 2Pi}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Csc[z], {z, -π - I, π + I}, PlotLegends -> Automatic]

在 0 处的级数展开式：

Wolfram Language code: Series[Csc[x], {x, 0, 10}]

在奇点处的渐近展开式：

Wolfram Language code: Series[Csc[x], {x, π, 5}]

范围 (47)

数值计算 (6)

数值计算：

Wolfram Language code: Csc[1.2]

以高精度计算：

Wolfram Language code: N[Csc[12 / 10], 50]

输出精度与输入精度相一致：

Wolfram Language code: Csc[1.2000000000000000000000000000000000000000000]

计算复数参数：

Wolfram Language code: Csc[2.5 + I]

在高精度条件下高效计算 Csc：

Wolfram Language code: Csc[1.2`500]//Timing

Wolfram Language code: Csc[1.2`100000];//Timing

自动逐项计算数组中每个元素的值：

Wolfram Language code: Csc[ {{π / 3, π}, {π / 6, -π / 2}}]

或用 MatrixFunction 计算矩阵形式的 Csc 函数：

Wolfram Language code: MatrixFunction[Csc[#]&, {{π / 3, π}, {π / 6, -π / 2}}]

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Csc[Interval[{Pi / 6, Pi / 3}]]

Wolfram Language code: Csc[CenteredInterval[1, 1 / 100]]

Wolfram Language code: Csc[CenteredInterval[2 + 3I, (1 + I) / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Csc[Around[2, 0.01]]

特殊值 (6)

Csc 在固定点上的值：

Wolfram Language code: Table[Csc[n (π/6)], {n, 1, 12, 2}]

无穷处的值：

Wolfram Language code: Csc[Infinity]

Wolfram Language code: Csc[ComplexInfinity]

Csc 的奇点：

Wolfram Language code: Assuming[m∈Integers, Refine[Csc[π m]]]

Csc 的局部极值：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Csc[π ((1/2) + m)]]]]

在最小值的邻域中求 Csc 的局部最小值，以作为的根：

Wolfram Language code: sol = Solve[D[Csc[x], x] == 0 && 0 < x < π, x]

替换结果：

Wolfram Language code: xmin = x /. First[sol]

可视化结果：

Wolfram Language code: Plot[Csc[x], {x, 0, π}, Epilog -> Style[Point[{xmin, Csc[xmin]}], PointSize[Large], Red]]

自动生成简单精确值：

Wolfram Language code: Csc[Pi / 5]

更复杂的情况则需使用 FunctionExpand：

Wolfram Language code: Csc[Pi / 30]

Wolfram Language code: FunctionExpand[%]

可视化 (3)

绘制 Csc 函数：

Wolfram Language code: Plot[Csc[x], {x, 0, 4π}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Csc[z]], {z, -π - π I, π + π I}, IconizedObject[«PlotOptions»]]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Sec[z]], {z, -π - π I, π + π I}, IconizedObject[«PlotOptions»]]

，绘制极坐标图：

Wolfram Language code:

Table[PolarPlot[Csc[k ϕ], {ϕ, -2π, 2π}, Sequence[Frame -> True, Exclusions -> All, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-5, 5}, {-5, 5}}]], {k, 1, 6}]

函数属性 (13)

Csc 的实定义域：

Wolfram Language code: FunctionDomain[Csc[x], x]

复定义域：

Wolfram Language code: FunctionDomain[Csc[z], z, Complexes]

Csc 的值域是开区间之外的所有实数：

Wolfram Language code: FunctionRange[Csc[x], x, y]

Csc 是周期为的周期函数：

Wolfram Language code: FunctionPeriod[Csc[x], x]

Csc 是一个奇函数：

Wolfram Language code: Csc[-x]

Csc 具有镜像属性：

Wolfram Language code: FullSimplify[Csc[Conjugate[z]] == Conjugate[Csc[z]]]

Csc 不是解析函数：

Wolfram Language code: FunctionAnalytic[Csc[x], x]

但是，它是亚纯函数：

Wolfram Language code: FunctionMeromorphic[Csc[x], x]

Csc 在特定范围内是单调的：

Wolfram Language code: FunctionMonotonicity[Csc[x], x]

Wolfram Language code: FunctionMonotonicity[{Csc[x], 0 < x < π / 2}, x]

Csc 不是单射函数：

Wolfram Language code: FunctionInjective[Csc[x], x]

Wolfram Language code: Plot[{Csc[x], 2}, {x, -2π, 2π}]

Csc 不是满射函数：

Wolfram Language code: FunctionSurjective[Csc[x], x]

Wolfram Language code: Plot[{Csc[x], .5}, {x, -2π, 2π}]

Csc 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Csc[x], x]

当 x 是 π 的倍数时，函数有奇点和断点：

Wolfram Language code: FunctionSingularities[Csc[x], x]

Wolfram Language code: FunctionDiscontinuities[Csc[x], x]

既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Csc[x], x]

x 位于 [0,3] 时是凸函数：

Wolfram Language code: FunctionConvexity[{Csc[x], 0 < x < 3}, x]

Wolfram Language code: Plot[Csc[x], {x, 0, 3}]

TraditionalForm 格式:

Wolfram Language code: Csc[z]//TraditionalForm

微分 (3)

一阶导数：

Wolfram Language code: D[Csc[x], x]

高阶导数：

Wolfram Language code: Table[D[Csc[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -2π, 2π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[Csc[x], {x, n}]

积分 (3)

Csc 的不定积分：

Wolfram Language code: Integrate[Csc[x], x]

Csc 在一个周期上的定积分为 0：

Wolfram Language code: Integrate[Csc[x], {x, π / 6, π / 6 + 2π}, PrincipalValue -> True]

更多积分：

Wolfram Language code: Integrate[Csc[x]Cos[x], x]

Wolfram Language code: Integrate[Csc[z]^a, z]

级数展开式 (3)

使用 Series 求泰勒级数展开式：

Wolfram Language code: Series[Csc[x], {x, π / 2, 8}]

在周围绘制 Csc 的前三个近似值：

Wolfram Language code:

terms = Normal@Table[Series[Csc[x], {x, π / 2, m}], {m, 2, 6, 2}];
Plot[{Csc[x], terms}, {x, 0, π}, PlotRange -> {0, 4}]

Csc 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Csc[x], {x, 0, n}]

Csc 可被应用于幂级数：

Wolfram Language code: Csc[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

函数恒等式和化简 (6)

倍角的 Csc：

Wolfram Language code: Expand[Csc[2x] , Trig -> True]

和的 Csc：

Wolfram Language code: Expand[Csc[x + y] , Trig -> True]

转换多倍角表达式：

Wolfram Language code: TrigExpand[Csc[4x]]

Wolfram Language code: TrigReduce[%]

将三角函数的和形式转换为积形式：

Wolfram Language code: TrigFactor[Csc[x] + Csc[y]]

假定实数变量和的展开：

Wolfram Language code: ComplexExpand[Csc[x + I y]]

转换为复数指数：

Wolfram Language code: TrigToExp[Csc[z]]

函数表示 (4)

用 Sin 表示：

Wolfram Language code: Simplify[1 / Sin[x]]

用贝塞尔函数来表示：

Wolfram Language code: Simplify[Sqrt[ 2 / π / x] / BesselJ[(1/2), x], x ≥ 0]

Wolfram Language code: Simplify[I Sqrt[ 2 / (π I x)] / BesselI[(1/2), I x], x ≥ 0]

用 SphericalHarmonicY 表示：

Wolfram Language code: Simplify[Sqrt[3 / 8 / π] / SphericalHarmonicY[1, -1, θ, 0]]

用 MeijerG 来表示：

Wolfram Language code: 1 / MeijerGReduce[Sin[x], x]

Wolfram Language code: Activate[%]

应用 (3)

根据极点的移动产生图形：

Wolfram Language code: Plot[Csc[x], {x, -2, 6}]

在复平面生成图形：

Wolfram Language code: Plot3D[Re[Csc[x + I y]], {x, -Pi, 2Pi}, {y, 0, 3}]

求解微分方程：

Wolfram Language code: DSolve[(a + x Cot[x]) y[x] + (x + 2 x^2 Cot[x]) Derivative[1][y][x] + x^2 Derivative[2][y][x] == 0, y[x], x]

属性和关系 (12)

自动应用余割函数的奇偶性和周期性：

Wolfram Language code: Csc[x + Pi]

Wolfram Language code: Csc[-x]

Wolfram Language code: Csc[I x]

Wolfram Language code: 1 / Csc[x]

用 TrigFactorList 将 Csc 展开为 Sin 和 Cos：

Wolfram Language code: 1 / Sin[x]

Wolfram Language code: TrigFactorList[Csc[x]]

包含复杂表达式的三角函数不会自动化简：

Wolfram Language code: 1 / Csc[Subscript[z, 1] + Subscript[z, 2]] - 2Sin[Subscript[z, 2]]Cos[Subscript[z, 1]]

Wolfram Language code: Simplify[%]

Wolfram Language code: Csc[Conjugate[z]] - Conjugate[Csc[z]]

Wolfram Language code: FullSimplify[%]

附加假设条件的化简：

Wolfram Language code: Csc[-x + k Pi]

Wolfram Language code: Simplify[%, k∈Integers]

由反函数组成：

Wolfram Language code: {Csc[ArcCsc[z]], Csc[2ArcCsc[z]], Csc[3ArcCsc[z]]}

Wolfram Language code: FunctionExpand[%]//Together

1 弧度是度:

Wolfram Language code: Csc[1] == CscDegrees[180 / π]//Simplify

求解三角方程：

Wolfram Language code: Reduce[3Csc[z]^2 - 6Csc[z - Pi / 6] == -8, z]

求解零点和极点：

Wolfram Language code: Reduce[Csc[α x + β] == 0, x]

Wolfram Language code: Reduce[1 / Csc[α x + β] == 0, x]

求超越方程的数值根：

Wolfram Language code: FindRoot[Csc[z]^2 + 3 Csc[z + Pi / 3] + z == 4, {z, 5}]

Csc 出现在许多数学方程的特例中：

Wolfram Language code:

{BesselJ[1 / 2, z]^-1, StruveH[-1 / 2, z]^-1, 1 / MathieuS[1, 0, z], JacobiDS[z, 0], JacobiNS[z, 0], HypergeometricPFQ[{}, {(3/2)}, -z]^-1, MeijerG[{{}, {}}, {{(1/2)}, {0}}, z]^-1}

计算符号余数和数值余数：

Wolfram Language code: Table[Residue[Csc[z]^k, {z, 0}], {k, 5}]

Wolfram Language code: (1/2π I)NIntegrate[Csc[z], {z, -(1/4), -(I/4), +(1/4), +(I/4), -(1/4)}]

Csc 是一个数值函数：

Wolfram Language code: Attributes[Csc]

Wolfram Language code: NumericQ[Csc[2 + E]]

可能存在的问题 (4)

机器精度输入不足以获得正确结果：

Wolfram Language code: Csc[10. ^ 30]

使用精确输入，得到正确结果：

Wolfram Language code: N[Csc[10 ^ 30], 10]

需要把 $MaxExtraPrecision 设成较大的值才能精确近似函数值：

Wolfram Language code: N[Csc[10 ^ 65], 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 70}, N[Csc[10 ^ 65], 20]]

输出精度可以远大于或远小于输入精度：

Wolfram Language code: Csc[3.141592653589793238462643383279502884297]

Wolfram Language code: Csc[1.5707963267948966192213216916397514421]

在传统格式中，需要在自变量外加上圆括号：

Wolfram Language code: csc x

Wolfram Language code: csc(x)

巧妙范例 (6)

计算各类积分：

Wolfram Language code: Integrate[Csc[x], x]

Wolfram Language code: ∫Sin[b z] Csc[c z]ⅆz

Wolfram Language code: ∫z^2 E^b zCsc[a z]ⅆz

计算余割的积：

Wolfram Language code: Underoverscript[∏, k = 1, n - 1] Csc[z + (k π/n)]

在整数点绘制 Csc：

Wolfram Language code: ArrayPlot[Table[ArcTan[Abs[Csc[x y]]], {x, -20, 20}, {y, -20, 20}]]

给出嵌套根式表示：

Wolfram Language code: Csc[(π/2^12)]//FunctionExpand

从积分和求和产生 Csc：

Wolfram Language code: (1/z)Underoverscript[∏, k = 1, ∞](π^2 k^2/π^2 k^2 - z^2)

Wolfram Language code: -2I Underoverscript[∑, k = 1, ∞] (E^I z)^2 k - 1//FullSimplify

Wolfram Language code: Sum[(I I^-1 + 2 k 2^2 k (-1 + 2^1 - 2 k) z^-1 + 2 k BernoulliB[2 k]/(2 k)!), {k, 1, ∞}]//TrigToExp//FullSimplify

n 为整数时，Csc[n] 是一个超越数：

Wolfram Language code: Element[Csc[1], Algebraics]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Csc

更多信息

背景

范例

基本范例 (6)

范围 (47)

数值计算 (6)

特殊值 (6)

可视化 (3)

函数属性 (13)

微分 (3)

积分 (3)

级数展开式 (3)

函数恒等式和化简 (6)

函数表示 (4)

应用 (3)

属性和关系 (12)

可能存在的问题 (4)

巧妙范例 (6)

文本

CMS

APA

BibTeX

BibLaTeX

Csc

更多信息

背景

范例

基本范例 (6)

范围 (47)

数值计算 (6)

特殊值 (6)

可视化 (3)

函数属性 (13)

微分 (3)

积分 (3)

级数展开式 (3)

函数恒等式和化简 (6)

函数表示 (4)

应用 (3)

属性和关系 (12)

可能存在的问题 (4)

巧妙范例 (6)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX