WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CubeRoot[x]

x の実数値の立方根を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

CubeRoot

CubeRoot[x]

x の実数値の立方根を与える．

詳細

  • CubeRoot[x]は実数 x について実数値の立方根を与える．
  • CubeRoot[x]の記号 x については，x は実数値であると想定される．
  • CubeRootは任意の数値精度で評価することができる．
  • CubeRootは自動的にリストに縫い込まれる．
  • StandardFormでは，CubeRoot[x]はと表される．
  • は，cbrtで入力できる．
  • ∛z は入力に使うこともできる．∛ 記号はcbrtiあるいは\[CubeRoot]で入力する．

例題

すべて開く すべて閉じる

例  (5)

CubeRootは実数根を与える：

Wolfram Language code: CubeRoot[-27]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[CubeRoot[x], {x, -2, 2}]

cbrtを使ってを入力する：

Wolfram Language code: Surd[-4.5, 3]

これは(Power[x,1/3])と同じではない点に注意のこと：

Wolfram Language code: -4.5^(1/(3))

との実部と虚部を実数上で比較する：

Wolfram Language code: ReImPlot[{x^(1/(3)), Surd[x, 3]}, {x, -4, 4}, PlotLegends -> Automatic]

級数展開：

Wolfram Language code: Series[CubeRoot[x], {x, -1, 5}]

スコープ  (36)

数値評価  (6)

数値的に評価する：

Wolfram Language code: CubeRoot[128.]

高精度で評価する：

Wolfram Language code: N[CubeRoot[18], 100]

出力精度は入力精度に従う：

Wolfram Language code: CubeRoot[0.2111111555555555555111111111111111]

高精度で効率よく評価する：

Wolfram Language code: CubeRoot[12`100]//Timing
Wolfram Language code: CubeRoot[181`1000000];//Timing

CubeRootは要素単位でリストと行列に縫い込まれる：

Wolfram Language code: CubeRoot[{0, 1.5, 8, Infinity}]
Wolfram Language code: CubeRoot[(⁠| | | | :- | :---- | | 1 | u | | v | 3.375 |⁠)]//MatrixForm

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: CubeRoot[ Around[2 / 3, 0.001]]

配列の要素ごとの値を計算する：

Wolfram Language code: CubeRoot[{{1 / 2, -1}, {-5 / 3, 1 / 2}}]

MatrixFunctionを使って行列のCubeRoot関数を計算することもできる：

Wolfram Language code: MatrixFunction[CubeRoot, {{1 / 2, -1}, {-5 / 3, 1 / 2}}]

特定の値  (4)

固定点におけるCubeRootの値：

Wolfram Language code: Table[CubeRoot[n ], {n, {-27, -8, -1, 1, 8, 27}}]

ゼロにおける値：

Wolfram Language code: CubeRoot[0]

無限大における値：

Wolfram Language code: CubeRoot[Infinity]
Wolfram Language code: CubeRoot[-Infinity]

Solveを使ってとなるような の値を求める：

Wolfram Language code: Solve[CubeRoot[x] == 3 / 2]

結果を代入する：

Wolfram Language code: xval = x /. First[%]

結果を可視化する：

Wolfram Language code: Plot[CubeRoot[x], {x, -10, 10}, Epilog -> Style[Point[{xval, CubeRoot[xval]}], PointSize[Large], Red]]

可視化  (3)

CubeRoot関数をプロットする：

Wolfram Language code: Plot[CubeRoot[x], {x, -3, 3}]

の絶対値と引数(sign)を可視化する：

Wolfram Language code: AbsArgPlot[Surd[x, 3], {x, -4, 4}, PlotLegends -> Automatic]

関数は について同じ絶対値を持つが，引数は異なる：

Wolfram Language code: AbsArgPlot[x^(1/(3)), {x, -4, 4}, PlotLegends -> Automatic]

の極プロット：

Wolfram Language code: PolarPlot[CubeRoot[ϕ], {ϕ, 0, 8π}, Frame -> True]

関数の特性  (9)

CubeRootは実数について定義される：

Wolfram Language code: FunctionDomain[CubeRoot[x], x]
Wolfram Language code: FunctionDomain[CubeRoot[x], x, Complexes]

CubeRootの範囲はすべての実数である：

Wolfram Language code: FunctionRange[CubeRoot[x], x, y]
Wolfram Language code: FunctionRange[CubeRoot[x], x, y, Complexes]//Reduce

∛ 記号を \[CubeRoot]として入力し，続けて数字を入力する：

Wolfram Language code: ∛-1000

は解析関数ではない：

Wolfram Language code: FunctionAnalytic[Surd[``x``, 3], x]

は有理型でもない：

Wolfram Language code: FunctionMeromorphic[Surd[``x``, 3], x]

は非減少である：

Wolfram Language code: FunctionMonotonicity[Surd[``x``, 3], x]

は単射である：

Wolfram Language code: FunctionInjective[Surd[``x``, 3], x]
Wolfram Language code: Plot[{Surd[``x``, 3], 1}, {x, -5, 5}]

全射でもある：

Wolfram Language code: FunctionSurjective[Surd[``x``, 3], x]
Wolfram Language code: Plot[{Surd[``x``, 3], -2}, {x, -10, 5}]

は非負でも非正でもない：

Wolfram Language code: FunctionSign[Surd[``x``, 3], x]

は実数上で連続であるが に特異点を持つ：

Wolfram Language code: FunctionContinuous[Surd[``x``, 3], x]
Wolfram Language code: FunctionSingularities[Surd[``x``, 3], x]

微分不可能なので特異なのである：

Wolfram Language code: Limit[(CubeRoot[h] - CubeRoot[0]/h), h -> 0]


は凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Surd[``x``, 3], x]

微分  (3)

x についての一次導関数：

Wolfram Language code: D[CubeRoot[x], x]

x についての高次導関数：

Wolfram Language code: Table[D[CubeRoot[x], {x, k}], {k, 1, 3}]//FullSimplify

x について高次導関数をプロットする：

Wolfram Language code: Plot[%, {x, -7, 7}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

x についての 次導関数の式：

Wolfram Language code: D[CubeRoot[x], {x, k}]// FullSimplify

積分  (4)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[CubeRoot[x], x]
Wolfram Language code: FullSimplify[D[Integrate[CubeRoot[x], x], x] == CubeRoot[x]]

不定積分を確かめる：

Wolfram Language code: FullSimplify[D[%, x] == CubeRoot[x]]

定積分：

Wolfram Language code: Integrate[CubeRoot[x], {x, 0, 4}]

対称区間上のCubeRootの定積分は0である：

Wolfram Language code: Integrate[CubeRoot[x], {x, -4, 4}]

その他の積分例：

Wolfram Language code: Integrate[Exp[x]CubeRoot[x], x]//FullSimplify
Wolfram Language code: Integrate[Sin[x]CubeRoot[x], {x, 0, 5}]//FullSimplify

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[CubeRoot[x], {x, 1, 4}]

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[CubeRoot[x], {x, 1, m}], {m, 1, 5, 2}]; Plot[{CubeRoot[x], terms}, {x, -1, 3}]

SeriesCoefficientを使った級数展開の一般項：

Wolfram Language code: SeriesCoefficient[CubeRoot[x], {x, 1, n}]

一次フーリエ(Fourier)級数：

Wolfram Language code: FourierSeries[CubeRoot[x], x, 1]// FullSimplify

生成点におけるテイラー(Taylor)展開：

Wolfram Language code: Series[CubeRoot[x], {x, x0, 2}]// FullSimplify

関数の恒等式と簡約  (3)

主定義：

Wolfram Language code: CubeRoot[x] == Surd[x, 3]

積はFullSimplifyを使って組み合せることができる：

Wolfram Language code: CubeRoot[x]CubeRoot[y] == CubeRoot[x y]

CubeRootは整数指数と可換である：

Wolfram Language code: Reduce[Table[CubeRoot[x ^ n] == CubeRoot[x] ^ n, {n, 10}], Reals]

アプリケーション  (1)

CubeRootを含む微分方程式を解く：

Wolfram Language code: DSolve[3 x y'[x] - y[x] == 0, y[x], x]
Wolfram Language code: DSolve[{CubeRoot[y[x]] - y'[x] == 0, y[0] == 1}, y[x], x]//Quiet

特性と関係  (5)

CubeRootは実数入力に対してしか定義されない：

Wolfram Language code: FunctionDomain[CubeRoot[x], x, ℂ]

CubeRootは実数上で全単射である：

Wolfram Language code: FunctionBijective[CubeRoot[x], x]

CubeRootを使って実数の立方根を求める：

Wolfram Language code: CubeRoot[-8.]

Power[x,1/3]またはを使って主複素立方根を求める：

Wolfram Language code: -8.^(1/(3))

CubeRootの母関数：

Wolfram Language code: GeneratingFunction[CubeRoot[n], n, x]
Wolfram Language code: Series[%, {x, 0, 5}]

CubeRootを含む関数の積分を求める：

Wolfram Language code: Integrate[(1 + x^3) CubeRoot[x], {x, -1, 1}]

関数と，関数と 軸の間の符号付きの領域を可視化する：

Wolfram Language code: Plot[(1 + x^3) CubeRoot[x], {x, -1, 1}, Filling -> Axis, FillingStyle -> {RGBColor[0.880722, 0.611041, 0.142051, 0.5], RGBColor[0.368417, 0.506779, 0.709798, 0.5]}]

考えられる問題  (1)

負の実軸上では，CubeRoot[x]はPower[x,1/3]によって返された主根とは異なる：

Wolfram Language code: ReImPlot[Evaluate[{CubeRoot[x], Power[x, 1 / 3]}], {x, -1, 1}, PlotTheme -> "Detailed"]
Wolfram Research (2012), CubeRoot, Wolfram言語関数， https://reference.wolfram.com/language/ref/CubeRoot.html （2020年に更新）.

テキスト

Wolfram Research (2012), CubeRoot, Wolfram言語関数， https://reference.wolfram.com/language/ref/CubeRoot.html （2020年に更新）.

CMS

Wolfram Language. 2012. "CubeRoot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/CubeRoot.html.

APA

Wolfram Language. (2012). CubeRoot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CubeRoot.html

BibTeX

@misc{reference.wolfram_2026_cuberoot, author="Wolfram Research", title="{CubeRoot}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CubeRoot.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cuberoot, organization={Wolfram Research}, title={CubeRoot}, year={2020}, url={https://reference.wolfram.com/language/ref/CubeRoot.html}, note=[Accessed: 07-September-2026]}