WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CumulantGeneratingFunction[dist,t]

分布 dist についてのキュムラント母関数を変数 t の関数として与える．

CumulantGeneratingFunction[dist,{t1,t2,…}]

多変量分布 dist のキュムラント母関数を変数 t1, t2, … の関数として与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CumulantGeneratingFunction

CumulantGeneratingFunction[dist,t]

分布 dist についてのキュムラント母関数を変数 t の関数として与える．

CumulantGeneratingFunction[dist,{t1,t2,…}]

多変量分布 dist のキュムラント母関数を変数 t1, t2, … の関数として与える．

詳細

例題

すべて開く すべて閉じる

例  (3)

一変量連続分布のキュムラント母関数を計算する：

Wolfram Language code: CumulantGeneratingFunction[NormalDistribution[μ, σ], t]

一変量離散分布のキュムラント母関数：

Wolfram Language code: CumulantGeneratingFunction[PoissonDistribution[μ], t]

多変量分布のキュムラント母関数：

Wolfram Language code: CumulantGeneratingFunction[BinormalDistribution[ρ], {t1, t2}]

スコープ  (5)

定式化されている分布のキュムラント母関数を計算する：

Wolfram Language code: CumulantGeneratingFunction[ProbabilityDistribution[(3/4)Sqrt[(1 + x/2)], {x, -1, 1}], t]

確率変量の関数のキュムラント母関数を求める：

Wolfram Language code: CumulantGeneratingFunction[TransformedDistribution[u z, {uUniformDistribution[], zNormalDistribution[]}], t]

データ分布のキュムラント母関数を計算する：

Wolfram Language code: hdist = HistogramDistribution[ExampleData[{"Statistics", "FatigueLifeFailures"}]]
Wolfram Language code: CumulantGeneratingFunction[hdist, t]

切断分布のキュムラント母関数を求める：

Wolfram Language code: CumulantGeneratingFunction[TruncatedDistribution[{-10, 10}, CauchyDistribution[0, 1]], t]

ランダム過程のスライス分布についてキュムラント母関数を求める：

Wolfram Language code: CumulantGeneratingFunction[PoissonProcess[μ][s], t]

アプリケーション  (5)

2つの独立した確率変数の差のキュムラント母関数は，正の符号の引数を持つ両者のキュムラント母関数の和に等しい：

Wolfram Language code: TransformedDistribution[x - y, {xPoissonDistribution[μ], yPoissonDistribution[λ]}]
Wolfram Language code: CumulantGeneratingFunction[SkellamDistribution[μ, λ], t]
Wolfram Language code: % == CumulantGeneratingFunction[PoissonDistribution[μ], t] + CumulantGeneratingFunction[PoissonDistribution[λ], -t]

中心極限定理を説明する：

Wolfram Language code: dist = LaplaceDistribution[μ, σ];

標準化された確率変量のキュムラント母関数を求める：

Wolfram Language code: cgf[t_] = CumulantGeneratingFunction[TransformedDistribution[(x - Mean[dist]) / StandardDeviation[dist], xdist], t]

で再スケールされた，標準化された 個の確率変量の総和について，モーメント母関数を求める：

Wolfram Language code: n * cgf[t / Sqrt[n]]

大きい 極限を求める：

Wolfram Language code: Limit[n * cgf[t / Sqrt[n]], n -> Infinity]

標準正規分布のモーメント母関数と比較する：

Wolfram Language code: CumulantGeneratingFunction[NormalDistribution[], t]

GammaDistributionに従った損失に体する保険を掛ける，エッシャー(Esscher)の保険料を求める：

Wolfram Language code: D[CumulantGeneratingFunction[GammaDistribution[α, β], h], h]

定義と比較する：

Wolfram Language code: (Expectation[x Exp[h x], xGammaDistribution[α, β]]/Expectation[Exp[h x], xGammaDistribution[α, β]])

生存関数 のBernstein–Chernoff限界を構築する：

Wolfram Language code: dist = BinomialDistribution[n, 1 / 2]; ℐ[t_, x_] = t * x - CumulantGeneratingFunction[dist, t]; k = Mean[dist] + u StandardDeviation[dist]; assumps = t > 0∧n > 0∧k < n∧u > 0;
Wolfram Language code: {bound} = Simplify[Exp[-ℐ[t, k]] /. Solve[D[ℐ[t, k], t] == 0 && assumps, t, Reals], assumps]
Wolfram Language code: Table[LogPlot[{SurvivalFunction[dist, k], bound}, {u, 0, 5}, PlotPoints -> n], {n, {50, 100, 500, 1000}}]

大きい による限界近似：

Wolfram Language code: Series[bound, {n, ∞, 2}]//Simplify

VarianceGammaDistributionのPDFについてのDanielの鞍点近似を構築する：

Wolfram Language code: vgd = VarianceGammaDistribution[7 / 3, 3, -1, 0]; cgf[t_] = CumulantGeneratingFunction[vgd, t]

確率密度関数 の引数に関連する鞍点を求める：

Wolfram Language code: sol = Solve[cgf'[t] == x, t]

原点を含むすべての実数 について有効な解を選ぶ：

Wolfram Language code: Limit[t /. sol, x -> 0]
Wolfram Language code: ts = Last[t /. sol]

近似は鞍点におけるキュムラント母関数を使って構築される：

Wolfram Language code: approxPDF[x_] = (1/Sqrt[2Pi cgf''[ts]])Exp[cgf[ts] - ts x]//FullSimplify

正規化された定数を求める：

Wolfram Language code: norm = NIntegrate[approxPDF[x], {x, -Infinity, Infinity}]

近似を厳密密度と比較する：

Wolfram Language code: Plot[{approxPDF[x] / norm, PDF[vgd, x]}, {x, -4, 4}, PlotLegends -> {"Saddlepoint approximation", "Exact density"}]

特性と関係  (3)

CumulantGeneratingFunctionの指数関数はMomentGeneratingFunctionを返す：

Wolfram Language code: CumulantGeneratingFunction[NormalDistribution[μ, σ], t]
Wolfram Language code: Exp[%] == MomentGeneratingFunction[NormalDistribution[μ, σ], t]

CumulantGeneratingFunctionは連続するキュムラントの指数母関数である：

Wolfram Language code: Cumulant[PoissonDistribution[μ], r]
Wolfram Language code: ExponentialGeneratingFunction[%, r, t]

CumulantGeneratingFunctionを直接使う：

Wolfram Language code: CumulantGeneratingFunction[PoissonDistribution[μ], t]

キュムラント はに等しい：

Wolfram Language code: Cumulant[UniformDistribution[{0, 1}], 4]
Wolfram Language code: Limit[D[CumulantGeneratingFunction[UniformDistribution[{0, 1}], t], {t, 4}], t -> 0]

SeriesCoefficientによる形式を使う：

Wolfram Language code: With[{r = 4}, SeriesCoefficient[CumulantGeneratingFunction[UniformDistribution[{0, 1}], t], {t, 0, r}]r!]

考えられる問題  (2)

裾部が長い分布の中にはいくつかの低次数のキュムラントしか定義できないものもある：

Wolfram Language code: Table[Cumulant[ParetoDistribution[1, 4], r], {r, 5}]

これに相応して，CumulantGeneratingFunctionも定義されない：

Wolfram Language code: CumulantGeneratingFunction[ParetoDistribution[1, 4], t]

CumulantGeneratingFunctionは閉形式では常に既知である訳ではない：

Wolfram Language code: CumulantGeneratingFunction[LogNormalDistribution[μ, σ], t]

Cumulantを使って直接キュムラントを求める：

Wolfram Language code: Cumulant[LogNormalDistribution[μ, σ], 3]

おもしろい例題  (1)

一変量分布についての累積分布関数を複素平面上で可視化する：

Wolfram Language code: dists = {NegativeBinomialDistribution[10, 1 / 3], PoissonDistribution[3], BorelTannerDistribution[5 / 6, 10], ExponentialDistribution[1], BirnbaumSaundersDistribution[1, 1 / 3], HyperbolicDistribution[2, 1, 1, 2]};
Wolfram Language code: Table[Plot3D[Re[CumulantGeneratingFunction[𝒟, x + I y]]//Evaluate, {x, -2, 2}, {y, -4, 4}, Mesh -> None, ImageSize -> 200, PlotLabel -> 𝒟], {𝒟, dists}]
Wolfram Research (2010), CumulantGeneratingFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html.

テキスト

Wolfram Research (2010), CumulantGeneratingFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html.

CMS

Wolfram Language. 2010. "CumulantGeneratingFunction." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html.

APA

Wolfram Language. (2010). CumulantGeneratingFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html

BibTeX

@misc{reference.wolfram_2026_cumulantgeneratingfunction, author="Wolfram Research", title="{CumulantGeneratingFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cumulantgeneratingfunction, organization={Wolfram Research}, title={CumulantGeneratingFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/CumulantGeneratingFunction.html}, note=[Accessed: 12-September-2026]}