WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DEigenvalues[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

線形微分演算子 ℒ について，領域 Ω 上で最も小さい n 個の固有値を与える．

DEigenvalues[eqns,u,t,{x,y,…}∈Ω,n]

時間依存微分方程式 eqns の解 u についての固有値を与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
1D  
2D  
3D  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DEigenvalues

DEigenvalues[ℒ[u[x,y,…]],u,{x,y,…}∈Ω,n]

線形微分演算子 ℒ について，領域 Ω 上で最も小さい n 個の固有値を与える．

DEigenvalues[eqns,u,t,{x,y,…}∈Ω,n]

時間依存微分方程式 eqns の解 u についての固有値を与える．

詳細とオプション

  • DEigenvaluesは，常微分演算子および偏微分演算子について，指定の境界条件で固有値を計算することができる．
  • DEigenvaluesは，最も小さい n 個の固有値 λiのリスト{λ1,…,λn}を与える．
  • 微分演算子 ℒ についての固有値と固有関数のペア{λi,ui}は ℒ[ui[x,y,…]]==λi ui[x,y,…]を満足する．
  • 同次DirichletCondition境界条件あるいは同次NeumannValue境界条件が含まれることがある．非同次境界条件は，対応する同次境界条件で置換される．
  • 境界 ∂Ωについて境界条件が指定されていない場合は，ノイマン(Neumann)0条件を指定することに等しい．
  • 方程式 eqns はDSolveにおけるように指定される．
  • N[DEigenvalues[…]]は，記号的に計算できない固有値についてはNDEigenvaluesを呼び出す．
  • Assumptionsオプションを使ってパラメータについての仮定を指定することができる．

例題

すべて開く すべて閉じる

例  (2)

[0,π]上で，ラプラス(Laplace)演算子の最も小さい4つの固有値を求める：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, π}, 4]

辺を固定した円筒膜について，最初の6つの固有値を計算する：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 6]//TraditionalForm
Wolfram Language code: N[%]

スコープ  (17)

1D  (8)

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

同次ディリクレ(Dirichlet)境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

区間内の最も小さい5つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, π}, 5]

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

同次ノイマン境界条件を指定する：

Wolfram Language code: ℬ = NeumannValue[0, True];

区間内の最も小さい5つの固有値を求める：

Wolfram Language code: DEigenvalues[ℒ + ℬ, u[x], {x, 0, π}, 5]

次は等しい：

Wolfram Language code: DEigenvalues[ℒ, u[x], {x, 0, π}, 5]

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == 0];

同次ノイマン境界条件を指定する：

Wolfram Language code: ℬ2 = NeumannValue[0, x == π];

区間内で最も小さい5つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5]

番目の固有値を求める：

Wolfram Language code: FindSequenceFunction[%, n]//Factor

ラプラス演算子の固有値について記号式を求める：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, a, b}, 3]

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ1 = DirichletCondition[u[x] == 0, x == π];

同次非零ノイマン境界条件を指定する：

Wolfram Language code: ℬ2 = NeumannValue[-u[x] / 3, x == 0];

区間内の最も小さい5つの固有値を求める：

Wolfram Language code: vals = DEigenvalues[{ℒ + ℬ2, ℬ1}, u[x], {x, 0, π}, 5];
Wolfram Language code: vals[[1]]//TraditionalForm

エアリー(Airy)演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x] == 0, True];

区間内の最も小さい3つの固有値を求める：

Wolfram Language code: vals = DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, 1}, 3];

固有値は超越方程式の根である：

Wolfram Language code: vals//TraditionalForm

固有値についての数値近似：

Wolfram Language code: N[vals, 20]

エアリー演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x], {x}] + x u[x];

同次ノイマン境界条件を指定する：

Wolfram Language code: ℬ = NeumannValue[0, True];

区間内で最も小さい5つの固有値と固有関数を求める：

Wolfram Language code: vals = DEigenvalues[{ℒ + ℬ}, u[x], {x, 0, 1}, 5];

固有値は超越方程式の根である：

Wolfram Language code: vals[[1]]//TraditionalForm

同次ディリクレ境界条件で熱伝導方程式を指定する：

Wolfram Language code: {ℒ, ℬ} = {D[u[t, x], t] == Laplacian[u[t, x], {x}], DirichletCondition[u[t, x] == 0, True]};

最も小さい4つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[t, x], t, {x, 0, π}, 4]

2D  (5)

同次ディリクレ境界条件でラプラス演算子を指定する：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]};

長方形内で最も小さい9つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, 0, π}, {y, 0, π}, 9]

同次ノイマン境界条件でラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}] + NeumannValue[0, True];

長方形内で最も小さい4つの固有値を求める：

Wolfram Language code: DEigenvalues[ℒ, u[x, y], {x, 0, π}, {y, 0, π}, 4]

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

単位円板上の演算子の最も小さい4つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[], 4]//TraditionalForm

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

三角形内の最も小さい6つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Triangle[], 6]

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y], {x, y}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y] == 0, True];

円板の扇形内の最も小さい4つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y], {x, y}∈Disk[{0, 0}, 1, {0, Pi / 5}], 4]//TraditionalForm

3D  (4)

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

直方体内の最も小さい7つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cuboid[{2, 1, 1}, {4, 2, 3}], 7]

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

円柱内の最も小さい5つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Cylinder[{{0, 0, 0}, {0, 0, 5}}, 2], 5]//TraditionalForm

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

球体内の最も小さい7つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Ball[{0, 0, 0}, 2], 7]//TraditionalForm

ラプラス演算子を指定する：

Wolfram Language code: ℒ = -Laplacian[u[x, y, z], {x, y, z}];

同次ディリクレ境界条件を指定する：

Wolfram Language code: ℬ = DirichletCondition[u[x, y, z] == 0, True];

角柱内の最も小さい7つの固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x, y, z], {x, y, z}∈Prism[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 2}, {1, 0, 2}, {0, 1, 2}}], 7]

特性と関係  (3)

NDEigenvaluesを使って数値による固有値と固有ベクトルを求める：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

厳密な固有値：

Wolfram Language code: exacteigvals = DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

数値による固有値：

Wolfram Language code: numeigvals = NDEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

DEigensystemを使って微分演算子についての固有系を求める：

Wolfram Language code: {ℒ, ℬ} = {-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]};

固有値を求める：

Wolfram Language code: DEigenvalues[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]

固有系を求める：

Wolfram Language code: {vals, funs} = DEigensystem[{ℒ, ℬ}, u[x], {x, 0, Pi}, 3]
Wolfram Language code: vals

記号評価が失敗した場合は，N[DEigenvalues[…]]を適用してNDEigenvaluesを呼び出す：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}] + E ^ (-x ^ 3 + x) u[x, y], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Rectangle[], 4]
Wolfram Language code: N[%]

考えられる問題  (2)

非同次ディリクレ条件は同次の条件で置換される：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 1, True]}, u[x], {x, 0, 1}, 2]

同じ結果：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}], DirichletCondition[u[x] == 0, True]}, u[x], {x, 0, 1}, 2]

非同次ノイマン値は同次の値で置換される：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x], {x}] + NeumannValue[1, True]}, u[x], {x, 0, 1}, 2]

同じ結果：

Wolfram Language code: DEigenvalues[-Laplacian[u[x], {x}], u[x], {x, 0, 1}, 2]
Wolfram Research (2015), DEigenvalues, Wolfram言語関数， https://reference.wolfram.com/language/ref/DEigenvalues.html.

テキスト

Wolfram Research (2015), DEigenvalues, Wolfram言語関数， https://reference.wolfram.com/language/ref/DEigenvalues.html.

CMS

Wolfram Language. 2015. "DEigenvalues." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DEigenvalues.html.

APA

Wolfram Language. (2015). DEigenvalues. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DEigenvalues.html

BibTeX

@misc{reference.wolfram_2026_deigenvalues, author="Wolfram Research", title="{DEigenvalues}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/DEigenvalues.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_deigenvalues, organization={Wolfram Research}, title={DEigenvalues}, year={2015}, url={https://reference.wolfram.com/language/ref/DEigenvalues.html}, note=[Accessed: 11-September-2026]}