WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Dated[obj,year]

特定の年と関連付けられたオブジェクト obj を表す．

Dated[obj,date]

ある日付と関連付けられたオブジェクト obj を表す．

Dated[obj,All]

オブジェクト obj についての情報が入手可能なすべての日付についてそのオブジェクトを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Dated

Dated[obj,year]

特定の年と関連付けられたオブジェクト obj を表す．

Dated[obj,date]

ある日付と関連付けられたオブジェクト obj を表す．

Dated[obj,All]

オブジェクト obj についての情報が入手可能なすべての日付についてそのオブジェクトを表す．

詳細

  • Dated[obj,date]の obj は，Entityオブジェクト，EntityPropertyオブジェクト，あるいは実体特性を表す文字列でよい．
  • Dated[obj,year]の年(year)は整数で与えることができる．
  • Dated[obj,date]の date はDateObjectを使って指定される．
  • Dated[obj,All]を使ってデータが要求された場合は時系列が返されることが多い．

例題

すべて開く すべて閉じる

例  (3)

1985年のフランスを表す：

Wolfram Language code: Dated[Entity["Country", "France"], 1985]

1985のフランスの人口を求める：

Wolfram Language code: Dated[Entity["Country", "France"], 1985]["Population"]

DatedはEntityProperty式と一緒に使うこともできる：

Wolfram Language code: Dated[EntityProperty["City", "PerCapitaIncome"], DateObject[{2010}, "Year", "Gregorian", -6.]]
Wolfram Language code: Dated[EntityProperty["City", "PerCapitaIncome"], DateObject[{2010}, "Year", "Gregorian", -6.]][Entity["City", {"Chicago", "Illinois", "UnitedStates"}]]

文字列特性名はDatedで囲むこともできる：

Wolfram Language code: EntityValue[Entity["Planet", "Mars"], Dated["DistanceFromEarth", DateObject[{1985, 8, 4}, "Day", "Gregorian", -6.]]]

スコープ  (2)

Datedが実体に使われると，日付限定子が付いていない特性は日付パラメータを無視する：

Wolfram Language code: EntityValue[Dated[Entity["Planet", "Mars"], DateObject[{1986, 10, 13}, "Day", "Gregorian", -6.]], "Mass"]

Datedが日付限定子のない特性に使われると，Missing[…]が返される：

Wolfram Language code: EntityValue[Entity["Planet", "Mars"], Dated["Mass", DateObject[{1986, 10, 13}, "Day", "Gregorian", -6.]]]

Datedが実体と特性の両方に使われると，特性に関連付けられた日付が使われる：

Wolfram Language code: EntityValue[Dated[Entity["Star", "HIP44511"], DateObject[{2010}, "Year", "Gregorian", -6.]], Dated[EntityProperty["Star", "DistanceFromSun"], DateObject[{1990}, "Year", "Gregorian", -6.]]]

一般化と拡張  (2)

複数の日付と関連付けられた特性を取得することで，ある企業の複数の日付における純利益を取得する：

Wolfram Language code: years = DateRange[DateObject[{2017}], DateObject[{2022}], "Years"];
Wolfram Language code: Entity["Company", "Apple::5zkjq"][Dated[EntityProperty["Company", "NetIncome"], #]& /@ years]

複数の日付実体についての純利益をリクエストして同じ結果を得る：

Wolfram Language code: EntityValue[Dated[Entity["Company", "Apple::5zkjq"], #]& /@ years, EntityProperty["Company", "NetIncome"]]

2010年の風力発電が最大の国を上から5つ取得する：

Wolfram Language code: wind2010 = Dated[EntityProperty["Country", "ElectricityWind"], 2010];
Wolfram Language code: EntityClass["Country", wind2010 -> TakeLargest[5]][wind2010, "Association"]

アプリケーション  (10)

現在地球の最も近くにある惑星を求める：

Wolfram Language code: EntityList[EntityClass["Planet", "DistanceFromEarth" -> TakeSmallest[2]]]

2023年2月2日に地球の最も近くにあった惑星を求める：

Wolfram Language code: EntityList[EntityClass["Planet", Dated["DistanceFromEarth", DateObject[{2023, 2, 2}, "Day"]] -> TakeSmallest[2]]]

2023年の1月から10月までの，地球から水星および火星までの距離を求める：

Wolfram Language code: EntityValue[{Entity["Planet", "Mercury"], Entity["Planet", "Mars"]}, Dated["DistanceFromEarth", #]& /@ DateRange[DateObject[{2023, 1}, "Month"], DateObject[{2023, 10}, "Month"], "Months"], "EntityAssociation"]
Wolfram Language code: ListPlot[%, Joined -> True]

2022年1月1日におけるアメリカ合衆国の小売の売上高を取得する：

Wolfram Language code: Dated[Entity["Country", "UnitedStates"], DateObject[{2022, 1, 1}]]["RetailSales"]

2020年におけるアメリカ合衆国のM1マネーサプライとM2マネーサプライを取得する：

Wolfram Language code: Dated[Entity["Country", "UnitedStates"], 2020][{EntityProperty["Country", "MoneySupply", {"Component" -> "M1"}], EntityProperty["Country", "MoneySupply", {"Component" -> "M2"}]}]

1965年から2000年までのアメリカ合衆国の実質GDP年間成長率のプロット：

Wolfram Language code: DateListPlot[Entity["Country", "UnitedStates"][Dated[EntityProperty["Country", "GrossDomesticProduct", {"Adjustment" -> "Real", "TimeSeriesOperator" -> "AnnualizedChangeRate"}], Interval[{DateObject[{1965}, "Year"], DateObject[{2000}, "Year"]}]]]]

1978年からのアメリカ合衆国の債務をアメリカ合衆国のGDPで割ったプロットを作成する：

Wolfram Language code: DateListPlot[Entity["Country", "UnitedStates"][Dated[EntityProperty["Country", "GrossDomesticProduct"], Interval[{DateObject[{1978}, "Year"], Today}]]] / Entity["Country", "UnitedStates"][Dated[EntityProperty["Country", "FederalDebt"], Interval[{DateObject[{1978}, "Year"], Today}]]]]

1995年のアメリカ合衆国の鉱工業生産を部門別に円グラフで表す：

Wolfram Language code: sectors = {"FinalProducts", "ConsumerGoods", "BusinessEquipment", "Manufacturing", "Materials", "Mining", "ElectricGasUtilities"}; PieChart[Dated[Entity["Country", "UnitedStates"], 1995][EntityProperty["Country", "IndustrialProduction", {"ProductionSector" -> #}]& /@ sectors], ChartLegends -> sectors]

1996年3月におけるイリノイ州とウィスコンシン州の失業率を比較する：

Wolfram Language code: Dated[{Entity["AdministrativeDivision", {"Illinois", "UnitedStates"}], Entity["AdministrativeDivision", {"Wisconsin", "UnitedStates"}]}, DateObject[{1996, 3}]]["CivilianUnemploymentRate", "Association"]

2010年からの，フェニックス，セントルイス，マイアミの住宅価格のプロットを作成する：

Wolfram Language code: With[{cities = {Entity["City", {"Phoenix", "Arizona", "UnitedStates"}], Entity["City", {"SaintLouis", "Missouri", "UnitedStates"}], Entity["City", {"Miami", "Florida", "UnitedStates"}]}}, DateListPlot[Dated[cities, Interval[{DateObject[{2010}], Today}]]["MedianHomeListingPrice"], PlotLegends -> cities]]

2020年のアメリカ合衆国中西部の州の1人当たGDPの地域値プロットを作成する：

Wolfram Language code: GeoRegionValuePlot[EntityList@EntityClass["AdministrativeDivision", "USStatesMidwest"] -> Dated[EntityProperty["AdministrativeDivision", "GrossDomesticProduct", {"Modifier" -> "PerCapita"}], 2020]]

特性と関係  (1)

指定の国の指定の日付における人口を取得する：

Wolfram Language code: Entity["Country", "UnitedStates"][Dated["Population", DateObject[{2020}, "Year"]]]

以下も同じことをする：

Wolfram Language code: Entity["Country", "UnitedStates"][EntityProperty["Country", "Population", {"Date" -> DateObject[{2020}, "Year"]}]]
Wolfram Research (2016), Dated, Wolfram言語関数， https://reference.wolfram.com/language/ref/Dated.html.

テキスト

Wolfram Research (2016), Dated, Wolfram言語関数， https://reference.wolfram.com/language/ref/Dated.html.

CMS

Wolfram Language. 2016. "Dated." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Dated.html.

APA

Wolfram Language. (2016). Dated. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Dated.html

BibTeX

@misc{reference.wolfram_2026_dated, author="Wolfram Research", title="{Dated}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/Dated.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dated, organization={Wolfram Research}, title={Dated}, year={2016}, url={https://reference.wolfram.com/language/ref/Dated.html}, note=[Accessed: 07-September-2026]}