WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DeleteDuplicates[data]

data から重複するものをすべて削除する．

DeleteDuplicates[data,test]

test を要素のペアに適用し，それらが重複とみなされるべきかどうかを決定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

DeleteDuplicates

DeleteDuplicates[data]

data から重複するものをすべて削除する．

DeleteDuplicates[data,test]

test を要素のペアに適用し，それらが重複とみなされるべきかどうかを決定する．

詳細

  • DeleteDuplicates[data]は，各個別要素を data の最初に現れるものを除いて削除する．
  • DeleteDuplicatesは，連想に使い，連想の前の方と値が重複する項目を削除することができる．
  • 次は，data が取り得る形である．
  • {e1,e2,…}数，数量，日付を含む値のリスト
    Association[…]値の連想
    QuantityArray[…]数量配列あるいはその他の構造化配列
    Tabular[…]一貫した型の表形式データ
    TabularColumn[…]一貫した型の列データ
    Dataset[…]一般的な階層データ
  • DeleteDuplicatesは要素を除くだけで，並べ直すことはない．
  • DeleteDuplicates[data]はDeleteDuplicates[data,SameQ]に等しい． »

例題

すべて開く すべて閉じる

例  (2)

重複する要素を削除する：

Wolfram Language code: DeleteDuplicates[{1, 7, 8, 4, 3, 4, 1, 9, 9, 2}]

連想中で，値が前のものと重複する要素を削除する：

Wolfram Language code: DeleteDuplicates[<|a -> 1, b -> 2, c -> 1, d -> 3, e -> 2|>]

スコープ  (6)

データの頭部がListである必要はない：

Wolfram Language code: DeleteDuplicates[Hold[1 + 2, 4 - 1, 1 + 2, 2 + 1]]

その前に少なくとも1つそれより大きい要素がある要素を削除する：

Wolfram Language code: DeleteDuplicates[{1, 7, 8, 4, 3, 4, 1, 9, 8, 9, 2}, Greater]

数の差が0.01以下の場合は同じものとして扱う：

Wolfram Language code: DeleteDuplicates[{3.0, 3.1, 3.11, 3.5, 3.51}, Abs[#1 - #2] <= 0.01&]

Tabularオブジェクトの重複している行を削除する：

Wolfram Language code: Tabular[{{1, 2}, {4, 5}, {1, 2}}, {"col1", "col2"}]
Wolfram Language code: DeleteDuplicates[%]

最初の列の値がその前の値よりも大きい行を削除する：

Wolfram Language code: Tabular[{{2, 2}, {3, 3}, {1, 5}}, {"col1", "col2"}]
Wolfram Language code: DeleteDuplicates[%, #1["col1"] < #2["col1"]&]

Datasetオブジェクトの重複している行を削除する：

Wolfram Language code: Dataset[<|"row1" -> <|"col1" -> 1, "col2" -> 3|>, "row2" -> <|"col1" -> 1, "col2" -> 3|>, "row3" -> <|"col1" -> 4, "col2" -> 3|>|>]
Wolfram Language code: DeleteDuplicates[%]

特性と関係  (4)

DeleteDuplicates[list]はDeleteDuplicates[list,SameQ]に等しい：

Wolfram Language code: list = Join[RandomInteger[100, {50}], RandomReal[1, {50}], {x, y, z, π, E}];
Wolfram Language code: DeleteDuplicates[list] == DeleteDuplicates[list, SameQ]

DeleteDuplicatesは並べ替えをしないUnionに等しい：

Wolfram Language code: list = {9, 0, 0, 3, 2, 3, 6, 2, 9, 8, 4, 9, 0, 2, 6, 5, 7, 4, 9, 8};
Wolfram Language code: Union[list]
Wolfram Language code: DeleteDuplicates[list]
Wolfram Language code: Sort[%]

並べ替えを避けることでスピードがかなり上がる：

Wolfram Language code: list = RandomInteger[10 ^ 5, 10 ^ 7];
Wolfram Language code: {First[Timing[DeleteDuplicates[list]]], First[Timing[Union[list]]]}

DeleteDuplicates[list,test]は，test を2つの要素に適用して両者が重複しているかどうかを判定する：

Wolfram Language code: list = {{0, 0, 0, 1, 0}, {1, 0, 1, 0, 1}, {1, 1, 1, 0, 0}, {0, 0, 0, 0, 1}, {1, 1, 1, 0, 1}};
Wolfram Language code: DeleteDuplicates[list, Total[#1] == Total[#2]&]

DeleteDuplicatesBy[list,f]は f を使って各要素を変換し結果を比較する：

Wolfram Language code: DeleteDuplicatesBy[list, Total]

CountDistinct[list]はLength[DeleteDuplicates[list]]に等しい：

Wolfram Language code: list = RandomInteger[100, {33}];
Wolfram Language code: CountDistinct[list] == Length[DeleteDuplicates[list]]

CountDistinct[list,test]はLength[DeleteDuplicates[list,test]]に等しい：

Wolfram Language code: lastDigitSameQ[x_, y_] := Mod[x, 10] === Mod[y, 10]
Wolfram Language code: CountDistinct[list, lastDigitSameQ] == Length[DeleteDuplicates[list, lastDigitSameQ]]

考えられる問題  (1)

比較関数がTrueもFalseも返さない場合，要素は異なるとみなされる：

Wolfram Language code: DeleteDuplicates[{3, 3, 3}, f]

常に要素が異なると報告する関数と比較する：

Wolfram Language code: DeleteDuplicates[{3, 3, 3}, False&]
Wolfram Research (2008), DeleteDuplicates, Wolfram言語関数， https://reference.wolfram.com/language/ref/DeleteDuplicates.html （2025年に更新）.

テキスト

Wolfram Research (2008), DeleteDuplicates, Wolfram言語関数， https://reference.wolfram.com/language/ref/DeleteDuplicates.html （2025年に更新）.

CMS

Wolfram Language. 2008. "DeleteDuplicates." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/DeleteDuplicates.html.

APA

Wolfram Language. (2008). DeleteDuplicates. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DeleteDuplicates.html

BibTeX

@misc{reference.wolfram_2026_deleteduplicates, author="Wolfram Research", title="{DeleteDuplicates}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DeleteDuplicates.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_deleteduplicates, organization={Wolfram Research}, title={DeleteDuplicates}, year={2025}, url={https://reference.wolfram.com/language/ref/DeleteDuplicates.html}, note=[Accessed: 06-September-2026]}