WOLFRAM

Wolfram 语言与系统参考资料中心

DeleteDuplicates[data]

删除 data 中的重复元素.

DeleteDuplicates[data,test]

将 test 应用到元素对中，确定它们是否是重复的.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
可能存在的问题  
参见
相关指南
相关链接
历史
按以下格式引用：

DeleteDuplicates

DeleteDuplicates[data]

删除 data 中的重复元素.

DeleteDuplicates[data,test]

将 test 应用到元素对中，确定它们是否是重复的.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

删除重复元素：

Wolfram Language code: DeleteDuplicates[{1, 7, 8, 4, 3, 4, 1, 9, 9, 2}]

删除与关联中先出现的值重复的元素：

Wolfram Language code: DeleteDuplicates[<|a -> 1, b -> 2, c -> 1, d -> 3, e -> 2|>]

范围  (6)

该数据不需要有头 List：

Wolfram Language code: DeleteDuplicates[Hold[1 + 2, 4 - 1, 1 + 2, 2 + 1]]

删除前面至少有一个更大数值元素的元素：

Wolfram Language code: DeleteDuplicates[{1, 7, 8, 4, 3, 4, 1, 9, 8, 9, 2}, Greater]

如果数值相差 0.01 或更小，则将其视为相等：

Wolfram Language code: DeleteDuplicates[{3.0, 3.1, 3.11, 3.5, 3.51}, Abs[#1 - #2] <= 0.01&]

删除 Tabular 对象中的重复行：

Wolfram Language code: Tabular[{{1, 2}, {4, 5}, {1, 2}}, {"col1", "col2"}]
Wolfram Language code: DeleteDuplicates[%]

删除第一列值大于前一列值的行：

Wolfram Language code: Tabular[{{2, 2}, {3, 3}, {1, 5}}, {"col1", "col2"}]
Wolfram Language code: DeleteDuplicates[%, #1["col1"] < #2["col1"]&]

删除 Dataset 对象中的重复行：

Wolfram Language code: Dataset[<|"row1" -> <|"col1" -> 1, "col2" -> 3|>, "row2" -> <|"col1" -> 1, "col2" -> 3|>, "row3" -> <|"col1" -> 4, "col2" -> 3|>|>]
Wolfram Language code: DeleteDuplicates[%]

属性和关系  (4)

DeleteDuplicates[list] 等价于 DeleteDuplicates[list,SameQ]:

Wolfram Language code: list = Join[RandomInteger[100, {50}], RandomReal[1, {50}], {x, y, z, π, E}];
Wolfram Language code: DeleteDuplicates[list] == DeleteDuplicates[list, SameQ]

DeleteDuplicates 和不排序的 Union 相似：

Wolfram Language code: list = {9, 0, 0, 3, 2, 3, 6, 2, 9, 8, 4, 9, 0, 2, 6, 5, 7, 4, 9, 8};
Wolfram Language code: Union[list]
Wolfram Language code: DeleteDuplicates[list]
Wolfram Language code: Sort[%]

避免排序，显著提高运行速度：

Wolfram Language code: list = RandomInteger[10 ^ 5, 10 ^ 7];
Wolfram Language code: {First[Timing[DeleteDuplicates[list]]], First[Timing[Union[list]]]}

DeleteDuplicates[list,test] 对两个元素应用 test 以确定它们是否重复：

Wolfram Language code: list = {{0, 0, 0, 1, 0}, {1, 0, 1, 0, 1}, {1, 1, 1, 0, 0}, {0, 0, 0, 0, 1}, {1, 1, 1, 0, 1}};
Wolfram Language code: DeleteDuplicates[list, Total[#1] == Total[#2]&]

DeleteDuplicatesBy[list,f] 使用 f 变换每个元素，然后比较结果：

Wolfram Language code: DeleteDuplicatesBy[list, Total]

CountDistinct[list] 等价于 Length[DeleteDuplicates[list]]:

Wolfram Language code: list = RandomInteger[100, {33}];
Wolfram Language code: CountDistinct[list] == Length[DeleteDuplicates[list]]

CountDistinct[list,test] 等价于 Length[DeleteDuplicates[list,test]]:

Wolfram Language code: lastDigitSameQ[x_, y_] := Mod[x, 10] === Mod[y, 10]
Wolfram Language code: CountDistinct[list, lastDigitSameQ] == Length[DeleteDuplicates[list, lastDigitSameQ]]

可能存在的问题  (1)

如果比较函数既不返回 True 也不返回 False，则认定元素是不同的：

Wolfram Language code: DeleteDuplicates[{3, 3, 3}, f]

与总是报告元素为不同的函数进行比较：

Wolfram Language code: DeleteDuplicates[{3, 3, 3}, False&]
Wolfram Research (2008)，DeleteDuplicates，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DeleteDuplicates.html （更新于 2025 年）.

文本

Wolfram Research (2008)，DeleteDuplicates，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DeleteDuplicates.html （更新于 2025 年）.

CMS

Wolfram 语言. 2008. "DeleteDuplicates." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2025. https://reference.wolfram.com/language/ref/DeleteDuplicates.html.

APA

Wolfram 语言. (2008). DeleteDuplicates. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DeleteDuplicates.html 年

BibTeX

@misc{reference.wolfram_2026_deleteduplicates, author="Wolfram Research", title="{DeleteDuplicates}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/DeleteDuplicates.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_deleteduplicates, organization={Wolfram Research}, title={DeleteDuplicates}, year={2025}, url={https://reference.wolfram.com/language/ref/DeleteDuplicates.html}, note=[Accessed: 09-September-2026]}