WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DesignMatrix[{{x11,x12,…,y1},{x21,x22,…,y2},…},{f1,f2,…},{x1,x2,…}]

線形モデル β0+β1 f1+β2 f2+… の計画行列を構築する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
IncludeConstantBasis  
NominalVariables  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

DesignMatrix

DesignMatrix[{{x11,x12,…,y1},{x21,x22,…,y2},…},{f1,f2,…},{x1,x2,…}]

線形モデル β0+β1 f1+β2 f2+… の計画行列を構築する．

詳細とオプション

  • DesignMatrix[{y1,y2,…},{f1,f2,…},x]は{{1,y1},{2,y2},…}の形式のデータを想定している． »
  • {{x_(11),x_(12),...,y_(1)},{x_(21),x_(22),...,y_(2)},...}の形のデータのとき，座標 xi1, xi2, …の数は変数 xiの数に等しくなければならない．
  • 計画行列 m は以下の形のデータ点における基底関数 fiの値から形成される．
  • DesignMatrixで使用可能なオプション
  • IncludeConstantBasis True定数基底関数を含むかどうか
    NominalVariables None名義的あるいはカテゴリ的とみなされる変数
    WorkingPrecisionAutomatic内部計算で使う精度
  • IncludeConstantBasis->Falseと設定すると，β1 f1+β2 f2+⋯の形式のモデルに対する計画行列が構築される． »

例題

すべて開く すべて閉じる

例  (3)

線形モデルの計画行列：

Wolfram Language code: data = Table[{i, i ^ (3 / 2) + RandomReal[]}, {i, 5}]
Wolfram Language code: DesignMatrix[data, x, x]//MatrixForm

二次項を加える：

Wolfram Language code: DesignMatrix[data, {x, x ^ 2}, x]//MatrixForm

係数項を除外する：

Wolfram Language code: DesignMatrix[data, {x, x ^ 2}, x, IncludeConstantBasis -> False]//MatrixForm

2つの予測変数を持つ計画行列：

Wolfram Language code: data2 = Table[{RandomInteger[10], RandomInteger[10], RandomReal[]}, {10}]
Wolfram Language code: DesignMatrix[data2, {x, y}, {x, y}]//MatrixForm

積の項を含む：

Wolfram Language code: DesignMatrix[data2, {x, y, x * y}, {x, y}]//MatrixForm

予測変数1, 2, …を推定する：

Wolfram Language code: DesignMatrix[RandomReal[10, 5], x, x]//MatrixForm

スコープ  (2)

予測器の任意の数値関数を使う：

Wolfram Language code: data = Table[{i, RandomReal[]}, {i, 5}]
Wolfram Language code: DesignMatrix[data, {Sin[x], Sqrt[x]}, x]//MatrixForm

厳密な演算で計画行列を得る：

Wolfram Language code: data = RandomInteger[99, {5, 2}]
Wolfram Language code: DesignMatrix[data, {x, Sin[x]}, x] //MatrixForm

機械演算を使う：

Wolfram Language code: DesignMatrix[N[data], {x, Sin[x]}, x] //MatrixForm

任意精度演算を使う：

Wolfram Language code: DesignMatrix[N[data, 24], {x, Sin[x]}, x] //MatrixForm

固定24桁精度演算を使う：

Wolfram Language code: DesignMatrix[data, {x, Sin[x]}, x, WorkingPrecision -> 24] //MatrixForm

オプション  (3)

IncludeConstantBasis  (1)

デフォルトでは定数項が含まれる：

Wolfram Language code: data = Table[{i, RandomReal[]}, {i, 10}]
Wolfram Language code: DesignMatrix[data, x, x]//MatrixForm

定数項なしで計画行列を構築する：

Wolfram Language code: DesignMatrix[data, x, x, IncludeConstantBasis -> False]//MatrixForm

NominalVariables  (2)

x を数値変数として扱う：

Wolfram Language code: data = {{0, 1.5}, {2, 2.3}, {2, 1.8}, {0, 2.5}};
Wolfram Language code: DesignMatrix[data, x, x]//MatrixForm

x を名義変数として扱う：

Wolfram Language code: DesignMatrix[data, x, x, NominalVariables -> x]//MatrixForm

数値的ではない名義変数を使う：

Wolfram Language code: DesignMatrix[{{a, 1.5}, {b, 2.3}, {b, 1.8}, {a, 2.5}}, x, x, NominalVariables -> x]//MatrixForm

x のみを名義変数として扱う：

Wolfram Language code: DesignMatrix[{{a, 0, 1.5}, {b, 2, 2.3}, {a, 2, 1.8}, {b, 0, 2.5}}, {x, y}, {x, y}, NominalVariables -> x]//MatrixForm

すべての予測器を名義変数として扱う：

Wolfram Language code: DesignMatrix[{{a, 0, 1.5}, {b, 2, 2.3}, {a, 2, 1.8}, {b, 0, 2.5}}, {x, y}, {x, y}, NominalVariables -> All]//MatrixForm

特性と関係  (1)

DesignMatrixはLinearModelFitで使われる計画行列を構築する：

Wolfram Language code: data = Table[{i, RandomReal[]}, {i, 5}]
Wolfram Language code: DesignMatrix[data, x, x]//MatrixForm
Wolfram Language code: lm = LinearModelFit[data, x, x];
Wolfram Language code: lm["DesignMatrix"]//MatrixForm

この行列はGeneralizedLinearModelFitについても同じである：

Wolfram Language code: glm = GeneralizedLinearModelFit[data, x, x];
Wolfram Language code: glm["DesignMatrix"]//MatrixForm
Wolfram Research (2008), DesignMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/DesignMatrix.html.

テキスト

Wolfram Research (2008), DesignMatrix, Wolfram言語関数， https://reference.wolfram.com/language/ref/DesignMatrix.html.

CMS

Wolfram Language. 2008. "DesignMatrix." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DesignMatrix.html.

APA

Wolfram Language. (2008). DesignMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DesignMatrix.html

BibTeX

@misc{reference.wolfram_2026_designmatrix, author="Wolfram Research", title="{DesignMatrix}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/DesignMatrix.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_designmatrix, organization={Wolfram Research}, title={DesignMatrix}, year={2008}, url={https://reference.wolfram.com/language/ref/DesignMatrix.html}, note=[Accessed: 14-September-2026]}