WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiagonalMatrixQ[m]

m が対角行列の場合はTrueを，それ以外の場合はFalseを返す．

DiagonalMatrixQ[m,k]

m が第 k 対角のみに非零要素を持つ場合はTrueを，それ以外の場合はFalseを返す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
特殊行列  
オプション  
Tolerance  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

DiagonalMatrixQ

DiagonalMatrixQ[m]

m が対角行列の場合はTrueを，それ以外の場合はFalseを返す．

DiagonalMatrixQ[m,k]

m が第 k 対角のみに非零要素を持つ場合はTrueを，それ以外の場合はFalseを返す．

詳細とオプション

  • DiagonalMatrixQ[m,k]は m が正方行列ではなくても使うことができる．
  • DiagonalMatrixQ[m,k]における正の k は主対角の上対角を示し，負の k は主対角の下対角を示す．
  • DiagonalMatrixQはSparseArrayオブジェクトおよび構造配列オブジェクトに使うことができる．
  • 次は，使用可能なオプションである．
  • Tolerance Automatic使用する数値許容範囲
  • 近似行列については，オプションTolerance->t を使って Abs[mij]≤t であるすべての要素を0であるとすることができる． »

例題

すべて開く すべて閉じる

例  (3)

行列が対角行列かどうか調べる：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | a | 0 | 0 | | 0 | b | 0 | | 0 | 0 | c |⁠)]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 1 | 0 | 0 | | 0 | 0 | 2 | | 3 | 0 | 0 |⁠)]

上対角行列を調べる：

Wolfram Language code: MatrixForm[{{0, a, 0}, {0, 0, b}, {0, 0, 0}}]
Wolfram Language code: DiagonalMatrixQ[%, 1]

下対角行列を調べる：

Wolfram Language code: MatrixForm[{{0, 0, 0}, {a, 0, 0}, {0, b, 0}}]
Wolfram Language code: DiagonalMatrixQ[%, -1]

スコープ  (12)

基本的な用法  (8)

矩形対角行列を調べる：

Wolfram Language code: (mat23 = {{1, 0, 0}, {0, 2, 0}})//MatrixForm
Wolfram Language code: DiagonalMatrixQ[mat23]
Wolfram Language code: (mat32 = {{1, 0}, {0, 2}, {0, 0}})//MatrixForm
Wolfram Language code: DiagonalMatrixQ[mat32]

DiagonalMatrixQを記号行列に使う：

Wolfram Language code: DiagonalMatrixQ[{{a, b}, {c, d}}]

のとき，行列は対角行列になる：

Wolfram Language code: Block[{b = c = 0}, DiagonalMatrixQ[{{a, b}, {c, d}}]]

機械精度の実行列が対角行列かどうかを調べる：

Wolfram Language code: m = {{1.2, 0, 0}, {0, 2.4, 0}, {0, 0, 3.5}};
Wolfram Language code: DiagonalMatrixQ[m]

複素行列が対角行列かどうかを調べる：

Wolfram Language code: m = {{1, -3I}, {0, 4}};
Wolfram Language code: DiagonalMatrixQ[m]

行列の実部は対角で虚部は上対角である：

Wolfram Language code: {DiagonalMatrixQ[Re[m]], DiagonalMatrixQ[Im[m], 1]}

厳密行列が対角行列かどうかを調べる：

Wolfram Language code: m = (⁠| | | | | - | - | ------- | | 0 | 5 | 4 | | 3 | 1 | Sqrt[2] | | 3 | 5 | Pi |⁠);
Wolfram Language code: DiagonalMatrixQ[m]

DiagonalMatrixQを任意精度の行列に使う：

Wolfram Language code: m = RandomReal[5, {3, 3}, WorkingPrecision -> 15]

ランダムな行列は，一般に，対角行列ではない：

Wolfram Language code: DiagonalMatrixQ[m]

行列の特定の上対角のみに比例要素があるかどうかを調べる：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠), 1]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠), 2]

次の行列は対角行列ではない：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠)]

行列の特定の下対角上に非零成分があるかどうかを調べる：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠), -1]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠), -2]

この行列は対角行列ではない：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠)]

特殊行列  (4)

DiagonalMatrixQを疎な行列に使う：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]
Wolfram Language code: DiagonalMatrixQ[%]
Wolfram Language code: SparseArray[{{x_, y_} /; x == y -> 3}, {5, 5}]
Wolfram Language code: DiagonalMatrixQ[%]

DiagonalMatrixQを構造化行列に使う：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 4, {2, 2} -> 5, {3, 3} -> 6}, {3, 3}, Symmetric[All]]
Wolfram Language code: DiagonalMatrixQ[%]

QuantityArrayを構造化行列に使う：

Wolfram Language code: QuantityArray[{{1, 0}, {0, 5}}, "Meters"]
Wolfram Language code: DiagonalMatrixQ[%]

恒等行列は対角行列である：

Wolfram Language code: DiagonalMatrixQ[IdentityMatrix[5]]

HilbertMatrixは対角行列ではない：

Wolfram Language code: DiagonalMatrixQ[HilbertMatrix[5]]

オプション  (1)

Tolerance  (1)

この行列は対角行列ではない：

Wolfram Language code: m = {{1., 10 ^ -12, 0}, {0, 2., 10 ^ -13}, {0, 0, 3.}}; DiagonalMatrixQ[m]

Toleranceオプションを加えて10-12未満の数が0であるとみなす：

Wolfram Language code: DiagonalMatrixQ[m, Tolerance -> 10 ^ -12]

アプリケーション  (2)

実数値行列は，それが正規行列で実固有値を持つときかつそのときに限り対角行列と直交相似である：

Wolfram Language code: m = N[HilbertMatrix[3]]; NormalMatrixQ[m]

m の固有値と固有ベクトルを計算する：

Wolfram Language code: {vals, vecs} = Eigensystem[m];

固有値は実数である：

Wolfram Language code: vals∈Reals

m が対角行列と等しいことを，その固有ベクトルを介して確かめる：

Wolfram Language code: DiagonalMatrixQ[vecs.m.Transpose[vecs]]

固有ベクトル行列が直交行列であることを確かめる：

Wolfram Language code: OrthogonalMatrixQ[vecs]

行列は，その標準ジョルダン行列が対角行列であるときかつそのときに限り対角化可能である：

Wolfram Language code: mat1 = {{1, 2}, {3, 4}}; (j1 = Last[JordanDecomposition[mat1]])//MatrixForm
Wolfram Language code: {DiagonalizableMatrixQ[mat1], DiagonalMatrixQ[j1]}
Wolfram Language code: mat2 = {{27, 48, 81}, {-6, 0, 0}, {1, 0, 3}}; (j2 = Last[JordanDecomposition[mat2]])//MatrixForm
Wolfram Language code: {DiagonalizableMatrixQ[mat2], DiagonalMatrixQ[j2]}

特性と関係  (10)

DiagonalMatrixQは，行列ではない入力に対してはFalseを返す：

Wolfram Language code: DiagonalMatrixQ[1]
Wolfram Language code: DiagonalMatrixQ[{}]

次元{n,0}の行列は対角行列である：

Wolfram Language code: DiagonalMatrixQ[{{}, {}}]

DiagonalMatrixは対角行列を作る：

Wolfram Language code: (m = DiagonalMatrix[{a, b, c, d}])//MatrixForm
Wolfram Language code: DiagonalMatrixQ[m]

任意の恒等行列は対角行列である：

Wolfram Language code: DiagonalMatrixQ[IdentityMatrix[5]]

対角行列の逆行列は対角行列である：

Wolfram Language code: mat = DiagonalMatrix[Range[5]];
Wolfram Language code: DiagonalMatrixQ[Inverse[mat]]

このことは，任意の累乗と関数に拡張される：

Wolfram Language code: DiagonalMatrixQ[MatrixPower[mat, n]]
Wolfram Language code: DiagonalMatrixQ[MatrixFunction[f, mat]]

2つ（あるいはそれ以上）の対角行列の積は対角行列である：

Wolfram Language code: m1 = DiagonalMatrix[RandomReal[1., {5}]]; m2 = DiagonalMatrix[RandomReal[1., {5}]];
Wolfram Language code: DiagonalMatrixQ[m1.m2]

対角行列は上三角行列であり下三角行列である：

Wolfram Language code: mat = DiagonalMatrix[RandomReal[1., {5}]];
Wolfram Language code: {DiagonalMatrixQ[m1], UpperTriangularMatrixQ[m1], LowerTriangularMatrixQ[m1]}

DiagonalMatrixQ[m,0]はDiagonalMatrixQ[m]に等しい：

Wolfram Language code: {DiagonalMatrixQ[{{1, 0}, {0, 2}}], DiagonalMatrixQ[{{1, 0}, {0, 2}}, 0]}
Wolfram Language code: {DiagonalMatrixQ[{{1, 3}, {4, 2}}], DiagonalMatrixQ[{{1, 3}, {4, 2}}, 0]}

下対角あるいは上対角だけを持つ行列 はベキ零である．つまり，ある について である：

Wolfram Language code: m1 = DiagonalMatrix[Range[4], -1]; DiagonalMatrixQ[m1, -1]
Wolfram Language code: MatrixPower[m1, 5]
Wolfram Language code: m2 = DiagonalMatrix[Range[4], 1]; DiagonalMatrixQ[m2, 1]
Wolfram Language code: MatrixPower[m2, 5]

Bandを使って k 対角疎行列が構築できる：

Wolfram Language code: k = RandomInteger[5]
Wolfram Language code: m = SparseArray[Band[{1, 1 + k}] -> Range[5], (5 + k){1, 1}]
Wolfram Language code: DiagonalMatrixQ[m, k]
Wolfram Research (2019), DiagonalMatrixQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

テキスト

Wolfram Research (2019), DiagonalMatrixQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

CMS

Wolfram Language. 2019. "DiagonalMatrixQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

APA

Wolfram Language. (2019). DiagonalMatrixQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html

BibTeX

@misc{reference.wolfram_2026_diagonalmatrixq, author="Wolfram Research", title="{DiagonalMatrixQ}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_diagonalmatrixq, organization={Wolfram Research}, title={DiagonalMatrixQ}, year={2019}, url={https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html}, note=[Accessed: 14-September-2026]}