WOLFRAM

Wolfram 语言与系统参考资料中心

DiagonalMatrixQ[m]

如果 m 是对角矩阵，给出 True，否则给出 False.

DiagonalMatrixQ[m,k]

如果 m 只在第 k 个对角上有非零元素，给出 True，否则给出 False.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
特殊矩阵  
选项  
Tolerance  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

DiagonalMatrixQ

DiagonalMatrixQ[m]

如果 m 是对角矩阵，给出 True，否则给出 False.

DiagonalMatrixQ[m,k]

如果 m 只在第 k 个对角上有非零元素，给出 True，否则给出 False.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

测试矩阵是否为对角矩阵：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | a | 0 | 0 | | 0 | b | 0 | | 0 | 0 | c |⁠)]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 1 | 0 | 0 | | 0 | 0 | 2 | | 3 | 0 | 0 |⁠)]

检验一个矩阵是否为对角矩阵：

Wolfram Language code: MatrixForm[{{0, a, 0}, {0, 0, b}, {0, 0, 0}}]
Wolfram Language code: DiagonalMatrixQ[%, 1]

检验一个矩阵是否为上对角矩阵：

Wolfram Language code: MatrixForm[{{0, 0, 0}, {a, 0, 0}, {0, b, 0}}]
Wolfram Language code: DiagonalMatrixQ[%, -1]

范围  (12)

基本用法  (8)

检验长方形对角矩阵：

Wolfram Language code: (mat23 = {{1, 0, 0}, {0, 2, 0}})//MatrixForm
Wolfram Language code: DiagonalMatrixQ[mat23]
Wolfram Language code: (mat32 = {{1, 0}, {0, 2}, {0, 0}})//MatrixForm
Wolfram Language code: DiagonalMatrixQ[mat32]

对符号矩阵使用 DiagonalMatrixQ：

Wolfram Language code: DiagonalMatrixQ[{{a, b}, {c, d}}]

当 时，矩阵变为对角线矩阵：

Wolfram Language code: Block[{b = c = 0}, DiagonalMatrixQ[{{a, b}, {c, d}}]]

检验一个实值机器精度矩阵是否是对角线矩阵：

Wolfram Language code: m = {{1.2, 0, 0}, {0, 2.4, 0}, {0, 0, 3.5}};
Wolfram Language code: DiagonalMatrixQ[m]

检验复矩阵是否为对角线矩阵：

Wolfram Language code: m = {{1, -3I}, {0, 4}};
Wolfram Language code: DiagonalMatrixQ[m]

矩阵的实部是对角线矩阵，虚部是上对角线矩阵：

Wolfram Language code: {DiagonalMatrixQ[Re[m]], DiagonalMatrixQ[Im[m], 1]}

检验精确矩阵是否是对角线矩阵：

Wolfram Language code: m = (⁠| | | | | - | - | ------- | | 0 | 5 | 4 | | 3 | 1 | Sqrt[2] | | 3 | 5 | Pi |⁠);
Wolfram Language code: DiagonalMatrixQ[m]

将 DiagonalMatrixQ 用于任意精度矩阵：

Wolfram Language code: m = RandomReal[5, {3, 3}, WorkingPrecision -> 15]

随机矩阵通常是非对角矩阵：

Wolfram Language code: DiagonalMatrixQ[m]

检验矩阵是否仅在特定的上对角线上有非零项：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠), 1]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠), 2]

请注意，矩阵不是对角线矩阵：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 1 | 0 | | 0 | 0 | 2 | | 0 | 0 | 0 |⁠)]

检验矩阵是否仅在特定的对角线上具有非零项：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠), -1]
Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠), -2]

请注意，矩阵不是对角线矩阵：

Wolfram Language code: DiagonalMatrixQ[(⁠| | | | | - | - | - | | 0 | 0 | 0 | | 0 | 0 | 0 | | 3 | 0 | 0 |⁠)]

特殊矩阵  (4)

将 DiagonalMatrixQ 用于稀疏矩阵：

Wolfram Language code: SparseArray[{{1, 3} -> 1, {2, 2} -> 2, {3, 1} -> 3}, {3, 3}]
Wolfram Language code: DiagonalMatrixQ[%]
Wolfram Language code: SparseArray[{{x_, y_} /; x == y -> 3}, {5, 5}]
Wolfram Language code: DiagonalMatrixQ[%]

将 DiagonalMatrixQ 用于结构化矩阵：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 4, {2, 2} -> 5, {3, 3} -> 6}, {3, 3}, Symmetric[All]]
Wolfram Language code: DiagonalMatrixQ[%]

用于 QuantityArray 结构化矩阵：

Wolfram Language code: QuantityArray[{{1, 0}, {0, 5}}, "Meters"]
Wolfram Language code: DiagonalMatrixQ[%]

单位矩阵是对角矩阵：

Wolfram Language code: DiagonalMatrixQ[IdentityMatrix[5]]

HilbertMatrix 不是对角矩阵：

Wolfram Language code: DiagonalMatrixQ[HilbertMatrix[5]]

选项  (1)

Tolerance  (1)

下列矩阵不是对角矩阵：

Wolfram Language code: m = {{1., 10 ^ -12, 0}, {0, 2., 10 ^ -13}, {0, 0, 3.}}; DiagonalMatrixQ[m]

加上 Tolerance 选项，将小于 10-12 的数视为零：

Wolfram Language code: DiagonalMatrixQ[m, Tolerance -> 10 ^ -12]

应用  (2)

当且仅当实矩阵为正规矩阵并具有实特征值时，实矩阵才与对角矩阵正交相似：

Wolfram Language code: m = N[HilbertMatrix[3]]; NormalMatrixQ[m]

计算 m 的特征值和特征向量：

Wolfram Language code: {vals, vecs} = Eigensystem[m];

特征值为实数：

Wolfram Language code: vals∈Reals

验证 m 经过与其特征向量的运算后等价于一个对角矩阵：

Wolfram Language code: DiagonalMatrixQ[vecs.m.Transpose[vecs]]

验证特征向量矩阵是正交矩阵：

Wolfram Language code: OrthogonalMatrixQ[vecs]

当且仅当其标准 Jordan 矩阵是对角矩阵时，矩阵才是可对角化的：

Wolfram Language code: mat1 = {{1, 2}, {3, 4}}; (j1 = Last[JordanDecomposition[mat1]])//MatrixForm
Wolfram Language code: {DiagonalizableMatrixQ[mat1], DiagonalMatrixQ[j1]}
Wolfram Language code: mat2 = {{27, 48, 81}, {-6, 0, 0}, {1, 0, 3}}; (j2 = Last[JordanDecomposition[mat2]])//MatrixForm
Wolfram Language code: {DiagonalizableMatrixQ[mat2], DiagonalMatrixQ[j2]}

属性和关系  (10)

如果输入不是矩阵，DiagonalMatrixQ 返回 False：

Wolfram Language code: DiagonalMatrixQ[1]
Wolfram Language code: DiagonalMatrixQ[{}]

维度为 {n,0} 的矩阵是对角矩阵：

Wolfram Language code: DiagonalMatrixQ[{{}, {}}]

DiagonalMatrix 创建一个对角矩阵：

Wolfram Language code: (m = DiagonalMatrix[{a, b, c, d}])//MatrixForm
Wolfram Language code: DiagonalMatrixQ[m]

单位矩阵是对角矩阵：

Wolfram Language code: DiagonalMatrixQ[IdentityMatrix[5]]

对角矩阵的逆矩阵也是对角矩阵：

Wolfram Language code: mat = DiagonalMatrix[Range[5]];
Wolfram Language code: DiagonalMatrixQ[Inverse[mat]]

对于矩阵的任意次幂和矩阵函数同样成立：

Wolfram Language code: DiagonalMatrixQ[MatrixPower[mat, n]]
Wolfram Language code: DiagonalMatrixQ[MatrixFunction[f, mat]]

两个（或多个）对角矩阵的积还是对角矩阵：

Wolfram Language code: m1 = DiagonalMatrix[RandomReal[1., {5}]]; m2 = DiagonalMatrix[RandomReal[1., {5}]];
Wolfram Language code: DiagonalMatrixQ[m1.m2]

对角矩阵也是上三角矩阵和下三角矩阵：

Wolfram Language code: mat = DiagonalMatrix[RandomReal[1., {5}]];
Wolfram Language code: {DiagonalMatrixQ[m1], UpperTriangularMatrixQ[m1], LowerTriangularMatrixQ[m1]}

DiagonalMatrixQ[m,0] 等价于 DiagonalMatrixQ[m]：

Wolfram Language code: {DiagonalMatrixQ[{{1, 0}, {0, 2}}], DiagonalMatrixQ[{{1, 0}, {0, 2}}, 0]}
Wolfram Language code: {DiagonalMatrixQ[{{1, 3}, {4, 2}}], DiagonalMatrixQ[{{1, 3}, {4, 2}}, 0]}

仅具有下对角线或超对角线的矩阵 是幂零矩阵，这意味着对于某些 ，：

Wolfram Language code: m1 = DiagonalMatrix[Range[4], -1]; DiagonalMatrixQ[m1, -1]
Wolfram Language code: MatrixPower[m1, 5]
Wolfram Language code: m2 = DiagonalMatrix[Range[4], 1]; DiagonalMatrixQ[m2, 1]
Wolfram Language code: MatrixPower[m2, 5]

Band 可用来构建 k-对角稀疏矩阵：

Wolfram Language code: k = RandomInteger[5]
Wolfram Language code: m = SparseArray[Band[{1, 1 + k}] -> Range[5], (5 + k){1, 1}]
Wolfram Language code: DiagonalMatrixQ[m, k]
Wolfram Research (2019)，DiagonalMatrixQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

文本

Wolfram Research (2019)，DiagonalMatrixQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

CMS

Wolfram 语言. 2019. "DiagonalMatrixQ." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html.

APA

Wolfram 语言. (2019). DiagonalMatrixQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html 年

BibTeX

@misc{reference.wolfram_2026_diagonalmatrixq, author="Wolfram Research", title="{DiagonalMatrixQ}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html}", note=[Accessed: 21-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_diagonalmatrixq, organization={Wolfram Research}, title={DiagonalMatrixQ}, year={2019}, url={https://reference.wolfram.com/language/ref/DiagonalMatrixQ.html}, note=[Accessed: 21-June-2026]}