WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DictionaryLookup[patt]

文字列パターン patt にマッチする英語の辞書中の単語を探す．

DictionaryLookup[patt,n]

見付かった単語の最初の n 個だけを返す．

DictionaryLookup[{"lang",patt}]

lang で指定された言語中の単語を探す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
オプション  
IgnoreCase  
アプリケーション  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

DictionaryLookup

DictionaryLookup[patt]

文字列パターン patt にマッチする英語の辞書中の単語を探す．

DictionaryLookup[patt,n]

見付かった単語の最初の n 個だけを返す．

DictionaryLookup[{"lang",patt}]

lang で指定された言語中の単語を探す．

詳細とオプション

  • デフォルトでは単語の語尾変化は考慮されないので，"jump"，"jumps"，"jumping"は別々の語とされる．
  • デフォルトで，単語は文中で使われるように表示される．オプション設定IgnoreCase->Trueとすると，大文字小文字が異なって用いられている単語も読み出される．
  • DictionaryLookup[]は辞書中のすべての語のリストを返す．
  • DictionaryLookup[All]は使用可能な辞書言語のリストを与える．
  • DictionaryLookup[{"lang",All}]は，言語辞書 lang にあるすべての語を検索する．
  • DictionaryLookup[{All,patt}]はすべての言語で patt にマッチする語を検索する．

例題

すべて開く すべて閉じる

例  (3)

「abb」で始まるすべての英単語を探す：

Wolfram Language code: DictionaryLookup["abb" ~~ ___]

「c」で始まり「n」で終り，中間に「ñ」があるすべてのスペイン語の単語を求める：

Wolfram Language code: DictionaryLookup[{"Spanish", "c" ~~ ___ ~~ "ñ" ~~ ___ ~~ "n"}]

辞書内の利用可能なすべての単語のリストを取得する：

Wolfram Language code: DictionaryLookup[]

スコープ  (3)

「jumps」と「jumping」のような派生語は別々に現れる：

Wolfram Language code: DictionaryLookup["jump" ~~ ___]

DictionaryLookupは文字列内のパターンをサポートする：

Wolfram Language code: DictionaryLookup["jump*"]

「z」で始まる最初の10個の単語：

Wolfram Language code: DictionaryLookup["z" ~~ ___, 10]

一般化と拡張  (3)

辞書が使用できるすべての言語のリストを与える：

Wolfram Language code: DictionaryLookup[All]

使用可能なすべての言語から「molecu」で始まる語を探す：

Wolfram Language code: DictionaryLookup[{All, "molecu" ~~ ___}]

オランダ語とスペイン語の中で「molecula」で始まる語をすべて求める：

Wolfram Language code: DictionaryLookup[{{"Dutch", "Spanish"}, "molecula" ~~ ___}]

該当語を含むすべての言語を求める：

Wolfram Language code: DictionaryLookup[{All, "fiancée"}]

オプション  (1)

IgnoreCase  (1)

検索が大文字小文字の違いを見ないように指定する：

Wolfram Language code: DictionaryLookup[{"Dutch", "molEcula*"}, IgnoreCase -> True]

アプリケーション  (5)

各文字で始まる辞書中の単語数を求める：

Wolfram Language code: Length[DictionaryLookup[# ~~ ___]]& /@ CharacterRange["a", "z"]
Wolfram Language code: ListPlot[%, Filling -> Axis]

辞書中のすべての回文配列の単語を求める：

Wolfram Language code: DictionaryLookup[x__ /; x === StringReverse[x]]

英語でもありフランス語でもある回文構造のすべての単語を求める：

Wolfram Language code: Intersection[DictionaryLookup[{"English", x__ /; x === StringReverse[x]}], DictionaryLookup[{"French", x__ /; x === StringReverse[x]}]]

いくつの言葉が，「a」，「b」，「c」の可能な各置換形を含んでいるかを求める：

Wolfram Language code: StringJoin /@ Permutations[{"a", "b", "c"}]
Wolfram Language code: Length[DictionaryLookup[___ ~~ # ~~ ___]]& /@ %

「a」から「e」までの文字を使って形成できる4文字の語をすべて求める：

Wolfram Language code: Select[StringJoin /@ Tuples[{"a", "b", "c", "d", "e"}, 4], Length[DictionaryLookup[#]] ≠ 0&]

辞書中のすべての語に最も近い関数を作る：

Wolfram Language code: nf = Nearest[DictionaryLookup[__]]

指定の語に最も近い単語を探す：

Wolfram Language code: nf["pickel"]

さらに探す：

Wolfram Language code: nf["pickel", 10]

おもしろい例題  (4)

どの単語がゲノム配列と紛らわしいかを求める：

Wolfram Language code: DictionaryLookup[("a" | "g" | "c" | "t").., IgnoreCase -> True]

「a」で始まる言葉を10個，辞書からランダムに拾い出す：

Wolfram Language code: RandomChoice[DictionaryLookup["a" ~~ ___], 10]

異なる言語からの単語のランダムな集合：

Wolfram Language code: randomWord[] := RandomChoice[DictionaryLookup[{RandomChoice[DictionaryLookup[All]], All}]];
Wolfram Language code: Graphics[Table[Rotate[Text[Style[randomWord[], Hue[RandomReal[]], Italic, RandomInteger[{10, 30}]], RandomReal[10, 2]], RandomReal[{0, 2Pi}]], {40}], AspectRatio -> 1 / GoldenRatio]

各言語の単語の長さのヒストグラムをプロットする：

Wolfram Language code: Table[Histogram[StringLength /@ DictionaryLookup[{l, All}], {Range[25]}, ImageSize -> 150, PlotLabel -> l, PlotRange -> {{0, 25}, All}], {l, DictionaryLookup[All]}]
Wolfram Research (2007), DictionaryLookup, Wolfram言語関数， https://reference.wolfram.com/language/ref/DictionaryLookup.html （2008年に更新）.

テキスト

Wolfram Research (2007), DictionaryLookup, Wolfram言語関数， https://reference.wolfram.com/language/ref/DictionaryLookup.html （2008年に更新）.

CMS

Wolfram Language. 2007. "DictionaryLookup." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/DictionaryLookup.html.

APA

Wolfram Language. (2007). DictionaryLookup. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DictionaryLookup.html

BibTeX

@misc{reference.wolfram_2026_dictionarylookup, author="Wolfram Research", title="{DictionaryLookup}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/DictionaryLookup.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dictionarylookup, organization={Wolfram Research}, title={DictionaryLookup}, year={2008}, url={https://reference.wolfram.com/language/ref/DictionaryLookup.html}, note=[Accessed: 13-September-2026]}