WOLFRAM

Wolfram 语言与系统参考资料中心

DictionaryLookup[patt]

给出英文词典中所有匹配字符串模式 patt 的单词.

DictionaryLookup[patt,n]

仅给出查到的前 n 个单词.

DictionaryLookup[{"lang",patt}]

在由 lang 指定的语言里找到单词.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
选项  
IgnoreCase  
应用  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

DictionaryLookup

DictionaryLookup[patt]

给出英文词典中所有匹配字符串模式 patt 的单词.

DictionaryLookup[patt,n]

仅给出查到的前 n 个单词.

DictionaryLookup[{"lang",patt}]

在由 lang 指定的语言里找到单词.

更多信息和选项

  • 默认情况下，对单词不进行分组，所以像单词 “jump”、“jumps”和 "jumping"将单独出现.
  • 默认情况下，单词以它们将在句子内的形式出现. 设定选项 IgnoreCase->True 获取以不同大小写格式出现的单词.
  • DictionaryLookup[] 给出词典中所有单词的一个列表.
  • DictionaryLookup[All] 给出词典中可查询的语言列表.
  • DictionaryLookup[{"lang",All}] 在词典中获取匹配 lang 的全部单词.
  • DictionaryLookup[{All,patt}] 在词典中获取匹配 patt 的全部单词.

范例

打开所有单元 关闭所有单元

基本范例  (3)

查找所有以“abb”开头的单词：

Wolfram Language code: DictionaryLookup["abb" ~~ ___]

查找所有以"c"开头，以 "n" 结束，"ñ"在两者之间的西班牙语单词：

Wolfram Language code: DictionaryLookup[{"Spanish", "c" ~~ ___ ~~ "ñ" ~~ ___ ~~ "n"}]

获取字典中所有可用的单词：

Wolfram Language code: DictionaryLookup[]

范围  (3)

如“jumps”和“jumping”一类的变体单独出现：

Wolfram Language code: DictionaryLookup["jump" ~~ ___]

DictionaryLookup 支持以字符串模式：

Wolfram Language code: DictionaryLookup["jump*"]

最初的 10 个以 "z" 开头的单词：

Wolfram Language code: DictionaryLookup["z" ~~ ___, 10]

推广和延伸  (3)

给出可查询的语言字典目录：

Wolfram Language code: DictionaryLookup[All]

查找在所有可用的语言中，以 "molecu" 开头的单词:

Wolfram Language code: DictionaryLookup[{All, "molecu" ~~ ___}]

查找以 "molecula" 开头的荷兰语和西班牙语单词：

Wolfram Language code: DictionaryLookup[{{"Dutch", "Spanish"}, "molecula" ~~ ___}]

查找包含一个词的所有语言：

Wolfram Language code: DictionaryLookup[{All, "fiancée"}]

选项  (1)

IgnoreCase  (1)

指定一个查找不区分大小写：

Wolfram Language code: DictionaryLookup[{"Dutch", "molEcula*"}, IgnoreCase -> True]

应用  (5)

得出词典中用每一个字母开头的单词数：

Wolfram Language code: Length[DictionaryLookup[# ~~ ___]]& /@ CharacterRange["a", "z"]
Wolfram Language code: ListPlot[%, Filling -> Axis]

得出词典中的所有回文单词：

Wolfram Language code: DictionaryLookup[x__ /; x === StringReverse[x]]

找到所有既是英文又是法文的回文单词：

Wolfram Language code: Intersection[DictionaryLookup[{"English", x__ /; x === StringReverse[x]}], DictionaryLookup[{"French", x__ /; x === StringReverse[x]}]]

得出包含每一个"a"，"b" 和 "c" 可能排列的单词数：

Wolfram Language code: StringJoin /@ Permutations[{"a", "b", "c"}]
Wolfram Language code: Length[DictionaryLookup[___ ~~ # ~~ ___]]& /@ %

得出从 "a" 到 "e" 由 4 个字母组成的所有单词：

Wolfram Language code: Select[StringJoin /@ Tuples[{"a", "b", "c", "d", "e"}, 4], Length[DictionaryLookup[#]] ≠ 0&]

从词典中的所有单词生成一个最邻近函数：

Wolfram Language code: nf = Nearest[DictionaryLookup[__]]

查出最靠近一个给定单词的单词：

Wolfram Language code: nf["pickel"]

进一步：

Wolfram Language code: nf["pickel", 10]

巧妙范例  (4)

得出可能同基因序列混淆的单词：

Wolfram Language code: DictionaryLookup[("a" | "g" | "c" | "t").., IgnoreCase -> True]

从词典中挑选10 个任意的以"a" 开头的单词：

Wolfram Language code: RandomChoice[DictionaryLookup["a" ~~ ___], 10]

一个不同语言的随机集合：

Wolfram Language code: randomWord[] := RandomChoice[DictionaryLookup[{RandomChoice[DictionaryLookup[All]], All}]];
Wolfram Language code: Graphics[Table[Rotate[Text[Style[randomWord[], Hue[RandomReal[]], Italic, RandomInteger[{10, 30}]], RandomReal[10, 2]], RandomReal[{0, 2Pi}]], {40}], AspectRatio -> 1 / GoldenRatio]

绘制每种语言的字长直方图：

Wolfram Language code: Table[Histogram[StringLength /@ DictionaryLookup[{l, All}], {Range[25]}, ImageSize -> 150, PlotLabel -> l, PlotRange -> {{0, 25}, All}], {l, DictionaryLookup[All]}]
Wolfram Research (2007)，DictionaryLookup，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DictionaryLookup.html （更新于 2008 年）.

文本

Wolfram Research (2007)，DictionaryLookup，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DictionaryLookup.html （更新于 2008 年）.

CMS

Wolfram 语言. 2007. "DictionaryLookup." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/DictionaryLookup.html.

APA

Wolfram 语言. (2007). DictionaryLookup. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DictionaryLookup.html 年

BibTeX

@misc{reference.wolfram_2026_dictionarylookup, author="Wolfram Research", title="{DictionaryLookup}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/DictionaryLookup.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_dictionarylookup, organization={Wolfram Research}, title={DictionaryLookup}, year={2008}, url={https://reference.wolfram.com/language/ref/DictionaryLookup.html}, note=[Accessed: 13-September-2026]}