WOLFRAM

Wolfram 语言与系统参考资料中心

Differences[list]

给出 list 中元素的逐次差分.

Differences[list,n]

给出 list 的第 n 阶差分.

Differences[list,n,s]

给出步骤 s 的差分.

Differences[list,{n1,n2,…}]

给出一个嵌套列表中在 k 层的第 nk 阶差分.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Differences

Differences[list]

给出 list 中元素的逐次差分.

Differences[list,n]

给出 list 的第 n 阶差分.

Differences[list,n,s]

给出步骤 s 的差分.

Differences[list,{n1,n2,…}]

给出一个嵌套列表中在 k 层的第 nk 阶差分.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

一阶差分：

Wolfram Language code: Differences[{a, b, c, d, e}]

二阶差分：

Wolfram Language code: Differences[{a, b, c, d, e}, 2]

范围  (4)

一阶差分：

Wolfram Language code: Differences[{a, b, c, d, e, f}]

以更具体的方式指定：

Wolfram Language code: Differences[{a, b, c, d, e, f}, 1]

计算相隔两个位置的元素之间的差：

Wolfram Language code: Differences[{a, b, c, d, e, f}, 1, 2]

计算相隔三个位置的元素之间的差：

Wolfram Language code: Differences[{a, b, c, d, e, f}, 1, 3]

在每一列内，行的差分：

Wolfram Language code: Differences[(| | | | | :-- | :-- | :-- | | a11 | a12 | a13 | | a21 | a22 | a23 | | a31 | a32 | a33 |)]//MatrixForm
Wolfram Language code: Differences[(| | | | | :-- | :-- | :-- | | a11 | a12 | a13 | | a21 | a22 | a23 | | a31 | a32 | a33 |), {1, 0}]//MatrixForm

在每一行内，列的差分：

Wolfram Language code: Differences[(| | | | | :-- | :-- | :-- | | a11 | a12 | a13 | | a21 | a22 | a23 | | a31 | a32 | a33 |), {0, 1}]//MatrixForm

规则采样 TimeSeries 的差分：

Wolfram Language code: v = {1, 3, 9, 3, 2}; ts = TimeSeries[v, Automatic]
Wolfram Language code: ts["Path"]
Wolfram Language code: diff = Differences[ts]
Wolfram Language code: diff["Path"]

与对值差分比较：

Wolfram Language code: Differences[v] == diff["Values"]

应用  (3)

通过查看逐次差分何时成为常数，推论序列阶数：

Wolfram Language code: Table[n ^ 5 + 2n - 1, {n, 8}]
Wolfram Language code: FixedPointList[Differences, %]

对高斯的拉普拉斯算子的有限差分近似：

Wolfram Language code: t = Table[Exp[-x ^ 2 - y ^ 2], {x, -2, 2, 0.1}, {y, -2, 2, 0.1}];
Wolfram Language code: ListDensityPlot[Drop[Differences[t, {0, 2}], 2, 0] + Drop[Differences[t, {2, 0}], 0, 2], PlotRange -> All, DataRange -> {{-2, 2}, {-2, 2}}]

股票的收盘价格：

Wolfram Language code: ts = TimeSeries@FinancialData["SBUX", "Close", {2013, 1, 1}]
Wolfram Language code: DateListPlot[ts]

求股票收盘价值的逐日差异：

Wolfram Language code: diff = Differences[ts]
Wolfram Language code: DateListPlot[diff]

求收盘时价格上涨的天数的比例：

Wolfram Language code: res = Tally[Sign[diff]["Values"]]
Wolfram Language code: Select[res, First[#] == 1&][[1, 2]] / ts["PathLength"]//N

属性和关系  (6)

对于一个线性函数的一阶差分是常数：

Wolfram Language code: Table[3i + 6, {i, 10}]
Wolfram Language code: Differences[%]

对于一个二次函数的二阶差分是常数：

Wolfram Language code: Table[3i ^ 2 + 6, {i, 10}]
Wolfram Language code: Differences[%]
Wolfram Language code: Differences[%]

逐次差分是逐渐缩短的：

Wolfram Language code: Column[Table[Differences[Range[10], n], {n, 10}]]

如果 list 的长度为 l，那么 Differences[list,n,s] 的长度为 Ramp[l-ns]：

Wolfram Language code: Table[Length[Differences[Range[10], n, 2]] == Ramp[10 - 2n], {n, 5}]
Wolfram Language code: Table[Length[Differences[Range[10], n, 3]] == Ramp[10 - 3n], {n, 5}]

Differences[list] 等价于 Rest[list]-Most[list]：

Wolfram Language code: list = {a, b, c, d, e}; Differences[list] === Rest[list] - Most[list]

也等同于 ListConvolve[{1,-1},list]：

Wolfram Language code: Differences[list] == ListConvolve[{1, -1}, list]

FoldList 的行为像是 Differences 的反函数：

Wolfram Language code: Differences[{a, b, c, d, e}]
Wolfram Language code: FoldList[Plus, a, %]

可能存在的问题  (1)

不规则采样 TimeSeries 的差分可能与值的差分不同：

Wolfram Language code: v = {1, 3, 9, 3, 2}; t = {0, .3, .4, 1.3, 1.5}; ts = TimeSeries[v, {t}]
Wolfram Language code: RegularlySampledQ[ts]
Wolfram Language code: diff = Differences[ts]
Wolfram Language code: diff["Path"]

与值的 Differences 比较：

Wolfram Language code: Differences[v] == diff["Values"]

将 TemporalRegularity 设为 True，计算新时间序列的差分：

Wolfram Language code: ts1 = TimeSeries[ts, TemporalRegularity -> True];
Wolfram Language code: diff1 = Differences[ts1];

现在，值的差分一致：

Wolfram Language code: diff1["Values"] == Differences[v]

巧妙范例  (2)

一个基于素数的序列的逐次差分模数 2：

Wolfram Language code: ArrayPlot[Mod[PadLeft[NestList[Differences, Array[(Prime[#] - 1) / 2&, 100], 100]], 2]]

帕斯卡-三角形-类模式：

Wolfram Language code: NestList[Differences, Normal[SparseArray[10 -> 1, 21]], 11]
Wolfram Research (2007)，Differences，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Differences.html （更新于 2012 年）.

文本

Wolfram Research (2007)，Differences，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Differences.html （更新于 2012 年）.

CMS

Wolfram 语言. 2007. "Differences." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2012. https://reference.wolfram.com/language/ref/Differences.html.

APA

Wolfram 语言. (2007). Differences. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Differences.html 年

BibTeX

@misc{reference.wolfram_2026_differences, author="Wolfram Research", title="{Differences}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/Differences.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_differences, organization={Wolfram Research}, title={Differences}, year={2012}, url={https://reference.wolfram.com/language/ref/Differences.html}, note=[Accessed: 10-September-2026]}