WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

DiscreteMaxLimit[f,k∞]

k が ∞ に近付くときの数列 f の最大極限k∞f(k) を整数上で与える．

DiscreteMaxLimit[f,{k1,…,kn}]

ネストした最大極限⋯ f(k1,…,kn)を整数上で与える．

DiscreteMaxLimit[f,{k1,…,kn}{,…,}]

多変量最大極限f(k1,…,kn)を整数上で与える．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
初等数列  
周期数列  
Show More Show More
区分数列  
特殊関数数列  
整数論の数列  
多変量数列  
オプション  
Assumptions  
GenerateConditions  
Method  
PerformanceGoal  
アプリケーション  
基本的な応用  
級数収束  
計算の複雑性  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

DiscreteMaxLimit

DiscreteMaxLimit[f,k∞]

k が ∞ に近付くときの数列 f の最大極限k∞f(k) を整数上で与える．

DiscreteMaxLimit[f,{k1,…,kn}]

ネストした最大極限⋯ f(k1,…,kn)を整数上で与える．

DiscreteMaxLimit[f,{k1,…,kn}{,…,}]

多変量最大極限f(k1,…,kn)を整数上で与える．

詳細とオプション

  • DiscreteMaxLimitは，上極限としても知られている．
  • DiscreteMaxLimitは極限の最小上界を計算し，常に実数値数列について定義される．収束条件や実際に極限が存在するかどうかに依存しないその他の漸近的特性を与えるためにしばしば使われる．
  • DiscreteMaxLimit[f,k∞]はf として入力することができる．テンプレートはdMlimで入力し，を使ってカーソルを真下付き文字から本体に移動する．
  • DiscreteMaxLimit[f,{k1,…,kn}{,…,}]は…f として入力できる．
  • 可能な極限点 は±∞である．
  • 最大極限は最大包絡線数列max[ω]の極限として定義される．
  • DiscreteMaxLimit[f,k∞]DiscreteLimit[max[ω],ω∞]
    DiscreteMaxLimit[f,{k1,…,kn}{∞,…,∞}]DiscreteLimit[max[ω],ω∞]
  • DiscreteMaxLimit[f[k],k-∞]はDiscreteMaxLimit[f[-l],l∞]等と等価である．
  • この定義は，一変量の f[k]については最大包絡線 max[ω]MaxValue[{f[k],k≥ω∧k∈},k]を，多変量の f[k1,…,kn]についてはmax[ω]MaxValue[{f[k1,…,kn],k1≥ω∧⋯∧kn≥ω∧ki∈},{k1,…,kn}]を使う．数列max[ω]は ω∞のとき単調減少であるので，常に極限を持つ．それは±∞である可能性がある．
  • 次の図ではmax[k]とmax[Min[k1,k2]]が青で示されている．
  • 最大極限が求まらなかったとき，DiscreteMaxLimitは未評価で返される．
  • 次は使用可能なオプションである．
  • Assumptions $Assumptionsパラメータについての仮定
    GenerateConditions Automaticパラメータについての条件を生成するかどうか
    Method Automatic使用するメソッド
    PerformanceGoal "Quality"パフォーマンスのどの面について最適化するか
  • 次はGenerateConditionsの可能な設定である．
  • Automatic一般的ではない条件のみ
    Trueすべての条件
    False条件なし
    None条件が必要な場合は未評価で返す
  • PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，DiscreteMaxLimitは，一般に，より多くの問題を解いたりより簡単な結果を与えたりすることが多いが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開く すべて閉じる

例  (4)

数列の最大極限：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n, n -> ∞]

積の最大極限：

Wolfram Language code: DiscretePlot[{(3 + (24 / 25) ^ n) Sin[Pi(n / 20)]}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]
Wolfram Language code: DiscreteMaxLimit[(3 + (24 / 25) ^ n) * Sin[Pi(n / 20)], n -> ∞]

dMlimを使ってテンプレートを入力し，を使って真下付き文字から本体に移動する：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]∞]Sin[n]

TraditionalFormによる表示：

Wolfram Language code: DiscreteMaxLimit[f[n], n -> Infinity]//TraditionalForm

スコープ  (21)

基本的な用法  (4)

n がInfinityに近付くときの数列の最大極限を計算する：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), n -> ∞]

n が-Infinityに近付くときの数列の最大極限を計算する：

Wolfram Language code: DiscreteMaxLimit[Sin[n π / 2](5 + 3 ^ n), n -> -∞]

多変量数列のネストした最大極限を計算する：

Wolfram Language code: DiscreteMaxLimit[Cos[m + 1 / (n + 1)], {m -> ∞, n -> ∞}]

数列のリストの最大極限を計算する：

Wolfram Language code: DiscreteMaxLimit[{(2) ^ (-n), Cos[n π]}, n -> ∞]

初等数列  (6)

有理指数数列の最大極限を求める：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n(3n) / (1 + 6n), n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n(3n) / (1 + 6n), 1 / 2}, {n, 0, 50}]

収束等比数列：

Wolfram Language code: DiscreteMaxLimit[(-9 / 10) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-9 / 10) ^ n}, {n, 10, 40}]

振動等比数列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n}, {n, 10, 30}]

発散振動等比数列：

Wolfram Language code: DiscreteMaxLimit[(-3) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-10 / 9) ^ n}, {n, 10, 50}]

指数数列：

Wolfram Language code: DiscreteMaxLimit[E ^ ((-1) ^ n(n) / (n + 2)), n -> ∞]
Wolfram Language code: DiscretePlot[{E ^ ((-1) ^ n(n) / (n + 2)), E}, {n, 1, 50}]

ベキ数列：

Wolfram Language code: DiscreteMaxLimit[2 ^ Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{2 ^ Sin[n], 2}, {n, 1, 50}]

三角数列：

Wolfram Language code: DiscreteMaxLimit[Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{Sin[n], 1}, {n, 1, 150}]
Wolfram Language code: DiscreteMaxLimit[(3n / (n + 1) + (14 / 17) ^ n)Cos[Pi(n / 20)], n -> ∞]
Wolfram Language code: DiscretePlot[{(3 n / (n + 1) + (14 / 17) ^ n) * Cos[Pi(n / 20)], 3}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]

逆三角数列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n ArcTan[n], n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n ArcTan[n], Pi / 2}, {n, 1, 30}]

対数数列：

Wolfram Language code: DiscreteMaxLimit[Log[1 + n / (n + 1)] Sin[n Pi / 5], n -> ∞]
Wolfram Language code: DiscretePlot[{Log[1 + n / (n + 1)] Sin[n Pi / 5], %}, {n, 1, 50}]

周期数列  (3)

周期数列の極限：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 5], n -> ∞]
Wolfram Language code: DiscretePlot[Mod[n, 5], {n, 1, 20}]
Wolfram Language code: DiscreteMaxLimit[Sin[n Pi / 4], n -> ∞]
Wolfram Language code: DiscretePlot[Sin[n Pi / 4], {n, 1, 40}]
Wolfram Language code: DiscreteMaxLimit[Cos[Pi n / 10], n -> ∞]
Wolfram Language code: DiscretePlot[Cos[Pi n / 10], {n, 1, 20}]

最終的に周期的になる数列：

Wolfram Language code: Table[Mod[Factorial[n] + (-1) ^ n, 5], {n, 12}]
Wolfram Language code: DiscreteMaxLimit[Mod[Factorial[n] + (-1) ^ n, 5], n -> ∞]
Wolfram Language code: DiscretePlot[Mod[Factorial[n] + (-1) ^ n, 5], {n, 1, 20}]

密に非周期的な数列：

Wolfram Language code: DiscreteMaxLimit[Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{Sin[n], 1}, {n, 1, 150}]
Wolfram Language code: DiscreteMaxLimit[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], n -> ∞]
Wolfram Language code: N[%]
Wolfram Language code: DiscretePlot[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], {n, 1, 150}]

区分数列  (2)

有限最大極限を持つ区分数列：

Wolfram Language code: DiscreteMaxLimit[Piecewise[{{n, n ≤ 4}}, Sin[n]], n -> ∞]
Wolfram Language code: DiscretePlot[{Piecewise[{{n, n ≤ 4}}, Sin[n] ], 1}, {n, 0, 75}]

無限最大極限を持つ区分数列：

Wolfram Language code: DiscreteMaxLimit[Piecewise[{{Sin[n], n ≤ 10}}, n(-1) ^ n], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{Sin[n], n ≤ 20}}, n(-1) ^ n], {n, 0, 75}]

周期条件を持つ区分数列：

Wolfram Language code: DiscreteMaxLimit[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], {n, 1, 75}]

特殊関数数列  (2)

Fibonacciを含む数列の極限を計算する：

Wolfram Language code: DiscreteMaxLimit[Fibonacci[n]Sin[n Pi / 2] / GoldenRatio ^ n, n -> ∞]

FactorialPowerを含む数列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n(FactorialPower[n, 2] / (7n ^ 2 + 1)), n -> ∞]

整数論の数列  (2)

LCMとGCDを含む極限：

Wolfram Language code: DiscreteMaxLimit[LCM[Mod[n, 3], 20], n -> ∞]
Wolfram Language code: DiscreteMaxLimit[GCD[Mod[n, 56], 33], n -> ∞]

Primeを含む数列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n Prime[n] / (n Log[n]), n -> ∞]
Wolfram Language code: DiscretePlot[(-1) ^ n Prime[n] / (n Log[n]), {n, 10, 100}]

多変量数列  (2)

ネストした最大極限を計算する：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ (m + n) (1000) ^ (1 / n) (m ^ 2 / (m ^ 2 + 1)), {m -> ∞, n -> ∞}]

数列とその極限をプロットする：

Wolfram Language code: DiscretePlot3D[{(-1) ^ (m + n)(1000) ^ (1 / n)(m ^ 2 / (m ^ 2 + 1)), 1}, {n, 50, 60}, {m, 50, 60}, Filling -> None]

多変量最大極限：

Wolfram Language code: DiscreteMaxLimit[(m + n/m n), {m, n} -> {∞, ∞}]
Wolfram Language code: DiscreteMaxLimit[Sin[(π n/3)]Cos[(π m/4)], {m, n} -> {∞, ∞}]

オプション  (6)

Assumptions  (1)

パラメータについての仮定を指定する：

Wolfram Language code: DiscreteMaxLimit[E ^ (a n) Cos[n], n -> ∞]

仮定が変わると結果も変わることがある：

Wolfram Language code: DiscreteMaxLimit[E ^ (a n)Cos[n], n -> ∞, Assumptions -> a > 0]
Wolfram Language code: DiscreteMaxLimit[E ^ (a n)Cos[n], n -> ∞, Assumptions -> a < 0]

GenerateConditions  (3)

初期条件なしで結果を返す：

Wolfram Language code: DiscreteMaxLimit[(1/2 +  ^ n), n -> ∞, GenerateConditions -> False]

結果は x>1のときだけ有効である：

Wolfram Language code: DiscreteMaxLimit[(1/2 +  ^ n), n -> ∞]

結果がパラメータの値に依存する場合は未評価で返される：

Wolfram Language code: DiscreteMaxLimit[Exp[a n]Sin[n], n -> ∞, GenerateConditions -> None]

デフォルトで，一意的な結果を返す条件が生成される：

Wolfram Language code: DiscreteMaxLimit[Exp[a n] Sin[n], n -> ∞]

デフォルトで，特別な値だけが結果を無効にするなら条件は生成されない：

Wolfram Language code: DiscreteMaxLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}]

GenerateConditions->Trueのときは，一般的ではない条件さえもレポートされる：

Wolfram Language code: DiscreteMaxLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}, GenerateConditions -> True]

Method  (1)

周期数列の最大極限をデフォルトメソッドを使って計算する：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 2], n -> ∞]

周期数列用のメソッドを使って同じ答を得る：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 2], n -> ∞, Method -> "Periodic"]

0と1の間で振動しているので，数列の極限は定義されない：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 2], n -> ∞, Method -> "DiscreteLimit"]

PerformanceGoal  (1)

DiscreteMaxLimitは，任意に大きい周期の数列を含む極限を計算する：

Wolfram Language code: expr = 1 / (Mod[n, 31] + 1 / (7 + Mod[n, 10 ^ 5]));
Wolfram Language code: DiscreteMaxLimit[expr, n -> ∞]

PerformanceGoalを使って，そのような場合に高くつくかもしれない計算を避ける：

Wolfram Language code: DiscreteMaxLimit[expr, n -> ∞, PerformanceGoal -> "Speed"]

MethodオプションはPerformanceGoalをオーバーライドする：

Wolfram Language code: DiscreteMaxLimit[expr, n -> ∞, Method -> "Periodic", PerformanceGoal -> "Speed"]

アプリケーション  (7)

基本的な応用  (2)

数列の漸近的上限を計算する：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n E ^ (-10 / n), n -> ∞]

数列と漸近的上限をプロットする：

Wolfram Language code: DiscretePlot[{(-1) ^ n E ^ (-10 / n), 1}, {n, 1, 100}]

次の数列には極限がないことを検証する：

Wolfram Language code: a[n_] := n Sin[5n] / (3n + 1)
Wolfram Language code: DiscretePlot[a[n], {n, 1, 140}]

DiscreteMaxLimitとDiscreteMinLimitは等しくないことを示す：

Wolfram Language code: DiscreteMaxLimit[a[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[a[n], n -> ∞]

DiscreteLimitを使って極限が存在しないことを確認する：

Wolfram Language code: DiscreteLimit[a[n], n -> ∞]

級数収束  (4)

以下で一般項が定義されている無限級数が収束することを，比判定法を使って示す：

Wolfram Language code: a[n_] := Inactive[Product][1 / 2 (Mod[k, 2] + 1 / 5), {k, 1, n}]

級数の部分和をプロットする：

Wolfram Language code: DiscretePlot[Activate[Sum[a[p], {p, 1, n}]], {n, 1, 20}]

DiscreteRatioを使って隣接項の比を計算する：

Wolfram Language code: rat = DiscreteRatio[a[n], n]
Wolfram Language code: Table[rat, {n, 1, 10}]

比の数列は収束しない：

Wolfram Language code: DiscreteLimit[rat, n -> ∞]

しかし，比の上限が1未満なので比検定法を使うことができる：

Wolfram Language code: DiscreteMaxLimit[rat, n -> ∞]

SumConvergenceを使ってこの級数が収束することを確認する：

Wolfram Language code: SumConvergence[a[p]//Activate, p]

無限級数を評価する：

Wolfram Language code: Sum[a[p]//Activate, {p, 1, ∞}]
Wolfram Language code: N[%]

一般項が以下で定義される無限級数が収束することを，ベキ根判定法を使って示す：

Wolfram Language code: a[n_] := (2 / 3) ^ n Mod[n, 2]

級数の部分和をプロットする：

Wolfram Language code: DiscretePlot[Activate[Sum[a[p], {p, 1, n}]], {n, 1, 20}, PlotRange -> {0.1, 1.2}]

一般項の n 乗根を計算する：

Wolfram Language code: root = a[n] ^ (1 / n)
Wolfram Language code: Table[root, {n, 1, 20}]

根の数列の極限は存在しない：

Wolfram Language code: DiscreteLimit[root, n -> ∞]

しかし，最大極限が1未満なので，ベキ根判定法は収束を示唆している：

Wolfram Language code: DiscreteMaxLimit[root, n -> ∞]

SumConvergenceを使ってこの級数が収束することを確認する：

Wolfram Language code: SumConvergence[a[p]//Activate, p]

無限級数を評価する：

Wolfram Language code: Sum[a[n]//Activate, {n, 1, ∞}]

数列 について考える：

Wolfram Language code: c[n_] := (Mod[n, 2]/n!)

関連するベキ級数の逆半径は以下で与えられる：

Wolfram Language code: DiscreteMaxLimit[c[n]^(1/(n)), n -> ∞]

これは，収束半径が無限ですべての z in TemplateBox[{}, Complexes]について，特にに収束することを意味している：

Wolfram Language code: FullSimplify[Underoverscript[∑, n = 0, ∞] (Mod[n, 2]/n!)z^n]

次の関数について，0におけるテイラー(Taylor)級数とその収束半径を計算する：

Wolfram Language code: f[z_] := (1/z^2 + 2)

次テイラー係数はである：

Wolfram Language code: a[n_] = FullSimplify[(1/n!)D[f[z], {z, n}] /. z -> 0]

形式的には，テイラー級数の総和はもとの関数である：

Wolfram Language code: Underoverscript[∑, n = 0, ∞]a[n]z^n == f[z]

テイラー級数の収束半径は以下で与えられる：

Wolfram Language code: r = 1 / DiscreteMaxLimit[Abs[a[n]]^(1/(n)), n -> ∞]

これは，テイラー級数が原点から以内で の値について収束することを意味する．例えば， では次のようになる：

Wolfram Language code: Underoverscript[∑, n = 0, ∞]a[n]I^n == f[I]

の値がこれより遠くなると総和は収束しない．例えば では以下のようになる：

Wolfram Language code: {Underscript[, k -> ∞]Underoverscript[∑, n = 0, k]a[n]2^n, Underscript[, k -> ∞]Underoverscript[∑, n = 0, k]a[n]2^n}

点では，テイラー級数の項がとの間を行ったり来たりする：

Wolfram Language code: Table[a[n](Sqrt[2])^n, {n, 0, 11}]

したがって，部分和はとの間を行ったり来たりする：

Wolfram Language code: Table[Underoverscript[∑, n = 0, k]a[n](Sqrt[2])^n, {k, 0, 11}]

とテイラー級数の部分和を区間で可視化する．区間の内側では収束が早いが，端点ではテイラー多項式は常に または になる：

Wolfram Language code: Plot[Evaluate@Prepend[Table[Underoverscript[∑, n = 0, k]a[n]x^n, {k, 0, 8, 2}], Style[f[x], AbsoluteThickness[2.5]]], {x, -Sqrt[2], Sqrt[2]}, PlotRange -> {0, .5}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

計算の複雑性  (1)

_(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))<inftyのとき，アルゴリズムのランタイム関数 は「big-o of 」()であると言われる：

Wolfram Language code: bigO[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) < ∞

同様に，_(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))<inftyおよび_(n->_(TemplateBox[{}, Integers])infty)(f(n))/(g(n))>0のとき， は「big-theta of 」()であると言われる：

Wolfram Language code: Θ[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) < ∞ && Underscript[, nUnderscript[ -> , ℤ]∞](f/g) > 0

という陳述は常に真である：

Wolfram Language code: bigO[n][f[n], f[n]]

で なら である：

Wolfram Language code: f = 10n ^ 2 + 2n + 1; g = 5 n ^ 3; h = n ^ 4 + 3n ^ 2 + 2; {bigO[n][f, g], bigO[n][g, h], bigO[n][f, h]}

2つの関数がどちらの関係も共有しないこともある：

Wolfram Language code: f = 1; g = (1/n)Mod[-1 + n, 2] + n Mod[n, 2]; {bigO[n][f, g], bigO[n][g, f]}

したがって， はと同様のアルゴリズムランタイムの空間における反射的半順序を定義する：

Wolfram Language code: runtimes = {n ^ 2, 1, n, n Log[n], Exp[n]};
Wolfram Language code: Sort[runtimes, bigO[n]]

で なら である．このことはが同値関係であることを暗示している：

Wolfram Language code: f = 10n ^ 2 + 2n + 1; g = 5 n ^ 2 + 100; {bigO[n][f, g], bigO[n][g, f], Θ[n][f, g], Θ[n][g, f]}

特性と関係  (11)

実数値数列には常に（無限の可能性がある）最大極限がある：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: DiscreteMaxLimit[f[n], n -> ∞]

対応する極限は存在しないかもしれない：

Wolfram Language code: DiscreteLimit[f[n], n -> ∞]

と に有限最大極限があるなら，TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMaxLimit]<=TemplateBox[{f, x, a}, DiscreteMaxLimit]+TemplateBox[{g, x, a}, DiscreteMaxLimit] である：

Wolfram Language code: f[n_] := Sin[n]
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteMaxLimit[f[n] + g[n], n -> ∞] <= DiscreteMaxLimit[f[n], n -> ∞] + DiscreteMaxLimit[g[n], n -> ∞]

この場合は，厳密な不等式が存在する：

Wolfram Language code: DiscreteMaxLimit[f[n] + g[n], n -> ∞] < DiscreteMaxLimit[f[n], n -> ∞] + DiscreteMaxLimit[g[n], n -> ∞]

正の乗法定数は極限の外に出すことができる：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: c = 6;
Wolfram Language code: DiscreteMaxLimit[c f[n], n -> ∞] == c DiscreteMaxLimit[f[n], n -> ∞]

実数値数列については，DiscreteLimitが存在するならDiscreteMaxLimitはそれと同じ値になる：

Wolfram Language code: f[n_] := (-1) ^ n n / (n ^ 2 + 1)
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMaxLimit[f[n], n -> ∞]

が有限極限を有するなら，TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMaxLimit]=TemplateBox[{f, x, a}, DiscreteMaxLimit]+TemplateBox[{g, x, a}, DiscreteMaxLimit] である：

Wolfram Language code: f[n_] := n / (n + 1)
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMaxLimit[f[n] + g[n], n -> ∞] == DiscreteMaxLimit[f[n], n -> ∞] + DiscreteMaxLimit[g[n], n -> ∞]

DiscreteMaxLimitは常にDiscreteMinLimit以上である：

Wolfram Language code: f[n_] := Sin[n]
Wolfram Language code: DiscreteMinLimit[f[n], n -> ∞] ≤ DiscreteMaxLimit[f[n], n -> ∞]

DiscreteMaxLimitとDiscreteMinLimitが等しいなら，その共通の値と等しい極限が存在する：

Wolfram Language code: f[n_] := (n Cos[n]/n^2 + 1)
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n]}

最大極限が, なら，最小極限もそれに等しく，したがって極限もまたである：

Wolfram Language code: f[n_] := -n^2
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]}

DiscreteMaxLimitは-DiscreteMinLimit[-f,…]として計算することができる：

Wolfram Language code: f[n_] := Piecewise[{{n, Mod[n, 2] == 0}, {-1, True}}]
Wolfram Language code: DiscreteMaxLimit[f[x], x -> ∞] == -DiscreteMinLimit[-f[x], x -> ∞]

ならTemplateBox[{{g, (, n, )}, x, a}, MaxLimit2Arg]<=TemplateBox[{{f, (, n, )}, x, a}, MinLimit2Arg]<=TemplateBox[{{f, , {(, n, )}}, x, a}, MaxLimit2Arg]である：

Wolfram Language code: f[n_] := Sin[n / 20] / n
Wolfram Language code: g[n_] := (-1/n)
Wolfram Language code: Reduce[f[n] ≥ g[n]n, Integers]//Simplify
Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] ≤ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] ≤ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

この例のように2つの最大極限が等しいなら， には極限がある：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

これは，はさみうちの定理 （またはサンドイッチ定理）の一般化である：

Wolfram Language code: DiscretePlot[{f[x], g[x]}, {x, 500}, Filling -> {2 -> {1}}]

MaxLimitは常にDiscreteMaxLimit以上である：

Wolfram Language code: g[n_] := Sin[n π + Pi / 4]
Wolfram Language code: DiscreteMaxLimit[g[n], n -> ∞]
Wolfram Language code: MaxLimit[g[n], n -> ∞]
Wolfram Language code: Show[Plot[{g[n], 1, 1 / Sqrt[2]}, {n, 0, 10}, PlotTheme -> "DashedLines"], DiscretePlot[g[n], {n, 0, 10}, PlotMarkers -> {"Point", Large}]]

考えられる問題  (1)

DiscreteMaxLimitは実数値数列に対してのみ定義される：

Wolfram Language code: DiscreteMaxLimit[I, n -> ∞]

おもしろい例題  (1)

数列の最大極限集合を可視化する：

Wolfram Language code: f[n_] := {{Sin[n], 1}, {(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), 3}, {(-1) ^ n, 1}, {(-1) ^ n E ^ (-10 / n), 1}, {n Sin[5n] / (3n + 1), 1 / 3}, {(-1.2) ^ n, 10000}}
Wolfram Language code: range = {{-1.1, 1.1}, {-3.1, 3.1}, {-1.1, 1.1}, {-1, 1}, {-0.36, 0.36}, {-1600, 1600}};
Wolfram Language code: Grid[Partition[Table[With[{r1 = f[n][[m, 1]], r2 = f[n][[m, 2]], r3 = range[[m]]}, DiscretePlot[{r1, r2}, {n, 1, 40}, PlotRange -> r3, ImageSize -> 210, PlotLabel -> Style[HoldForm[DiscreteMaxLimit[r1, n -> Infinity]] == DiscreteMaxLimit[f[n][[m, 1]], n -> Infinity], 13]]], {m, 1, 6}], 2], Frame -> All]
Wolfram Research (2017), DiscreteMaxLimit, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html.

テキスト

Wolfram Research (2017), DiscreteMaxLimit, Wolfram言語関数， https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html.

CMS

Wolfram Language. 2017. "DiscreteMaxLimit." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html.

APA

Wolfram Language. (2017). DiscreteMaxLimit. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html

BibTeX

@misc{reference.wolfram_2026_discretemaxlimit, author="Wolfram Research", title="{DiscreteMaxLimit}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discretemaxlimit, organization={Wolfram Research}, title={DiscreteMaxLimit}, year={2017}, url={https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html}, note=[Accessed: 09-September-2026]}