WOLFRAM

Wolfram 语言与系统参考资料中心

DiscreteMaxLimit[f,k∞]

给出序列 f[k] 当 k 在整数上趋近于 ∞ 时的最大极限 k∞f(k).

DiscreteMaxLimit[f,{k1,…,kn}]

给出整数上的嵌套最大极限 ⋯ f(k1,…,kn).

DiscreteMaxLimit[f,{k1,…,kn}{,…,}]

给出整数上的多变量最大极限 f(k1,…,kn).

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
初等函数序列  
周期序列  
Show More Show More
分段序列  
特殊函数序列  
数论函数序列  
多变量序列  
选项  
Assumptions  
GenerateConditions  
Method  
PerformanceGoal  
应用  
基本应用  
级数收敛  
计算复杂性  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

DiscreteMaxLimit

DiscreteMaxLimit[f,k∞]

给出序列 f[k] 当 k 在整数上趋近于 ∞ 时的最大极限 k∞f(k).

DiscreteMaxLimit[f,{k1,…,kn}]

给出整数上的嵌套最大极限 ⋯ f(k1,…,kn).

DiscreteMaxLimit[f,{k1,…,kn}{,…,}]

给出整数上的多变量最大极限 f(k1,…,kn).

更多信息和选项

  • DiscreteMaxLimit 亦称为 limit superior、supremum limit、limsup、upper limit 和 outer limit.
  • DiscreteMaxLimit 计算极限的最小上限，且总是为实值序列定义. 它通常用于给出不依赖于实际极限的收敛条件和其他渐进属性.
  • 可用 f 来输入 DiscreteMaxLimit[f,k∞]. 可用 dMlim 来输入模板 ，用 把光标从底部移动到主体.
  • 可用 …f 来输入 DiscreteMaxLimit[f,{k1,…,kn}{,…,}].
  • 的极限值为 ±∞.
  • 最大极限被定义为最大包络序列 max[ω] 的极限：
  • DiscreteMaxLimit[f,k∞]DiscreteLimit[max[ω],ω∞]
    DiscreteMaxLimit[f,{k1,…,kn}{∞,…,∞}]DiscreteLimit[max[ω],ω∞]
  • DiscreteMaxLimit[f[k],k-∞] 等价于 DiscreteMaxLimit[f[-l],l∞] 等.
  • 对单变量 f[k]，定义使用最大包络 max[ω]MaxValue[{f[k],k≥ω∧k∈},k]，对多变量 f[k1,…,kn]，则使用 max[ω]MaxValue[{f[k1,…,kn],k1≥ω∧⋯∧kn≥ω∧ki∈},{k1,…,kn}]. ω∞ 时，序列 max[ω] 单调递减，所以它总是有一个极限，可能是 ±∞.
  • 下图中用蓝色显示 max[k] 和 max[Min[k1,k2]].
  • 如果无法找到最大极限，DiscreteMaxLimit 不进行计算，直接返回.
  • 可以给出下列选项：
  • Assumptions $Assumptions对参数的假设
    GenerateConditions Automatic是否为参数生成条件
    Method Automatic所用的方法
    PerformanceGoal "Quality"优化的目标
  • GenerateConditions 的可能设置包括：
  • Automatic只汇报非通用条件
    True汇报所有条件
    False不汇报条件
    None如果需要条件，则不进行计算，直接返回
  • PerformanceGoal 的可能设置包括 $PerformanceGoal、"Quality" 和 "Speed". 如果设置为 "Quality"， DiscreteMaxLimit 通常能求解更多问题或产生更简单的结果，但会需要更多时间和内存.

范例

打开所有单元 关闭所有单元

基本范例  (4)

序列的最大极限：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n, n -> ∞]

乘积的最大极限：

Wolfram Language code: DiscretePlot[{(3 + (24 / 25) ^ n) Sin[Pi(n / 20)]}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]
Wolfram Language code: DiscreteMaxLimit[(3 + (24 / 25) ^ n) * Sin[Pi(n / 20)], n -> ∞]

用 dMlim 输入模板 ， 用 把光标从底部移动到主体：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]∞]Sin[n]

TraditionalForm 输出：

Wolfram Language code: DiscreteMaxLimit[f[n], n -> Infinity]//TraditionalForm

范围  (21)

基本用法  (4)

计算当 n 趋近于 Infinity 时序列的最大极限：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), n -> ∞]

计算当 n 趋近于 -Infinity 时序列的最大极限：

Wolfram Language code: DiscreteMaxLimit[Sin[n π / 2](5 + 3 ^ n), n -> -∞]

计算多变量序列的嵌套最大极限：

Wolfram Language code: DiscreteMaxLimit[Cos[m + 1 / (n + 1)], {m -> ∞, n -> ∞}]

计算一系列序列的最大极限：

Wolfram Language code: DiscreteMaxLimit[{(2) ^ (-n), Cos[n π]}, n -> ∞]

初等函数序列  (6)

求有理指数序列的最大极限：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n(3n) / (1 + 6n), n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n(3n) / (1 + 6n), 1 / 2}, {n, 0, 50}]

收敛几何函数序列：

Wolfram Language code: DiscreteMaxLimit[(-9 / 10) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-9 / 10) ^ n}, {n, 10, 40}]

振荡几何函数序列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n}, {n, 10, 30}]

发散振荡几何函数序列：

Wolfram Language code: DiscreteMaxLimit[(-3) ^ n, n -> ∞]
Wolfram Language code: DiscretePlot[{(-10 / 9) ^ n}, {n, 10, 50}]

指数函数序列：

Wolfram Language code: DiscreteMaxLimit[E ^ ((-1) ^ n(n) / (n + 2)), n -> ∞]
Wolfram Language code: DiscretePlot[{E ^ ((-1) ^ n(n) / (n + 2)), E}, {n, 1, 50}]

幂函数序列：

Wolfram Language code: DiscreteMaxLimit[2 ^ Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{2 ^ Sin[n], 2}, {n, 1, 50}]

三角函数序列：

Wolfram Language code: DiscreteMaxLimit[Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{Sin[n], 1}, {n, 1, 150}]
Wolfram Language code: DiscreteMaxLimit[(3n / (n + 1) + (14 / 17) ^ n)Cos[Pi(n / 20)], n -> ∞]
Wolfram Language code: DiscretePlot[{(3 n / (n + 1) + (14 / 17) ^ n) * Cos[Pi(n / 20)], 3}, {n, 1, 200, 3}, PlotRange -> {-4, 4}]

反三角函数序列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n ArcTan[n], n -> ∞]
Wolfram Language code: DiscretePlot[{(-1) ^ n ArcTan[n], Pi / 2}, {n, 1, 30}]

对数函数序列：

Wolfram Language code: DiscreteMaxLimit[Log[1 + n / (n + 1)] Sin[n Pi / 5], n -> ∞]
Wolfram Language code: DiscretePlot[{Log[1 + n / (n + 1)] Sin[n Pi / 5], %}, {n, 1, 50}]

周期序列  (3)

周期序列的极限：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 5], n -> ∞]
Wolfram Language code: DiscretePlot[Mod[n, 5], {n, 1, 20}]
Wolfram Language code: DiscreteMaxLimit[Sin[n Pi / 4], n -> ∞]
Wolfram Language code: DiscretePlot[Sin[n Pi / 4], {n, 1, 40}]
Wolfram Language code: DiscreteMaxLimit[Cos[Pi n / 10], n -> ∞]
Wolfram Language code: DiscretePlot[Cos[Pi n / 10], {n, 1, 20}]

最终周期序列：

Wolfram Language code: Table[Mod[Factorial[n] + (-1) ^ n, 5], {n, 12}]
Wolfram Language code: DiscreteMaxLimit[Mod[Factorial[n] + (-1) ^ n, 5], n -> ∞]
Wolfram Language code: DiscretePlot[Mod[Factorial[n] + (-1) ^ n, 5], {n, 1, 20}]

密集非周期序列：

Wolfram Language code: DiscreteMaxLimit[Sin[n], n -> ∞]
Wolfram Language code: DiscretePlot[{Sin[n], 1}, {n, 1, 150}]
Wolfram Language code: DiscreteMaxLimit[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], n -> ∞]
Wolfram Language code: N[%]
Wolfram Language code: DiscretePlot[Exp[Sin[2n] ^ 2 / (2 + Cos[n])], {n, 1, 150}]

分段序列  (2)

最大极限为有限值的分段序列：

Wolfram Language code: DiscreteMaxLimit[Piecewise[{{n, n ≤ 4}}, Sin[n]], n -> ∞]
Wolfram Language code: DiscretePlot[{Piecewise[{{n, n ≤ 4}}, Sin[n] ], 1}, {n, 0, 75}]

最大极限为无穷大值的分段序列：

Wolfram Language code: DiscreteMaxLimit[Piecewise[{{Sin[n], n ≤ 10}}, n(-1) ^ n], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{Sin[n], n ≤ 20}}, n(-1) ^ n], {n, 0, 75}]

周期性条件下的分段序列：

Wolfram Language code: DiscreteMaxLimit[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], n -> ∞]
Wolfram Language code: DiscretePlot[Piecewise[{{1 + 1 / n, Mod[n, 2] == 0}, {-1 - 1 / n, Mod[n, 2] == 1}}], {n, 1, 75}]

特殊函数序列  (2)

计算涉及 Fibonacci 的序列的极限：

Wolfram Language code: DiscreteMaxLimit[Fibonacci[n]Sin[n Pi / 2] / GoldenRatio ^ n, n -> ∞]

涉及 FactorialPower 的序列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n(FactorialPower[n, 2] / (7n ^ 2 + 1)), n -> ∞]

数论函数序列  (2)

涉及 LCM 和 GCD 的极限：

Wolfram Language code: DiscreteMaxLimit[LCM[Mod[n, 3], 20], n -> ∞]
Wolfram Language code: DiscreteMaxLimit[GCD[Mod[n, 56], 33], n -> ∞]

涉及 Prime 的序列：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n Prime[n] / (n Log[n]), n -> ∞]
Wolfram Language code: DiscretePlot[(-1) ^ n Prime[n] / (n Log[n]), {n, 10, 100}]

多变量序列  (2)

计算嵌套最大极限：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ (m + n) (1000) ^ (1 / n) (m ^ 2 / (m ^ 2 + 1)), {m -> ∞, n -> ∞}]

绘制序列和它的极限：

Wolfram Language code: DiscretePlot3D[{(-1) ^ (m + n)(1000) ^ (1 / n)(m ^ 2 / (m ^ 2 + 1)), 1}, {n, 50, 60}, {m, 50, 60}, Filling -> None]

多变量最大极限：

Wolfram Language code: DiscreteMaxLimit[(m + n/m n), {m, n} -> {∞, ∞}]
Wolfram Language code: DiscreteMaxLimit[Sin[(π n/3)]Cos[(π m/4)], {m, n} -> {∞, ∞}]

选项  (6)

Assumptions  (1)

指定参数的假设：

Wolfram Language code: DiscreteMaxLimit[E ^ (a n) Cos[n], n -> ∞]

不同的假设会给出不同的结果：

Wolfram Language code: DiscreteMaxLimit[E ^ (a n)Cos[n], n -> ∞, Assumptions -> a > 0]
Wolfram Language code: DiscreteMaxLimit[E ^ (a n)Cos[n], n -> ∞, Assumptions -> a < 0]

GenerateConditions  (3)

不陈述条件，返回结果：

Wolfram Language code: DiscreteMaxLimit[(1/2 +  ^ n), n -> ∞, GenerateConditions -> False]

只有 x>1 时结果才有效：

Wolfram Language code: DiscreteMaxLimit[(1/2 +  ^ n), n -> ∞]

如果结果取决于参数的值，则不进行计算，直接返回：

Wolfram Language code: DiscreteMaxLimit[Exp[a n]Sin[n], n -> ∞, GenerateConditions -> None]

默认情况下，会生成返回唯一结果的条件：

Wolfram Language code: DiscreteMaxLimit[Exp[a n] Sin[n], n -> ∞]

默认情况下，如果只有特殊值使结果无效，则不会生成条件：

Wolfram Language code: DiscreteMaxLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}]

当设置为 GenerateConditions->True 时，即便是非通用条件，也会汇报：

Wolfram Language code: DiscreteMaxLimit[(x y/x^2 + (-1 + a x)^2 y^2), {x, y} -> {∞, ∞}, GenerateConditions -> True]

Method  (1)

用缺省方法计算周期序列的最大极限：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 2], n -> ∞]

用针对周期序列的方法获取同样的答案：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 2], n -> ∞, Method -> "Periodic"]

序列的极限没有定义，因为它在 0 和 1 之间振荡：

Wolfram Language code: DiscreteMaxLimit[Mod[n, 2], n -> ∞, Method -> "DiscreteLimit"]

PerformanceGoal  (1)

DiscreteMaxLimit 计算周期为任意长度的序列的极限：

Wolfram Language code: expr = 1 / (Mod[n, 31] + 1 / (7 + Mod[n, 10 ^ 5]));
Wolfram Language code: DiscreteMaxLimit[expr, n -> ∞]

用 PerformanceGoal 来避免此种花费时间较长的计算：

Wolfram Language code: DiscreteMaxLimit[expr, n -> ∞, PerformanceGoal -> "Speed"]

Method 选项会覆盖 PerformanceGoal：

Wolfram Language code: DiscreteMaxLimit[expr, n -> ∞, Method -> "Periodic", PerformanceGoal -> "Speed"]

应用  (7)

基本应用  (2)

计算序列的渐进上确界：

Wolfram Language code: DiscreteMaxLimit[(-1) ^ n E ^ (-10 / n), n -> ∞]

绘制序列及其渐进上确界：

Wolfram Language code: DiscretePlot[{(-1) ^ n E ^ (-10 / n), 1}, {n, 1, 100}]

验证下列序列没有极限：

Wolfram Language code: a[n_] := n Sin[5n] / (3n + 1)
Wolfram Language code: DiscretePlot[a[n], {n, 1, 140}]

证明 DiscreteMaxLimit 和 DiscreteMinLimit 不相等：

Wolfram Language code: DiscreteMaxLimit[a[n], n -> ∞]
Wolfram Language code: DiscreteMinLimit[a[n], n -> ∞]

用 DiscreteLimit 确认极限不存在：

Wolfram Language code: DiscreteLimit[a[n], n -> ∞]

级数收敛  (4)

用比例检验法证明一般项由下式给出的无穷级数收敛：

Wolfram Language code: a[n_] := Inactive[Product][1 / 2 (Mod[k, 2] + 1 / 5), {k, 1, n}]

绘制级数的部分和：

Wolfram Language code: DiscretePlot[Activate[Sum[a[p], {p, 1, n}]], {n, 1, 20}]

用 DiscreteRatio 计算相邻项的比：

Wolfram Language code: rat = DiscreteRatio[a[n], n]
Wolfram Language code: Table[rat, {n, 1, 10}]

比的序列不收敛：

Wolfram Language code: DiscreteLimit[rat, n -> ∞]

但是，依然可以使用比例检验法，因为比值的上限小于 1：

Wolfram Language code: DiscreteMaxLimit[rat, n -> ∞]

用 SumConvergence 确认级数是收敛的：

Wolfram Language code: SumConvergence[a[p]//Activate, p]

计算无穷级数：

Wolfram Language code: Sum[a[p]//Activate, {p, 1, ∞}]
Wolfram Language code: N[%]

用根检验法证明一般项由下式给出的无穷级数收敛：

Wolfram Language code: a[n_] := (2 / 3) ^ n Mod[n, 2]

绘制级数的部分和：

Wolfram Language code: DiscretePlot[Activate[Sum[a[p], {p, 1, n}]], {n, 1, 20}, PlotRange -> {0.1, 1.2}]

计算一般项的第 n 个根：

Wolfram Language code: root = a[n] ^ (1 / n)
Wolfram Language code: Table[root, {n, 1, 20}]

根序列的极限不存在：

Wolfram Language code: DiscreteLimit[root, n -> ∞]

但是，根检验法还是表明序列是收敛的，因为最大极限小于 1：

Wolfram Language code: DiscreteMaxLimit[root, n -> ∞]

用 SumConvergence 确认级数是收敛的：

Wolfram Language code: SumConvergence[a[p]//Activate, p]

计算无穷级数：

Wolfram Language code: Sum[a[n]//Activate, {n, 1, ∞}]

考虑序列 ：

Wolfram Language code: c[n_] := (Mod[n, 2]/n!)

相关幂级数的反向半径 为：

Wolfram Language code: DiscreteMaxLimit[c[n]^(1/(n)), n -> ∞]

这意味着收敛半径为无穷大，对于所有 z in TemplateBox[{}, Complexes]，收敛于 ：

Wolfram Language code: FullSimplify[Underoverscript[∑, n = 0, ∞] (Mod[n, 2]/n!)z^n]

计算下列函数在零处的泰勒级数和收敛半径：

Wolfram Language code: f[z_] := (1/z^2 + 2)

第 个泰勒系数为 ：

Wolfram Language code: a[n_] = FullSimplify[(1/n!)D[f[z], {z, n}] /. z -> 0]

泰勒级数的和是原来的函数：

Wolfram Language code: Underoverscript[∑, n = 0, ∞]a[n]z^n == f[z]

泰勒级数的收敛半径为：

Wolfram Language code: r = 1 / DiscreteMaxLimit[Abs[a[n]]^(1/(n)), n -> ∞]

这表明泰勒级数对于距原点 的范围内的 值是收敛的. 例如，在 处：

Wolfram Language code: Underoverscript[∑, n = 0, ∞]a[n]I^n == f[I]

对于更远处的 值，和是不收敛的；例如，在 处：

Wolfram Language code: {Underscript[, k -> ∞]Underoverscript[∑, n = 0, k]a[n]2^n, Underscript[, k -> ∞]Underoverscript[∑, n = 0, k]a[n]2^n}

在点 处，泰勒级数的项在 和 之间交替出现：

Wolfram Language code: Table[a[n](Sqrt[2])^n, {n, 0, 11}]

因此，部分和位于 和 之间：

Wolfram Language code: Table[Underoverscript[∑, n = 0, k]a[n](Sqrt[2])^n, {k, 0, 11}]

可视化 及其泰勒级数在 区间上的部分和；在区间内部，收敛是快速的，但泰勒多项式在端点处总是为 或 ：

Wolfram Language code: Plot[Evaluate@Prepend[Table[Underoverscript[∑, n = 0, k]a[n]x^n, {k, 0, 8, 2}], Style[f[x], AbsoluteThickness[2.5]]], {x, -Sqrt[2], Sqrt[2]}, PlotRange -> {0, .5}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

计算复杂性  (1)

一个算法运行时间函数 被认为是 "big-o of "，写作 ，如果 _(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))<infty：

Wolfram Language code: bigO[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) < ∞

同样， 还被认为是 "big-theta of "，写作 ，如果 _(n->_(TemplateBox[{}, Integers])infty) (f(n))/(g(n))<infty 和 _(n->_(TemplateBox[{}, Integers])infty)(f(n))/(g(n))>0：

Wolfram Language code: Θ[n_][f_, g_] := Underscript[, nUnderscript[ -> , ℤ]∞](f/g) < ∞ && Underscript[, nUnderscript[ -> , ℤ]∞](f/g) > 0

总是为真：

Wolfram Language code: bigO[n][f[n], f[n]]

如果 和 ，则 ：

Wolfram Language code: f = 10n ^ 2 + 2n + 1; g = 5 n ^ 3; h = n ^ 4 + 3n ^ 2 + 2; {bigO[n][f, g], bigO[n][g, h], bigO[n][f, h]}

两个函数不可能共享两种关系：

Wolfram Language code: f = 1; g = (1/n)Mod[-1 + n, 2] + n Mod[n, 2]; {bigO[n][f, g], bigO[n][g, f]}

因此， 在算法运行时间空间 (runtime space) 上定义了自反部分关系，类似于 ：

Wolfram Language code: runtimes = {n ^ 2, 1, n, n Log[n], Exp[n]};
Wolfram Language code: Sort[runtimes, bigO[n]]

如果 和 ，则 ，表明 是一个等价关系：

Wolfram Language code: f = 10n ^ 2 + 2n + 1; g = 5 n ^ 2 + 100; {bigO[n][f, g], bigO[n][g, f], Θ[n][f, g], Θ[n][g, f]}

属性和关系  (11)

实值序列总是有最大极限（可能是无穷大）：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: DiscreteMaxLimit[f[n], n -> ∞]

相应的极限则有可能不存在：

Wolfram Language code: DiscreteLimit[f[n], n -> ∞]

如果 和 的最大极限为有限值，则 TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMaxLimit]<=TemplateBox[{f, x, a}, DiscreteMaxLimit]+TemplateBox[{g, x, a}, DiscreteMaxLimit]：

Wolfram Language code: f[n_] := Sin[n]
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteMaxLimit[f[n] + g[n], n -> ∞] <= DiscreteMaxLimit[f[n], n -> ∞] + DiscreteMaxLimit[g[n], n -> ∞]

在这种情况下，存在严格的不相等性：

Wolfram Language code: DiscreteMaxLimit[f[n] + g[n], n -> ∞] < DiscreteMaxLimit[f[n], n -> ∞] + DiscreteMaxLimit[g[n], n -> ∞]

正的乘数常数可以被移到极限外面：

Wolfram Language code: f[n_] := (-1) ^ n
Wolfram Language code: c = 6;
Wolfram Language code: DiscreteMaxLimit[c f[n], n -> ∞] == c DiscreteMaxLimit[f[n], n -> ∞]

对于实值序列，如果 DiscreteLimit 存在，DiscreteMaxLimit 的值与之相等：

Wolfram Language code: f[n_] := (-1) ^ n n / (n ^ 2 + 1)
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMaxLimit[f[n], n -> ∞]

如果 的极限为有限值，则 TemplateBox[{{(, {f, +, g}, )}, x, a}, DiscreteMaxLimit]=TemplateBox[{f, x, a}, DiscreteMaxLimit]+TemplateBox[{g, x, a}, DiscreteMaxLimit]：

Wolfram Language code: f[n_] := n / (n + 1)
Wolfram Language code: g[n_] := Cos[n]
Wolfram Language code: DiscreteLimit[f[n], n -> ∞]
Wolfram Language code: DiscreteMaxLimit[f[n] + g[n], n -> ∞] == DiscreteMaxLimit[f[n], n -> ∞] + DiscreteMaxLimit[g[n], n -> ∞]

DiscreteMaxLimit 总是大于或等于 DiscreteMinLimit：

Wolfram Language code: f[n_] := Sin[n]
Wolfram Language code: DiscreteMinLimit[f[n], n -> ∞] ≤ DiscreteMaxLimit[f[n], n -> ∞]

如果 DiscreteMaxLimit 等于 DiscreteMinLimit，极限存在并等于它们共有的值：

Wolfram Language code: f[n_] := (n Cos[n]/n^2 + 1)
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n], Underscript[, nUnderscript[ -> , ℤ]∞]f[n]}

如果最大极限为 ，那么最小极限和极限也等于 ：

Wolfram Language code: f[n_] := -n^2
Wolfram Language code: {Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n], Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]}

可用 -DiscreteMinLimit[-f,…] 来计算 DiscreteMaxLimit：

Wolfram Language code: f[n_] := Piecewise[{{n, Mod[n, 2] == 0}, {-1, True}}]
Wolfram Language code: DiscreteMaxLimit[f[x], x -> ∞] == -DiscreteMinLimit[-f[x], x -> ∞]

如果 ，则 TemplateBox[{{g, (, n, )}, x, a}, MaxLimit2Arg]<=TemplateBox[{{f, (, n, )}, x, a}, MinLimit2Arg]<=TemplateBox[{{f, , {(, n, )}}, x, a}, MaxLimit2Arg]：

Wolfram Language code: f[n_] := Sin[n / 20] / n
Wolfram Language code: g[n_] := (-1/n)
Wolfram Language code: Reduce[f[n] ≥ g[n]n, Integers]//Simplify
Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] ≤ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] ≤ Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

如果两个最大极限相等，如此例，那么 的极限存在：

Wolfram Language code: Underscript[, nUnderscript[ -> , ℤ]-∞]f[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]g[n] == Underscript[, nUnderscript[ -> , ℤ]-∞]f[n]

这是 "squeezing" 或 "sandwich" 定理的推广：

Wolfram Language code: DiscretePlot[{f[x], g[x]}, {x, 500}, Filling -> {2 -> {1}}]

MaxLimit 总是大于或等于 DiscreteMaxLimit：

Wolfram Language code: g[n_] := Sin[n π + Pi / 4]
Wolfram Language code: DiscreteMaxLimit[g[n], n -> ∞]
Wolfram Language code: MaxLimit[g[n], n -> ∞]
Wolfram Language code: Show[Plot[{g[n], 1, 1 / Sqrt[2]}, {n, 0, 10}, PlotTheme -> "DashedLines"], DiscretePlot[g[n], {n, 0, 10}, PlotMarkers -> {"Point", Large}]]

可能存在的问题  (1)

DiscreteMaxLimit 只对实值序列有定义：

Wolfram Language code: DiscreteMaxLimit[I, n -> ∞]

巧妙范例  (1)

可视化一组序列的最大极限：

Wolfram Language code: f[n_] := {{Sin[n], 1}, {(-1) ^ n 3n ^ 2 / (n ^ 2 + 5), 3}, {(-1) ^ n, 1}, {(-1) ^ n E ^ (-10 / n), 1}, {n Sin[5n] / (3n + 1), 1 / 3}, {(-1.2) ^ n, 10000}}
Wolfram Language code: range = {{-1.1, 1.1}, {-3.1, 3.1}, {-1.1, 1.1}, {-1, 1}, {-0.36, 0.36}, {-1600, 1600}};
Wolfram Language code: Grid[Partition[Table[With[{r1 = f[n][[m, 1]], r2 = f[n][[m, 2]], r3 = range[[m]]}, DiscretePlot[{r1, r2}, {n, 1, 40}, PlotRange -> r3, ImageSize -> 210, PlotLabel -> Style[HoldForm[DiscreteMaxLimit[r1, n -> Infinity]] == DiscreteMaxLimit[f[n][[m, 1]], n -> Infinity], 13]]], {m, 1, 6}], 2], Frame -> All]
Wolfram Research (2017)，DiscreteMaxLimit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html.

文本

Wolfram Research (2017)，DiscreteMaxLimit，Wolfram 语言函数，https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html.

CMS

Wolfram 语言. 2017. "DiscreteMaxLimit." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html.

APA

Wolfram 语言. (2017). DiscreteMaxLimit. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html 年

BibTeX

@misc{reference.wolfram_2026_discretemaxlimit, author="Wolfram Research", title="{DiscreteMaxLimit}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_discretemaxlimit, organization={Wolfram Research}, title={DiscreteMaxLimit}, year={2017}, url={https://reference.wolfram.com/language/ref/DiscreteMaxLimit.html}, note=[Accessed: 15-September-2026]}