WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Distribute[f[x1,x2,…]]

xiに現れるPlusに対し f を分配する．

Distribute[expr,g]

g に対し分配する．

Distribute[expr,g,f]

式 expr の頭部が f であるものに限って分配を実行する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Distribute

Distribute[f[x1,x2,…]]

xiに現れるPlusに対し f を分配する．

Distribute[expr,g]

g に対し分配する．

Distribute[expr,g,f]

式 expr の頭部が f であるものに限って分配を実行する．

詳細

  • Distributeは，実質的に演算子 f および g の分配則を実装する．
  • Distributeは，分配の完全な結果を一気に構成する．一方，Expandは，各段階で簡約化を行いながら反復して結果を組み上げていく．
  • Distribute[expr,g,f,gp,fp]は，分配の結果として g と f の代りにそれぞれ gp と fp を与える． »

例題

すべて開く すべて閉じる

例  (3)

分配法則を適用する：

Wolfram Language code: Distribute[(a + b).(x + y + z)]

fをPlusに分配する：

Wolfram Language code: Distribute[f[a + b, c + d + e]]

fをgに分配する：

Wolfram Language code: Distribute[f[g[a, b], g[c, d, e]], g]

スコープ  (4)

デフォルトで，Plusに分配する：

Wolfram Language code: Distribute[(a + b + c)(u + v), Plus]
Wolfram Language code: Distribute[(a + b + c)(u + v)]

総和の積のみ分配する：

Wolfram Language code: Distribute[(a + b + c)(u + v), Plus, Times]
Wolfram Language code: Distribute[(a + b + c) ^ (u + v), Plus, Times]

論理演算子の分配法則：

Wolfram Language code: Distribute[And[Or[a, b, c], Or[u, v]], Or, And]
Wolfram Language code: Distribute[Or[And[a, b, c], And[u, v]], And, Or]
Wolfram Language code: Distribute[And[Xor[a, b, c], Xor[u, v]], Xor, And]

分配法則を任意の演算子に適用する：

Wolfram Language code: Distribute[(a⊕b⊕c)⊗(u⊕v), CirclePlus, CircleTimes]

一般化と拡張  (1)

fをgに分配し，fpとgpを得る：

Wolfram Language code: Distribute[f[g[a, b], g[c, d, e]], g, f, gp, fp]
Wolfram Language code: Distribute[(a + b + c)(u + v), Plus, Times, plus, times]

アプリケーション  (5)

記号行列とベクトル式を展開する：

Wolfram Language code: Distribute[(m1 + m2).(m3 + m4)]
Wolfram Language code: Distribute[(v1 + v2)⨯(v3 + v4)]

演算子を使って分配法則を適用する：

Wolfram Language code: Distribute[(a + b)⊕(x + y + z)⊕(s + t)]

要素の可能なすべての組合せのリストを求める：

Wolfram Language code: Distribute[{{a, b}, {x, y, z}, {s, t}}, List]

ベキ集合を生成する：

Wolfram Language code: Distribute[{{}, {#}}& /@ {a, b, c}, List, List, List, Join]

分配法則を直接適用して中間の項を求める：

Wolfram Language code: Distribute[Factor[x ^ 6 - 1], Plus, Times, List, Times]
Wolfram Language code: Plus@@%

特性と関係  (3)

純粋な積については，DistributeはExpandと同じ結果を返す：

Wolfram Language code: Factor[x ^ 10 - 1]
Wolfram Language code: Distribute[%]

PowerExpandはTimesに分配することに相当する：

Wolfram Language code: PowerExpand[(x y z) ^ n]
Wolfram Language code: Distribute[(x y z) ^ n, Times]

Outerも，すべての要素の同じ組合せを作るが，その構造はネスト構造である：

Wolfram Language code: Outer[List, {a, b, c}, {x, y}]
Wolfram Language code: Distribute[{{a, b, c}, {x, y}}, List]

考えられる問題  (2)

Distributeのこの使い方は期待される結果を与えない：

Wolfram Language code: Distribute[(a + b) * (a + b)]

引数が最初に評価され積が消えてしまうからである：

Wolfram Language code: (a + b) * (a + b)
Wolfram Language code: Distribute[%]

Distributeが引数を見る前に引数が評価されないようにする：

Wolfram Language code: Distribute[Unevaluated[(a + b) * (a + b)]]

Distributeは数学的に正しい結果を返すとは限らない：

Wolfram Language code: Distribute[u ^ (a + b)]

変換を回避するために，Timesの出現へのアプリケーションを制限する：

Wolfram Language code: Distribute[u ^ (a + b), Plus, Times]

おもしろい例題  (1)

リストの部分リストのすべての可能な総和を求める：

Wolfram Language code: Union[Distribute[Thread[{{1, 2, 2, 8}, 0}], List, List, List, Plus]]
Wolfram Research (1988), Distribute, Wolfram言語関数， https://reference.wolfram.com/language/ref/Distribute.html.

テキスト

Wolfram Research (1988), Distribute, Wolfram言語関数， https://reference.wolfram.com/language/ref/Distribute.html.

CMS

Wolfram Language. 1988. "Distribute." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Distribute.html.

APA

Wolfram Language. (1988). Distribute. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Distribute.html

BibTeX

@misc{reference.wolfram_2026_distribute, author="Wolfram Research", title="{Distribute}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Distribute.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_distribute, organization={Wolfram Research}, title={Distribute}, year={1988}, url={https://reference.wolfram.com/language/ref/Distribute.html}, note=[Accessed: 11-September-2026]}