WOLFRAM

Wolfram 语言与系统参考资料中心

Do[expr,n]

对 expr 计算 n 次.

Do[expr,{i,imax}]

将变量 i 从 1 递增到 imax（步长为 1），计算 expr.

Do[expr,{i,imin,imax}]

从 i=imin 开始.

Do[expr,{i,imin,imax,di}]

使用步长 di.

Do[expr,{i,{i1,i2,…}}]

使用连续的值 i1、i2、….

Do[expr,{i,imin,imax},{j,jmin,jmax},…]

对于每个 i，循环地根据不同的 j 等，计算 expr.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Do

Do[expr,n]

对 expr 计算 n 次.

Do[expr,{i,imax}]

将变量 i 从 1 递增到 imax（步长为 1），计算 expr.

Do[expr,{i,imin,imax}]

从 i=imin 开始.

Do[expr,{i,imin,imax,di}]

使用步长 di.

Do[expr,{i,{i1,i2,…}}]

使用连续的值 i1、i2、….

Do[expr,{i,imin,imax},{j,jmin,jmax},…]

对于每个 i，循环地根据不同的 j 等，计算 expr.

更多信息

  • Do 使用标准的 Wolfram 语言迭代规则.
  • 您可以在 Do 中使用 Return、Break、Continue 和 Throw.
  • 除非使用明确的 Return，由 Do 返回的值是 Null.
  • Do[expr,Infinity] 连续运算 expr，直到明确通过函数 Break、Return、Throw、Abort 或 Quit 等被告知 退出运行.
  • Do[expr,spec] 首先计算 spec，然后局部化指定的变量，依次对其连续赋值，每次计算 expr.
  • Do 实际上用 Block 来实现值或变量的局部化.
  • Do[expr,spec1,spec2] 实际上等价于 Do[Do[expr,spec2],spec1].
  • Parallelize[Do[expr,iter]] 或 ParallelDo[expr,iter] 在所有子核中并行计算 Do[expr,iter]. »

范例

打开所有单元 关闭所有单元

基本范例  (3)

显示前四个平方：

Wolfram Language code: Do[Print[n ^ 2], {n, 4}]

n 从 -3 到 5，步长为 2：

Wolfram Language code: Do[Print[n], {n, -3, 5, 2}]

显示4个随机整数：

Wolfram Language code: Do[Print[RandomInteger[10]], 4]

范围  (8)

计算 Print[x] 两次：

Wolfram Language code: Do[Print[x], {2}]

步长可以是负值：

Wolfram Language code: Do[Print[i], {i, 10, 8, -1}]

可以是符号值：

Wolfram Language code: Do[Print[n], {n, x, x + 3y, y}]

循环 i 和 j，j 运行到 i-1：

Wolfram Language code: Do[Print[{i, j}], {i, 4}, {j, i - 1}]

主体可以是程序：

Wolfram Language code: t = 67;Do[Print[t];t = Floor[t / 2], {3}]

Break 从 Do 循环中退出：

Wolfram Language code: t = 1;Do[t *= k;Print[t];If[t > 19, Break[]], {k, 10}]

Continue 保持循环，但不执行主体的剩余部分：

Wolfram Language code: t = 1;Do[t *= k;Print[t];If[k < 2, Continue[]];t += 2, {k, 5}]

无穷循环，直至满足某条件：

Wolfram Language code: Do[If[k ^ 2 > 100, Return[k]], {k, ∞}]

推广和延伸  (2)

给出一个值的列表来迭代：

Wolfram Language code: Do[Print[k], {k, {a, b, c, d}}]

ParallelDo 并行计算 Do：

Wolfram Language code: ParallelDo[Print[i];i, {i, 4}]

Do 有效地使用 ParallelDo 自动并行运行：

Wolfram Language code: Parallelize[Do[Print[i];i, {i, 4}]]

应用  (5)

创建一个符号连分式：

Wolfram Language code: t = x;Do[t = 1 / (1 + t), {5}];t
Wolfram Language code: Nest[1 / (1 + #)&, x, 5]

创建一个素数列表：

Wolfram Language code: t = {};Do[If[PrimeQ[2 ^ n - 1], AppendTo[t, n]], {n, 100}];t

选择使用 Reap 和 Sow：

Wolfram Language code: Reap[Do[If[PrimeQ[2 ^ n - 1], Sow[n]], {n, 100}]][[2, 1]]

执行回代：

Wolfram Language code: upperTriangularLinearSolve[ U_, v_ ] := Module[ {x, m, n}, {m, n} = Dimensions[U]; x = Range[n]; Do[x[[i]] = (v[[i]] - U[[i, i + 1 ;; n]].x[[i + 1 ;; n]]) / U[[i, i]], {i, n, 1, -1}]; x];
Wolfram Language code: upperTriangularLinearSolve[{{1, 2}, {0, 3}}, {1, 2} ]

执行矩阵的 LU 三角分解：

Wolfram Language code: lu[A_] := Module[{m, n, L, U}, {m, n} = Dimensions[A];L = IdentityMatrix[n];U = A; Do[ L[[k ;; n, k]] = U[[k ;; n, k]] / U[[k, k]]; U[[(k + 1) ;; n, k ;; n]] = U[[(k + 1) ;; n, k ;; n]] - L[[(k + 1) ;; n, {k}]].U[[{k}, k ;; n]]; , {k, 1, n - 1}]; {L, U} ];
Wolfram Language code: {l, u} = lu[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}]
Wolfram Language code: l.u

选择排序算法：

Wolfram Language code: list = RandomSample[Range[10], 10]
Wolfram Language code: Do[If[list[[i]] > list[[j]], list[[{i, j}]] = list[[{j, i}]]], {i, Length[list]}, {j, i + 1, Length[list]}];list

属性和关系  (2)

相等的循环：

Wolfram Language code: Do[Print[i], {i, 3}]
Wolfram Language code: For[i = 1, i ≤ 3, i++, Print[i]]
Wolfram Language code: i = 1;While[i ≤ 3, Print[i];i++]
Wolfram Language code: Scan[Print, Range[3]]

无穷循环，直至满足某条件：

Wolfram Language code: i = 1;Do[If[i ^ 2 > 100, Return[i], i++], ∞]
Wolfram Language code: i = 1;While[True, If[i ^ 2 > 100, Return[i], i++]]
Wolfram Research (1988)，Do，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Do.html （更新于 2015 年）.

文本

Wolfram Research (1988)，Do，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Do.html （更新于 2015 年）.

CMS

Wolfram 语言. 1988. "Do." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/Do.html.

APA

Wolfram 语言. (1988). Do. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Do.html 年

BibTeX

@misc{reference.wolfram_2026_do, author="Wolfram Research", title="{Do}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/Do.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_do, organization={Wolfram Research}, title={Do}, year={2015}, url={https://reference.wolfram.com/language/ref/Do.html}, note=[Accessed: 15-September-2026]}