Wolfram 语言与系统参考资料中心

ElectricCurrentDensityValue

ElectricCurrentDensityValue[pred,vars,pars]

表示偏微分方程的当前密度边界条件，谓词 pred 指示其适用位置，并具有模型变量 vars 和全局参数 pars.

ElectricCurrentDensityValue[pred,vars,pars,lkey]

表示电流密度边界条件，其局部参数在 pars[lkey] 中指定.

更多信息

ElectricCurrentDensityValue 指定 ElectricCurrentPDEComponent 的边界条件，并用作以下建模方程的一部分：

ElectricCurrentDensityValue 用于对垂直于边界、进入或离开边界的电流密度（单位为 [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]）进行建模.
正值表示流入的电流，负值表示流出的电流.
ElectricCurrentDensityValue 模拟垂直于边界的电流密度，其中因变量，单位为伏特 []，自变量，单位为 [].
稳态变量 vars 为 vars={V[x₁,…,x_n],{x₁,…,x_n}}.
与频率相关的变量 vars 为 vars={V[x₁,…,x_n],ω,{x₁,…,x_n}}.
给定垂直于边界的标量电流密度，ElectricCurrentDensityValue 模拟：

给定电流密度向量 [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]，ElectricCurrentDensityValue 模拟：

其中为单位法线.
给定垂直于边界的电流 []，ElectricCurrentDensityValue 模拟：

其中 [ $TemplateBox[{InterpretationBox[, 1], {{"m", ^, 2}}, meters squared, {"Meters", ^, 2}}, QuantityTF]$ ] 为边界面积. 电流自动转换为法向电流密度 .
模型参数 pars 的指定与 ElectricCurrentPDEComponent 相同.
可以给出以下附加模型参数 pars：

参数	默认值	符号
	"BoundaryUnitNormal"	Automatic
	"Current"		，电流，单位为 []
	"CurrentDensity"	{0,...}	，电流密度，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
	"NormalCurrentDensity"		，法向电流密度，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
	"Thickness"	-	，厚度，单位为 []

所有模型参数可能取决于空间变量 .
在二维情况下，将考虑参数 "Thickness"，以将电流从单位 [] 转化为 [ $TemplateBox[{InterpretationBox[, 1], {"A", , "/", , {"m", ^, 2}}, amperes per meter squared, {{(, "Amperes", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ].
为了本地化模型参数，可以指定键 lkey，并将关联 pars[lkey] 中的值用于模型参数.
预设的电流密度边界条件可用于以下情况：
分析类型 是否适用

频率响应是

静态是
ElectricCurrentDensityValue 运算为 NeumannValue.
边界谓词 pred 可以像在 NeumannValue 中一样指定.
如果 ElectricCurrentDensityValue 取决于在关联 pars 中指定为 …,keyp_i…,p_iv_i,… 的参数，则参数将替换为 .

范例

打开所有单元关闭所有单元

基本范例 (3)

建立符号电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x >= 0, {V[x, y], {x, y}}, <|"NormalCurrentDensity" -> Jn|>]

用电流密度设置符号电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x >= 0, {V[x, y], {x, y}}, <|"CurrentDensity" -> {J0x, J0y}|>]

对一根受到直流电流 ( []) 激励的铜线进行建模，在其左下边界应用电流密度边界条件，并在右下边界应用零电势条件.

设置稳态电流偏微分方程模型变量和：

Wolfram Language code:

vars = {V[x, y], {x, y}};
pars = <|"Material" -> Entity["Element", "Copper"]|>;

建立方程：

Wolfram Language code: op = ElectricCurrentPDEComponent[vars, pars];

定义导线的几何形状：

Wolfram Language code: Ω = RegionUnion[Rectangle[{0, 0}, {1 / 3, 1}], Rectangle[{1 / 3, 2 / 3}, {2, 1}], Rectangle[{2 - 1 / 3, 0}, {2, 1}]];

可视化电线：

Wolfram Language code: RegionPlot[Ω]

指定右下边界处的接地电位：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[x >= 2 - 1 / 3 && y == 0, vars, pars, <|"ElectricPotential" -> 0|>];

指定左下边界处的向内电流：

Wolfram Language code: Subscript[Γ, source] = ElectricCurrentDensityValue[x <= 1 / 3 && y == 0, vars, pars, <|"Current" -> 1|>];

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{op == Subscript[Γ, source], Subscript[Γ, ground]}, V, {x, y}∈Ω]

可视化电势：

Wolfram Language code: DensityPlot[Vfun[x, y], {x, y}∈Ω, ...]

范围 (6)

创建电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], {x, y, z}}, <|"CurrentDensity" -> {10, 0, 0}|>]

创建具有边界单位法线的电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y], {x, y}}, <|"CurrentDensity" -> {10, 0}, "BoundaryUnitNormal" -> {-1, 0}|>]

使用创建电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], {x, y, z}}, <|"NormalCurrentDensity" -> Jn|>]

使用电流创建电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], {x, y, z}}, <|"Current" -> I0|>]

使用电流和厚度创建二维电流密度边界条件：

Wolfram Language code:

ElectricCurrentDensityValue[x == 0, {V[x, y], {x, y}}, <|"ElectricalConductivity" -> σ, "Thickness" -> d|>, <|"Current" -> I0|>]

创建参数频率电流密度边界条件：

Wolfram Language code: ElectricCurrentDensityValue[x == 0, {V[x, y, z], ω, {x, y, z}}, <|"Current" -> (4I0 Subscript[ω, 0]/ π ω)|>]

应用 (2)

三维稳态分析 (1)

建立一个铜螺旋电感器模型，该电感器在左边界以法线电流密度激励，右边界的电动势边界条件为零.

定义螺旋电感器的几何属性：

Wolfram Language code:

Ω = RegionUnion[Cuboid[{0, 0, 0}, {2, 1, 1}], Cuboid[{1, 1, 0}, {2, 8, 1}], Cuboid[{2, 7, 0}, {8, 8, 1}], Cuboid[{7, 7, 0}, {8, 0, 1}], Cuboid[{7, 0, 0}, {3, 1, 1}], Cuboid[{3, 1, 0}, {4, 6, 1}], Cuboid[{4, 6, 0}, {6, 5, 1}], Cuboid[{6, 5, 0}, {5, 2, 1}], Cuboid[{5, 2, 1}, {6, 3, 1.2}], Cuboid[{5, 2, 1.2}, {10, 3, 2.2}]]

设置稳态电流偏微分方程模型变量和：

Wolfram Language code:

vars = {V[x, y, z], {x, y, z}};
pars = <|"Material" -> Entity["Element", "Copper"]|>;

指定左端边界处的向内电流：

Wolfram Language code: Subscript[Γ, source] = ElectricCurrentDensityValue[x == 0, vars, pars, <|"NormalCurrentDensity" -> 10|>];

指定接地电位：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[x == 10, vars, pars];

求解偏微分方程：

Wolfram Language code:

Vfun = NDSolveValue[{ElectricCurrentPDEComponent[vars, pars] == Subscript[Γ, source], Subscript[Γ, ground]}, V, {x, y, z}∈Ω]

计算电流密度矢量：

Wolfram Language code: Jfield = -QuantityMagnitude[pars["Material"]["ElectricalConductivity"]] * Grad[Vfun[x, y, z], {x, y, z}];

可视化电势：

Wolfram Language code:

SliceDensityPlot3D[Sqrt[Total[Jfield ^ 2]], {{"XStackedPlanes", 10}, {"YStackedPlanes", 10}, {"ZStackedPlanes", 5}}, {x, y, z}∈Ω, ...]

频率分析 (1)

对圆柱形电容器的介电材料进行建模，该电容器受到 [] 的交流电 (AC ) 激励，其中在上边界设置了电流密度边界条件，该边界代表其中一个电容器电极，并且在下边界设置了零电势边界条件.

设置频率电流偏微分方程模型变量：

Wolfram Language code: vars = {V[x, y, z], ω, {x, y, z}};

定义频率和周期：

Wolfram Language code:

f0 = 60;
T0 = 1 / f0;

设置区域：

Wolfram Language code:

r0 = 0.01;
h = 0.001;
Ω = Cylinder[{{0, 0, 0}, {0, 0, h}}, r0];

指定电导率和相对介电常数：

Wolfram Language code: pars = <|"ElectricalConductivity" -> 1*^-8, "RelativePermittivity" -> 2|>;

指定下边界处的接地电位：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0, vars, pars];

指定上边界处的内向电流：

Wolfram Language code: Subscript[Γ, current] = ElectricCurrentDensityValue[z == h, vars, pars, <|"Current" -> 1*^-7|>];

设置方程：

Wolfram Language code: op = ElectricCurrentPDEComponent[vars, pars];

求解 [] 的谐波偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{(op /. {ω -> 2 Pi f0}) == Subscript[Γ, current], Subscript[Γ, ground]}, V, {x, y, z}∈Ω]

将上边界电压变换到时域：

Wolfram Language code: Vlist = Table[{t, Re[Vfun[0, 0, h] * Exp[I ω t] /. {ω -> 2 Pi f0}]}, {t, 0, 3 * T0, T0 / 100}];

可视化电容器上极板的电压：

Wolfram Language code: ListLinePlot[Vlist]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ElectricCurrentDensityValue

更多信息

范例

基本范例 (3)

范围 (6)

应用 (2)

三维稳态分析 (1)

频率分析 (1)

文本

CMS

APA

BibTeX

BibLaTeX

	分析类型	是否适用
	频率响应	是
	静态	是

ElectricCurrentDensityValue

更多信息

范例

基本范例 (3)

范围 (6)

应用 (2)

三维稳态分析 (1)

频率分析 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX