ElectrostaticPDEComponent

ElectrostaticPDEComponent[vars,pars]

静電気PDE項を，変数 vars，パラメータ pars で与える．

詳細

ElectrostaticPDEComponentは，通常，モデル変数 vars，モデルパラメータ pars で静電方程式を生成するために使用される．
ElectrostaticPDEComponentは，PDEの一部として使う微分演算子の和を返す．

ElectrostaticPDEComponentは，絶縁体または誘電体の材料内の静電荷によって生じる静電気場をモデル化する．

ElectrostaticPDEComponentは，静電気現象を，スカラー電位の従属変数でモデル化する．の単位はボルト[]，独立変数の単位は[]である．
定常変数 vars は vars={V[x₁,…,x_n],{x₁,…,x_n}}である．
ElectrostaticPDEComponentは，一般に，時間依存編微分方程式は生成しない．
ElectrostaticPDEComponentは，拡散，ソース，PDEの導関数の各項に基づいている．

は真空誘電率（単位：[]），破分局ベクトル（単位：[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ] ），は体積電荷密度（単位：[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]）である．
分極ベクトルは，材料内の永久または誘起電気双極子モーメントの密度を指定する．
体積電荷密度は，正または負の電荷分布をモデル化する．
ElectrostaticPDEComponentは，構成関係によって異なる方程式を生成する．
ElectrostaticPDEComponentは，線形の材料については以下のように簡約される．

は単位のない比誘電率である．
は，等方性，直交異方性，異方性のいずれでもよい．
一般的な非線形で非ヒステリシスの強誘電体材料の場合，ElectrostaticPDEComponent方程式は以下として与えられる．

は残留分極ベクトル（単位：[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]）である．
静電気モデルについての陰的なデフォルトの境界条件は0 ElectricFluxDensityValueである．
静電気モデル項の単位は[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]あるいは同等の[ $TemplateBox[{InterpretationBox[, 1], {"s", , "A", , "/", , {"m", ^, 3}}, second amperes per meter cubed, {{(, {"Amperes", , "Seconds"}, )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]である．
次は，使用可能なパラメータ pars である．

パラメータ	デフォルト	シンボル
"Polarization"	{0,…}	，分極ベクトル（単位：[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]）
"RegionSymmetry"	None
"RelativePermittivity"	1	，無単位の比誘電率
"RemanentPolarization"	{0,…}	，残留分極ベクトル（単位：[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]）
"Thickness"	1	，厚み（単位：[]）
"CrossSectionalArea"	1	，断面積（単位：[ $TemplateBox[{InterpretationBox[, 1], {{"m", ^, 2}}, meters squared, {"Meters", ^, 2}}, QuantityTF]$ ]）
"VacuumPermittivity"		，真空誘電率（単位：[]）
"VolumeChargeDensity"	0	，体積電荷密度（単位：[ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]）

パラメータはどれも，空間変数と従属変数に依存することがある．
独立変数の数はまたはの次元とベクトルおよびの長さを決定する．
パラメータ"RegionSymmetry"の可能な選択肢には"Axisymmetric"がある．
"Axisymmetric"領域対称性は，以下のように角度変数を削除することによって円筒座標が縮小される，切り取られた円筒座標系を表す．
次元削減方程式

1D

2D
2Dの場合，"Thickness" が指定されているとElectrostaticPDEComponent方程式は以下のように与えられる．

1Dの場合，"CrossSectionalArea" が指定されているとElectrostaticPDEComponent方程式は以下のように与えられる．

1D軸対称の場合，"Thickness" が指定されると，ElectrostaticPDEComponent方程式は以下のように与えられる．

パラメータの入力指定は対応する演算子項のそれと厳密に等しい．
パラメータが指定されていない場合，デフォルトの静電気PDEは以下のようになる．

ElectrostaticPDEComponentが連想 pars で…,keyp_i…,p_iv_i,…として指定されたパラメータに依存するとき，パラメータはで置換される．

例題

すべて開くすべて閉じる

例 (3)

静電気モデルを定義する：

Wolfram Language code: ElectrostaticPDEComponent[{V[x], {x}}, <||>]

特定の材料パラメータで静電気モデルを設定する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> Subscript[ϵ, 𝓇], "VolumeChargeDensity" -> Subscript[ρ, v]|>]

モデル変数と静電気パラメータを指定する：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

静電気PDEを設定して解く：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]}}, V, {x, 0, 0.08}]

解を可視化する：

Wolfram Language code: Plot[Vfun[x], {x, 0, 0.08}]

スコープ (14)

1D (4)

断面積がの1D静電気モデルを定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x], {x}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[1], "CrossSectionalArea" -> A, "VolumeChargeDensity" -> Subscript[ρ, s]|>]

側面の2つの電位条件で電位場をモデル化する．

モデルの変数と静電パラメータを指定する：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> 2|>;

線電気PDEを設定して解く：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

解を可視化する：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

側面における2つの電位条件と不連続比誘電率で電位場をモデル化する．

モデル変数と静電パラメータを指定する：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> Piecewise[{{2, x <= 1 / 10}}, 1]|>;

静電気PDEを設定して解く：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

解を可視化する：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

2D (5)

2D静電モデルを分極ベクトルで定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0] * IdentityMatrix[2], "Polarization" -> {Px[x, y], Py[x, y]}|>]

2D非線形静電モデルを残留分極ベクトルで定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "RemanentPolarization" -> {Prx[x, y], Pry[x, y]}|>]

2D静電モデルを厚みで定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "Thickness" -> d|>]

直交異方性比誘電率を定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], 0}, {0, Subscript[ϵ, r12]}}|>]

完全に異方性の比誘電率を定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], Subscript[ϵ, r12]}, {Subscript[ϵ, r21], Subscript[ϵ, r12]}}|>]

2D軸対称 (2)

2D軸対称静電気モデルを定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[r, z], {r, z}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "RegionSymmetry" -> "Axisymmetric"|>]

2D軸対称直交静電モデルを定義する：

Wolfram Language code:

ElectrostaticPDEComponent[{V[r, z], {r, z}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, 𝓇𝓇], 0}, {0, Subscript[ϵ, zz]}}, "RegionSymmetry" -> "Axisymmetric"|>]

3D (1)

内半径と外半径の電位条件を使用して中空ボール内の電位場をモデル化する．

モデル変数と静電パラメータを指定する：

Wolfram Language code:

vars = {V[x, y, z], {x, y, z}};
pars = <|"RelativePermittivity" -> 3.9|>;

静電気PDEを設定して解く：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x ^ 2 + y ^ 2 + z ^ 2 <= (3 / 1000) ^ 2, vars, pars, <|"ElectricPotential" -> 32|>], ElectricPotentialCondition[x ^ 2 + y ^ 2 + z ^ 2 >= (9 / 1000) ^ 2, vars, pars, <|"ElectricPotential" -> 0|> ]}}, V, {x, y, z} ∈ RegionDifference[Ball[{0, 0, 0}, 10 / 1000], Ball[{0, 0, 0}, 3 / 1000]]];

解を可視化する：

Wolfram Language code:

SliceContourPlot3D[Vfun[x, y, z], "CenterPlanes", {x, -10 / 1000, 10 / 1000}, {y, -10 / 1000, 10 / 1000}, {z, -10 / 1000, 10 / 1000}, ColorFunction -> "Rainbow"]

マルチマテリアル (2)

複数の材料領域について静電気モデルを設定する：

Wolfram Language code: ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> Piecewise[{{7, y <= 1}, {2, y > 1}}]|>]

側面の2つの電位条件と不連続な比誘電率を持つ電位場をモデル化する．

モデル変数と静電パラメータを指定する：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> Piecewise[{{2, x <= 1 / 10}}, 1]|>;

静電気PDEを設定して解く：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

解を可視化する：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

アプリケーション (4)

1D (2)

距離 []で隔てられた軸に垂直の2枚の平行プレート間の電位分布を計算する．左側のパネルは定電位 []に保たれているのに対し，右側のプレートは接地していて []である．プレート間の領域は比誘電率と均一な電子電荷密度 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]で特徴付られる．モデルの方程式は以下で与えられる：

静電気モデル変数を設定する：

Wolfram Language code: vars = {V[x], {x}};

領域を設定する：

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

静電気モデルパラメータを指定する：

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

電位条件を指定する：

Wolfram Language code:

Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]};

方程式を設定する：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

PDEを解く：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

解を可視化する：

Wolfram Language code: Plot[Vfun[x], x∈Ω]

前の例と同じ距離と境界条件を使用して2つの平行平板間の電位分布を計算するが，で与えられる不均一な電荷分布を使用する：

静電気モデル変数を設定する：

Wolfram Language code: vars = {V[x], {x}};

領域を設定する：

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

静電気モデルパラメータを指定する：

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8 * (1 - (x/0.08))^2|>;

電位条件を指定する：

Wolfram Language code:

Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]};

方程式を設定する：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

PDEを解く：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

解を可視化する：

Wolfram Language code: Plot[Vfun[x], x∈Ω]

2D (1)

金属壁を持つ無限に長い長方形のボックスをモデル化する．ボックスの幅は []で高さは []である．縦方向の壁と底の壁の電位は0に保たれているのに対し，上の壁のの固定電位を持つ．ボックス内の領域には電荷はない．モデルの方程式は以下で与えられる：

モデル変数とパラメータを定義する：

Wolfram Language code:

vars = {V[x, y], {x, y}};
pars = <|"RelativePermittivity" -> 1|>;

モデル領域を設定する：

Wolfram Language code:

w = 1;
h  = 2;
Ω = Rectangle[{0, 0}, {w, h}];

2D静電気モデルを設定する：

Wolfram Language code: op = ElectrostaticPDEComponent[vars, pars];

における底の壁と側面の壁の一部の電位は0に保たれている：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[y <= 1, vars, pars];

における上の壁の電位は []に固定されている：

Wolfram Language code:

V0 = 1;
Subscript[Γ, potential] = ElectricPotentialCondition[y == h, vars, pars, <|"ElectricPotential" -> V0|>];

方程式を設定する：

Wolfram Language code: eqn = {op == 0, Subscript[Γ, ground], Subscript[Γ, potential]};

PDEを解く：

Wolfram Language code: Vfun = NDSolveValue[eqn, V, {x, y}∈Ω];

解を可視化する：

Wolfram Language code: Legended[ContourPlot[Vfun[x, y], {x, y}∈Ω, ...], BarLegend[...]]

3D (1)

コンデンサの電極を表す上部と下部の境界に2つの電位条件を備えた円筒コンデンサの誘電体材料をモデル化する．モデルの方程式は以下で与えられる：

静電気モデル変数を設定する：

Wolfram Language code: vars = {V[x, y, z], {x, y, z}};

領域を設定する：

Wolfram Language code:

r0 = 0.01;
h = 0.001;
Ω = Cylinder[{{0, 0, 0}, {0, 0, h}}, r0];

比誘電率を指定する：

Wolfram Language code: pars = <|"RelativePermittivity" -> 2|>;

より低い境界における地電位を指定する：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0, vars, pars];

上界における電位 []を指定する：

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[z == h, vars, pars, <|"ElectricPotential" -> 1|>];

方程式を設定する：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

PDEを解く：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y, z}∈Ω]

解を可視化する：

Wolfram Language code: SliceDensityPlot3D[Vfun[x, y, z], "CenterPlanes", {x, y, z}∈Ω, ...]

考えられる問題 (1)

記号計算では，"VacuumPermittivity"または"RelativePermittivity"のパラメータは行列として与えられなければならない：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], 0}, {0, Subscript[ϵ, r12]}}|>]//Activate

数値計算では，"VacuumPermittivity"または"RelativePermittivity"のパタメータは自動的に適切な次元の行列に変換される：

Wolfram Language code: ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> 1|>]

この自動変換は記号入力では行われない：

Wolfram Language code: ElectrostaticPDEComponent[{V[x], {x}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0]|>]

適切な次元の行列を与えないと結果はエラーになる：

Wolfram Language code: %//Activate

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ElectrostaticPDEComponent

詳細

例題

例 (3)

スコープ (14)

1D (4)

2D (5)

2D軸対称 (2)

3D (1)

マルチマテリアル (2)

アプリケーション (4)

1D (2)

2D (1)

3D (1)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

次元	削減	方程式
1D
2D

ElectrostaticPDEComponent

詳細

例題

例 (3)

スコープ (14)

1D (4)

2D (5)

2D軸対称 (2)

3D (1)

マルチマテリアル (2)

アプリケーション (4)

1D (2)

2D (1)

3D (1)

考えられる問題 (1)

関連項目

テクニカルノート

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX