Wolfram 语言与系统参考资料中心

ElectrostaticPDEComponent

ElectrostaticPDEComponent[vars,pars]

生成带有变量 vars 和参数 pars 的静电偏微分方程项.

更多信息

ElectrostaticPDEComponent 通常用于生成带有模型变量 vars 和模型参数 pars 的静电方程.
ElectrostaticPDEComponent 返回用作偏微分方程一部分的微分算子之和：

ElectrostaticPDEComponent 模拟绝缘或介电材料中的静电荷产生的静电场.

ElectrostaticPDEComponent 使用因变量（电标量电势）对静电现象进行建模. 的单位为伏特 []，自变量为，单位为 [].
静态变量 vars 为 vars={V[x₁,…,x_n],{x₁,…,x_n}}.
ElectrostaticPDEComponent 一般不会产生时间相关的偏微分方程.
ElectrostaticPDEComponent 基于扩散、源和导数的偏微分方程项：

是真空介电常数，单位为 []，是极化矢量，单位是 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]，是体积电荷密度，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ].
极化矢量指定材料内部永久或感应电偶极矩的密度.
体积电荷密度对电荷分布（负或正）进行建模.
ElectrostaticPDEComponent 根据本构关系的不同，可以产生不同的方程.
对于线性材料，ElectrostaticPDEComponent 方程简化为：

是无单位相对介电常数.
可以是各向同性、正交各向异性或各向异性的.
对于非线性非磁滞铁电材料，ElectrostaticPDEComponent 方程如下：

是残余极化矢量，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ].
静电模型的隐式默认边界条件是 0 ElectricFluxDensityValue.
静电模型项的单位为 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]，或等效为 [ $TemplateBox[{InterpretationBox[, 1], {"s", , "A", , "/", , {"m", ^, 3}}, second amperes per meter cubed, {{(, {"Amperes", , "Seconds"}, )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ].
可以给出以下参数 pars：

参数	默认值	符号
"Polarization"	{0,…}	，极化向量，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
"RegionSymmetry"	None
"RelativePermittivity"	1	，无单位相对介电常数
"RemanentPolarization"	{0,…}	，残余极化矢量，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 2}}, coulombs per meter squared, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 2}, )}}}, QuantityTF]$ ]
"Thickness"	1	，厚度，单位为
"CrossSectionalArea"	1	，横截面积，单位为 [ $TemplateBox[{InterpretationBox[, 1], {{"m", ^, 2}}, meters squared, {"Meters", ^, 2}}, QuantityTF]$ ]
"VacuumPermittivity"		，真空介电常数，单位为 []
"VolumeChargeDensity"	0	，体积电荷密度，单位为 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]

所有参数可能取决于空间变量和因变量 .
自变量的数量决定了或的维度以及向量和的长度.
参数 "RegionSymmetry" 的可能选择是 "Axisymmetric".
"Axisymmetric" 区域的对称性表示一个截断的柱坐标系，在这个柱坐标系中，柱坐标通过去除角度变量而简化，如下所示：
维度简化方程

一维

二维
在二维中，当指定 "Thickness" 时，ElectrostaticPDEComponent 方程如下：

在一维中，当指定 "CrossSectionalArea" 时，ElectrostaticPDEComponent 方程如下：

在一维轴对称模型中，当指定 "Thickness" 时，ElectrostaticPDEComponent 方程为：

参数的输入规范与其相应的运算符项完全相同.
如果未指定任何参数，则默认静电偏微分方程为：

如果 ElectrostaticPDEComponent 取决于在关联 pars 中指定为 …,keyp_i…,p_iv_i,… 的参数，则参数将替换为 .

范例

打开所有单元关闭所有单元

基本范例 (3)

定义静电模型：

Wolfram Language code: ElectrostaticPDEComponent[{V[x], {x}}, <||>]

设置具有特定材料参数的静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> Subscript[ϵ, 𝓇], "VolumeChargeDensity" -> Subscript[ρ, v]|>]

指定模型变量和静电参数：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

设置并求解静电偏微分方程：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]}}, V, {x, 0, 0.08}]

可视化解：

Wolfram Language code: Plot[Vfun[x], {x, 0, 0.08}]

范围 (14)

一维 (4)

定义横截面积为的一维静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x], {x}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[1], "CrossSectionalArea" -> A, "VolumeChargeDensity" -> Subscript[ρ, s]|>]

对两侧具有两个电势条件的电势场进行建模.

指定模型变量和静电参数：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> 2|>;

设置并求解静电偏微分方程：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

可视化解：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

对两侧具有两个电势条件和不连续相对介电常数的电势场进行建模.

指定模型变量和静电参数：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> Piecewise[{{2, x <= 1 / 10}}, 1]|>;

设置并求解静电偏微分方程：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

可视化解：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

二维 (5)

定义具有极化矢量的二维静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0] * IdentityMatrix[2], "Polarization" -> {Px[x, y], Py[x, y]}|>]

定义一个带有残余极化矢量的二维非线性静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "RemanentPolarization" -> {Prx[x, y], Pry[x, y]}|>]

定义一个具有厚度的二维静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "Thickness" -> d|>]

定义一个正交各向异性的相对介电常数：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], 0}, {0, Subscript[ϵ, r12]}}|>]

定义一个完全各向异性的相对介电常数：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], Subscript[ϵ, r12]}, {Subscript[ϵ, r21], Subscript[ϵ, r12]}}|>]

二维轴对称 (2)

定义二维轴对称静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[r, z], {r, z}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> Subscript[ϵ, 𝓇] * IdentityMatrix[2], "RegionSymmetry" -> "Axisymmetric"|>]

定义二维轴对称正交各向异性静电模型：

Wolfram Language code:

ElectrostaticPDEComponent[{V[r, z], {r, z}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, 𝓇𝓇], 0}, {0, Subscript[ϵ, zz]}}, "RegionSymmetry" -> "Axisymmetric"|>]

三维 (1)

对中空球体中的电势场进行建模，在内半径和外半径处设置电势条件：

指定模型变量和静电参数：

Wolfram Language code:

vars = {V[x, y, z], {x, y, z}};
pars = <|"RelativePermittivity" -> 3.9|>;

设置并求解静电偏微分方程：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x ^ 2 + y ^ 2 + z ^ 2 <= (3 / 1000) ^ 2, vars, pars, <|"ElectricPotential" -> 32|>], ElectricPotentialCondition[x ^ 2 + y ^ 2 + z ^ 2 >= (9 / 1000) ^ 2, vars, pars, <|"ElectricPotential" -> 0|> ]}}, V, {x, y, z} ∈ RegionDifference[Ball[{0, 0, 0}, 10 / 1000], Ball[{0, 0, 0}, 3 / 1000]]];

可视化解：

Wolfram Language code:

SliceContourPlot3D[Vfun[x, y, z], "CenterPlanes", {x, -10 / 1000, 10 / 1000}, {y, -10 / 1000, 10 / 1000}, {z, -10 / 1000, 10 / 1000}, ColorFunction -> "Rainbow"]

多材料 (2)

为多个材料区域建立一个静电模型：

Wolfram Language code: ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> Piecewise[{{7, y <= 1}, {2, y > 1}}]|>]

建立一个电势场模型，其中在两侧设置两个电势条件，并具有不连续的相对介电常数.

指定模型变量和静电参数：

Wolfram Language code:

vars = {V[x], {x}};
pars = <|"RelativePermittivity" -> Piecewise[{{2, x <= 1 / 10}}, 1]|>;

设置并求解静电偏微分方程：

Wolfram Language code:

Vfun = NDSolveValue[{ElectrostaticPDEComponent[vars, pars] == 0, {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 10|>], ElectricPotentialCondition[x == 1 / 5, vars, pars, <|"ElectricPotential" -> 0|>]}}, V, x∈Line[{{0}, {1 / 5}}]];

可视化解：

Wolfram Language code: Plot[Vfun[x], {x, 0, 1 / 5}, AxesLabel -> {"x", "V"}]

应用 (4)

一维 (2)

计算两个平行板之间的电势分布，这两个平行板之间的距离为 []，并且垂直于轴放置. 左边的平板维持在一个恒定的电势 []，而右边的平板接地， []. 两板之间的区域具有相对介电常数和均匀电荷密度 [ $TemplateBox[{InterpretationBox[, 1], {"C", , "/", , {"m", ^, 3}}, coulombs per meter cubed, {{(, "Coulombs", )}, /, {(, {"Meters", ^, 3}, )}}}, QuantityTF]$ ]. 用于建模的方程如下：

设置静电模型变量：

Wolfram Language code: vars = {V[x], {x}};

设置区域：

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

指定静电模型参数：

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8|>;

指定电势条件：

Wolfram Language code:

Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]};

建立方程：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

可视化解：

Wolfram Language code: Plot[Vfun[x], x∈Ω]

计算两个平行板之间的电势分布，其距离和边界条件与上一个示例相同，但现在电荷分布不均匀，如下所示：

设置静电模型的变量：

Wolfram Language code: vars = {V[x], {x}};

设置区域：

Wolfram Language code: Ω = Line[{{0}, {0.08}}];

指定静电模型的参数：

Wolfram Language code: pars = <|"RelativePermittivity" -> 1, "VolumeChargeDensity" -> -10*^-8 * (1 - (x/0.08))^2|>;

指定电势条件：

Wolfram Language code:

Subscript[Γ, v] = {ElectricPotentialCondition[x == 0, vars, pars, <|"ElectricPotential" -> 1|>], ElectricPotentialCondition[x == 0.08, vars, pars]};

建立方程：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, v]}, V, x∈Ω]

可视化解：

Wolfram Language code: Plot[Vfun[x], x∈Ω]

二维 (1)

建立一个具有金属墙壁的无限长矩形箱子模型. 该箱子的宽度为 []，高度为 []. 箱子的侧面和底部墙壁维持在零电势，而顶部墙壁的电势固定为 . 箱子内部的区域没有电荷 . 用于建模的方程如下：

定义模型的变量和参数：

Wolfram Language code:

vars = {V[x, y], {x, y}};
pars = <|"RelativePermittivity" -> 1|>;

设置模型区域：

Wolfram Language code:

w = 1;
h  = 2;
Ω = Rectangle[{0, 0}, {w, h}];

建立一个二维静电模型：

Wolfram Language code: op = ElectrostaticPDEComponent[vars, pars];

在、和处，侧面和底部墙壁维持零电势：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[y == 0 || x == w || x == 0, vars, pars];

在处，顶部墙壁的电势固定为 []：

Wolfram Language code:

V0 = 1;
Subscript[Γ, potential] = ElectricPotentialCondition[y == h, vars, pars, <|"ElectricPotential" -> V0|>];

建立方程：

Wolfram Language code: eqn = {op == 0, Subscript[Γ, ground], Subscript[Γ, potential]};

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[eqn, V, {x, y}∈Ω];

可视化解：

Wolfram Language code: Legended[ContourPlot[Vfun[x, y], {x, y}∈Ω, ...], BarLegend[...]]

三维 (1)

对圆柱电容器的介电材料建模，其中上下边界有两个电势条件，它们代表电容器的电极. 用于建模的方程如下.

设置静电模型的变量：

Wolfram Language code: vars = {V[x, y, z], {x, y, z}};

设置区域：

Wolfram Language code:

r0 = 0.01;
h = 0.001;
Ω = Cylinder[{{0, 0, 0}, {0, 0, h}}, r0];

指定相对介电常数：

Wolfram Language code: pars = <|"RelativePermittivity" -> 2|>;

指定下边界处的接地电位：

Wolfram Language code: Subscript[Γ, ground] = ElectricPotentialCondition[z == 0, vars, pars];

指定上边界处的电势为 []：

Wolfram Language code: Subscript[Γ, potential] = ElectricPotentialCondition[z == h, vars, pars, <|"ElectricPotential" -> 1|>];

建立方程：

Wolfram Language code: eqn = ElectrostaticPDEComponent[vars, pars] == 0

求解偏微分方程：

Wolfram Language code: Vfun = NDSolveValue[{eqn, Subscript[Γ, ground], Subscript[Γ, potential]}, V, {x, y, z}∈Ω]

可视化解：

Wolfram Language code: SliceDensityPlot3D[Vfun[x, y, z], "CenterPlanes", {x, y, z}∈Ω, ...]

可能存在的问题 (1)

对于符号计算，"VacuumPermittivity" 或 "RelativePermittivity" 参数应该以矩阵形式给出：

Wolfram Language code:

ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0], "RelativePermittivity" -> {{Subscript[ϵ, r11], 0}, {0, Subscript[ϵ, r12]}}|>]//Activate

对于数值，"VacuumPermittivity" 或 "RelativePermittivity" 参数会自动转换为适当维度的矩阵：

Wolfram Language code: ElectrostaticPDEComponent[{V[x, y], {x, y}}, <|"RelativePermittivity" -> 1|>]

对于符号输入来说，这种自动转换是不可能的：

Wolfram Language code: ElectrostaticPDEComponent[{V[x], {x}}, <|"VacuumPermittivity" -> Subscript[ϵ, 0]|>]

未提供正确维度的矩阵将导致错误：

Wolfram Language code: %//Activate

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

ElectrostaticPDEComponent

更多信息

范例

基本范例 (3)

范围 (14)

一维 (4)

二维 (5)

二维轴对称 (2)

三维 (1)

多材料 (2)

应用 (4)

一维 (2)

二维 (1)

三维 (1)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

维度	简化	方程
一维
二维

ElectrostaticPDEComponent

更多信息

范例

基本范例 (3)

范围 (14)

一维 (4)

二维 (5)

二维轴对称 (2)

三维 (1)

多材料 (2)

应用 (4)

一维 (2)

二维 (1)

三维 (1)

可能存在的问题 (1)

参见

技术笔记

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX