WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Elementwise[f][{x1,…,xn},{y1,…,yn}]

{f[x1,y1],…,f[xn,yn]}を与える．

Elementwise[f][arg1,…]

arg1,…内の任意のリストに縫い込む．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

Elementwise

Elementwise[f][{x1,…,xn},{y1,…,yn}]

{f[x1,y1],…,f[xn,yn]}を与える．

Elementwise[f][arg1,…]

arg1,…内の任意のリストに縫い込む．

詳細

  • Elementwiseは，通常，リスト化不可能な関数をリスト化可能なものとして動作させるために使われる．

例題

すべて開く すべて閉じる

例  (4)

負の数を0で置換する：

Wolfram Language code: Elementwise[Max][{1, -1, 3, -4, 5}, 0]

リスト中の1未満の要素を求める：

Wolfram Language code: Elementwise[Less][{1, 0, 2, -1}, 1]

演算子形を使う：

Wolfram Language code: Elementwise[LessThan[1]][{1, 0, 2, -1}]

最大の平方を持つ行列要素を選択する：

Wolfram Language code: Elementwise[If[#1^2 >= #2^2, #1, #2]&][(⁠| | | | | -- | -- | -- | | -9 | -5 | -7 | | -2 | -4 | 1 | | -3 | -8 | -4 |⁠), (⁠| | | | | -- | -- | -- | | -1 | 2 | -5 | | 5 | -2 | -3 | | 4 | 6 | 3 |⁠)]

文字列の各リストに山カッコを加える：

Wolfram Language code: Elementwise[StringJoin]["<", RandomWord[5], ">"]

スコープ  (5)

Greaterは，デフォルトではリストに縫い込まれない：

Wolfram Language code: Greater[{1, -1, 3, -4, 5}, 0]

Elementwise[Greater]を使ってリスト化可能な関数として動作するようにする：

Wolfram Language code: Elementwise[Greater][{1, -1, 3, -4, 5}, 0]

Minは引数の最小値を返す：

Wolfram Language code: Min[2, {-4, 2}, {{8, 5}, {-1, 6}}]

Elementwise[Min]を使って可能な最深レベルまで引数を縫い込む：

Wolfram Language code: Elementwise[Min][2, {-4, 1}, {{8, 5}, {0, 6}}]

これは，事実上，縫込み操作である：

Wolfram Language code: Block[{min}, SetAttributes[min, Listable]; min[2, {-4, 1}, {{8, 5}, {0, 6}}] ]

日付のTabularColumnオブジェクトを取る：

Wolfram Language code: TabularColumn[RandomDate[10 ^ 5]]

月と日付についてそれぞれの列を効率的に抽出する：

Wolfram Language code: RepeatedTiming[mds = Elementwise[DateValue[#, {"Month", "Day"}]&][%]]

これら2列のTabularオブジェクトを構築する：

Wolfram Language code: ToTabular[{"month" -> mds[[All, 1]], "day" -> mds[[All, 2]]}, "Columns"]

3数のリストからなる2列のTabularオブジェクトを取得する：

Wolfram Language code: tab = Tabular[{{{1, 2, 3}, 2}, {{2, -1, 4}, 1}}, {"vector", "scalar"}]
Wolfram Language code: TransformColumns[tab, "comp" -> Function[Elementwise[Greater][#vector, #scalar]]]

ElementwiseはThreadedに使える：

Wolfram Language code: Elementwise[f][{{1, 2, 3}, {4, 5, 6}}, {a, b}]
Wolfram Language code: Elementwise[f][{{1, 2, 3}, {4, 5, 6}}, Threaded[{α, β, γ}]]

アプリケーション  (2)

姓と名を組み合せてフルネームを取得する：

Wolfram Language code: firstNames = TabularColumn[{"Pierce", "Sean", "Daniel", "Timothy", "George", "Roger", "David"}]; lastNames = TabularColumn[{"Brosnan", "Connery", "Craig", "Dalton", "Lazenby", "Moore", "Niven"}];
Wolfram Language code: Elementwise[StringJoin][firstNames, " ", lastNames]
Wolfram Language code: Normal[%]

ヘミングウェイの主要作品の中で彼の生前に出版されたものの冊数を求める：

Wolfram Language code: dates = EntityValue[Entity["Person", "ErnestHemingway::8gktg"][EntityProperty["Person", "NotableBooks"]], EntityProperty["Book", "FirstPublished"]]
Wolfram Language code: Elementwise[LessEqualThan[Entity["Person", "ErnestHemingway::8gktg"]["DeathDate"]]][dates]//Counts

特性と関係  (6)

ElementwiseはListable関数のように縫い込まれる：

Wolfram Language code: Elementwise[f][1, {2, 3}, {{4, 5, 6}, {7, 8, 9}}]
Wolfram Language code: Block[{f}, SetAttributes[f, Listable]; f[1, {2, 3}, {{4, 5, 6}, {7, 8, 9}}] ]
Wolfram Language code: %% === %

Elementwise[f][]は f[]を返す：

Wolfram Language code: Elementwise[f][]

Elementwise[f][{}]は{}を返す：

Wolfram Language code: Elementwise[f][{}]

Elementwise[f][list1,list2,…]は，同じ長さのいくつかのリストについてはElementwise[f][list1,list2,…]に等しい：

Wolfram Language code: Elementwise[f][{a, b}, {1, 2}, {x, y}]
Wolfram Language code: MapThread[f][{{a, b}, {1, 2}, {x, y}}]

リストの中にサブリストを含むものがあれば，Elementwiseは可能な限り縫い込まれる：

Wolfram Language code: Elementwise[f][{{a}, {b}}, {1, 2}, {x, y}]
Wolfram Language code: MapThread[f][{{{a}, {b}}, {1, 2}, {x, y}}]

また別の相違は，Elementwiseがスカラーにも縫い込まれる点である：

Wolfram Language code: Elementwise[f][{a, b}, 0, {x, y}]

f[list,scalar]が評価されないのなら，Elementwise[f][list,scalar]はThread[f[list,scalar]]に等しい：

Wolfram Language code: Elementwise[f][{a, b, c}, x]
Wolfram Language code: Thread[f[{a, b, c}, x]]

Elementwiseの機能の中にはMapで達成できるものもある：

Wolfram Language code: Elementwise[Max][{1, -1, 3, -4, 5}, 0]
Wolfram Language code: Map[Max[#, 0]&, {1, -1, 3, -4, 5}]

あるいはThreadで：

Wolfram Language code: Elementwise[LessThan[1]][{1, 0, 2, -1}]
Wolfram Language code: Thread[LessThan[1][{1, 0, 2, -1}]]

あるいはMapとThreadの組合せで：

Wolfram Language code: Elementwise[f][{{1, 2, 3}, {4, 5, 6}}, {a, b}]
Wolfram Language code: MapThread[Thread[f[#1, #2]]&, {{{1, 2, 3}, {4, 5, 6}}, {a, b}}]

Elementwiseは，可能なすべてのレベルでAllを使用したMapAtに等しい：

Wolfram Language code: data = {{0.2, 0.8, .9}, {0.12, .74}, {.4}, {.32, .85}};
Wolfram Language code: Elementwise[f][data]
Wolfram Language code: MapAt[f, data, {All, All}]
Wolfram Research (2025), Elementwise, Wolfram言語関数， https://reference.wolfram.com/language/ref/Elementwise.html.

テキスト

Wolfram Research (2025), Elementwise, Wolfram言語関数， https://reference.wolfram.com/language/ref/Elementwise.html.

CMS

Wolfram Language. 2025. "Elementwise." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Elementwise.html.

APA

Wolfram Language. (2025). Elementwise. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Elementwise.html

BibTeX

@misc{reference.wolfram_2026_elementwise, author="Wolfram Research", title="{Elementwise}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/Elementwise.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_elementwise, organization={Wolfram Research}, title={Elementwise}, year={2025}, url={https://reference.wolfram.com/language/ref/Elementwise.html}, note=[Accessed: 05-September-2026]}