WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Ellipsoid[p,{r1,…}]

中心が p で半軸の長さが riの，軸に沿った楕円体を表す．

Ellipsoid[p,Σ]

中心が p で，重み行列がΣでの楕円体を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイリング  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

Ellipsoid

Ellipsoid[p,{r1,…}]

中心が p で半軸の長さが riの，軸に沿った楕円体を表す．

Ellipsoid[p,Σ]

中心が p で，重み行列がΣでの楕円体を表す．

詳細とオプション

  • Ellipsoidは，中心区間，楕円，および超楕円体としても知られている．
  • Ellipsoidは，幾何学的領域およびグラフィックスプリミティブとして使うことが可能である．
  • Ellipsoidは，軸に沿った，塗り潰された楕円体，あるいは一般的な楕円体を表す．
  • Ellipsoidでは，p はの任意の点，riは正の実数，Σ は任意の対称正定実行列である．
  • Ellipsoidは，GraphicsおよびGraphics3Dで使うことができる．
  • グラフィックスでは，点 p，piおよび半径 riは，ScaledおよびDynamicの式でよい．
  • グラフィックスの描画はFaceForm，Specularity，Opacity，色等の指示子の影響を受ける．

例題

すべて開く すべて閉じる

例  (2)

3Dにおける軸に沿った楕円体：

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {4, 3, 2}]]

2Dにおける：

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {3, 2}]]

測度と重心：

Wolfram Language code: RegionMeasure[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]
Wolfram Language code: RegionCentroid[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

スコープ  (20)

グラフィックス  (10)

指定  (4)

3Dにおける軸に沿った楕円体：

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {4, 3, 2}]]

2Dにおける：

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {3, 2}]]

3Dにおける一般的な楕円体：

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {{5, 2, 3}, {2, 3, 2}, {3, 2, 5}}]]

2Dにおける：

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {{5, 2}, {2, 5}}]]

スタイリング  (4)

さまざまな鏡面反射指数の球体：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], ℛ}], {n, {5, 20, 100}}]

赤く輝く黒い球体：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Graphics3D[{Glow[Red], Black, ℛ}]

Opacityは表面の不透明度を指定する：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Table[Graphics3D[{Opacity[o], ℛ}], {o, {0.3, 0.5, 0.9}}]

2Dのスタイリング：

Wolfram Language code: ℛ = Ellipsoid[{0, 0}, {3, 2}];
Wolfram Language code: Graphics[{EdgeForm[{Thick, Dashed, Blue}], Brown, ℛ}]

座標  (2)

プロット範囲との割合で座標を指定する：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[Scaled[{0.5, 0.75}], {3, 2}];
Wolfram Language code: Graphics[Subscript[ℛ, 1], PlotRange -> {{0, 8}, {0, 8}}, Frame -> True]

通常の座標からのスケールされたオフセットを指定する：

Wolfram Language code: Graphics[Ellipsoid[ Scaled[{0.5, 0.25}, {0, 0}], {4, 2}], Frame -> True]

領域  (10)

埋込み次元は球体が存在する空間の次元である：

Wolfram Language code: RegionEmbeddingDimension[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

幾何次元は図形の次元である：

Wolfram Language code: RegionDimension[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

帰属判定：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {5, 5, 5}]}

点の帰属条件を求める：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体積：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {RegionDistance[ℛ, {0, 0, 0}], RegionDistance[ℛ, {0, 2, 2}]}

楕円の最近点までの距離：

Wolfram Language code: Plot3D[RegionDistance[Ellipsoid[{0, 0}, {1, 2}], {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> {x^2 + (y^2/4) == 1}]

点からの符号付きの距離：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {SignedRegionDistance[ℛ, {0, 2, 2}], SignedRegionDistance[ℛ, {0, 1 / 2, 0}]}

楕円までの符号付きの距離：

Wolfram Language code: Plot3D[SignedRegionDistance[Ellipsoid[{0, 0}, {1, 2}], {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

領域内の最近点：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {RegionNearest[ℛ, {3., 3, 3}], RegionNearest[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

包み込んでいる球までの最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 4]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

楕円体は有界である：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: BoundedRegionQ[ℛ]

その範囲を求める：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

楕円体の領域で積分する：

Wolfram Language code: ℛ = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

楕円体の領域で最適化する：

Wolfram Language code: ℛ = Ellipsoid[{1, 2, 3}, {4, 5, 6}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]//RootReduce

楕円体の領域で方程式を解く：

Wolfram Language code: ℛ = Ellipsoid[{1, 2, 3}, {2, 3, 4}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

アプリケーション  (4)

回転楕円体は，2本の等しい軸を持つ楕円体である：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {a, a, c}]

その体積を計算する：

Wolfram Language code: Volume[ℛ]

密度が で与えられる楕円体領域の総質量：

Wolfram Language code: ℛ = Ellipsoid[{a, b, c}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> Subscript[r, 1] > 0 && Subscript[r, 2] > 0 && Subscript[r, 3] > 0 && (a | b | c)∈Reals]

Ellipsoid内のメタノールの質量を求める：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, Quantity[{4, 3, 2}, "Centimeters"]];

メタノールの密度：

Wolfram Language code: d = ChemicalData["Methanol", "Density"]

楕円体の体積：

Wolfram Language code: v = Volume[ℛ]

楕円体内のメタノールの質量：

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]

領域の境界ボックスに対しての，境界Ellipsoidを求める：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];
Wolfram Language code: bounds = RegionBounds[ℛ];

境界ボックスを計算する：

Wolfram Language code: boundingBox = Cuboid@@Transpose[bounds];

境界ボックスについての境界楕円体を計算する：

Wolfram Language code: r = (Sqrt[3]/2) EuclideanDistance@@@bounds;
Wolfram Language code: boundingEllipsoid = Ellipsoid[RegionCentroid[boundingBox], r];

境界立体のVolumeの違いを計算する：

Wolfram Language code: Volume[boundingEllipsoid] - Volume[boundingBox]

境界曲面を可視化する：

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox, boundingEllipsoid}], Boxed -> False]

特性と関係  (4)

Diskは，Ellipsoidの特殊なケースである：

Wolfram Language code: RegionMember[Disk[{0, 0}, {1, 2}], {x, y}]
Wolfram Language code: RegionMember[Ellipsoid[{0, 0}, {1, 2}], {x, y}]

Ballは，Ellipsoidの特殊なケースである：

Wolfram Language code: RegionMember[Ball[{0, 0, 0}, 1], {x, y, z}]
Wolfram Language code: RegionMember[Ellipsoid[{0, 0, 0}, {1, 1, 1}], {x, y, z}]

Ellipsoidは，Ballを一般化したものである：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 1, 1, 1}]; Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegionは，任意のEllipsoidを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(Subscript[t, 1] - Subscript[c, 1])^2 + (1/4) (Subscript[t, 2] - Subscript[c, 2])^2 + (1/9) (Subscript[t, 3] - Subscript[c, 3])^2 + (1/16) (Subscript[t, 4] - Subscript[c, 4])^2 ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3], Subscript[t, 4]}]; Subscript[ℛ, 2] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 2, 3, 4}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

おもしろい例題  (2)

ランダムな楕円体の集合：

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Ellipsoid[RandomReal[50, {3}], RandomReal[{1, 5}, 3]]}, {100}]]

軸の周りで楕円体を急速に動かす：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[ℛ, RotationTransform[c, {1, -2, 3}, {5, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 16}]}]
Wolfram Research (2014), Ellipsoid, Wolfram言語関数， https://reference.wolfram.com/language/ref/Ellipsoid.html.

テキスト

Wolfram Research (2014), Ellipsoid, Wolfram言語関数， https://reference.wolfram.com/language/ref/Ellipsoid.html.

CMS

Wolfram Language. 2014. "Ellipsoid." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Ellipsoid.html.

APA

Wolfram Language. (2014). Ellipsoid. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Ellipsoid.html

BibTeX

@misc{reference.wolfram_2026_ellipsoid, author="Wolfram Research", title="{Ellipsoid}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Ellipsoid.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipsoid, organization={Wolfram Research}, title={Ellipsoid}, year={2014}, url={https://reference.wolfram.com/language/ref/Ellipsoid.html}, note=[Accessed: 08-September-2026]}