WOLFRAM

Wolfram 语言与系统参考资料中心

Ellipsoid[p,{r1,…}]

表示以点 p 为中心、半轴长度为 ri 的轴对齐椭球.

Ellipsoid[p,Σ]

表示以点 p 为中心、权重矩阵为 Σ 的椭球.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
指定  
样式化  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Ellipsoid

Ellipsoid[p,{r1,…}]

表示以点 p 为中心、半轴长度为 ri 的轴对齐椭球.

Ellipsoid[p,Σ]

表示以点 p 为中心、权重矩阵为 Σ 的椭球.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (2)

在三维空间的轴对齐椭球：

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {4, 3, 2}]]

在二维空间：

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {3, 2}]]

测量和质心：

Wolfram Language code: RegionMeasure[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]
Wolfram Language code: RegionCentroid[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

范围  (20)

图形  (10)

指定  (4)

在三维空间的轴对齐椭球：

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {4, 3, 2}]]

在二维空间：

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {3, 2}]]

在三维空间的一般椭球：

Wolfram Language code: Graphics3D[Ellipsoid[{0, 0, 0}, {{5, 2, 3}, {2, 3, 2}, {3, 2, 5}}]]

在二维空间：

Wolfram Language code: Graphics[Ellipsoid[{0, 0}, {{5, 2}, {2, 5}}]]

样式化  (4)

具有不同的镜面指数的球：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], ℛ}], {n, {5, 20, 100}}]

发红光的黑球：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Graphics3D[{Glow[Red], Black, ℛ}]

Opacity 指定面不透明度：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Table[Graphics3D[{Opacity[o], ℛ}], {o, {0.3, 0.5, 0.9}}]

二维样式化：

Wolfram Language code: ℛ = Ellipsoid[{0, 0}, {3, 2}];
Wolfram Language code: Graphics[{EdgeForm[{Thick, Dashed, Blue}], Brown, ℛ}]

坐标  (2)

通过绘图范围的分数指定坐标：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[Scaled[{0.5, 0.75}], {3, 2}];
Wolfram Language code: Graphics[Subscript[ℛ, 1], PlotRange -> {{0, 8}, {0, 8}}, Frame -> True]

指定从普通坐标的缩放偏移：

Wolfram Language code: Graphics[Ellipsoid[ Scaled[{0.5, 0.25}, {0, 0}], {4, 2}], Frame -> True]

区域  (10)

嵌入维数是指球所在空间的维数：

Wolfram Language code: RegionEmbeddingDimension[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

几何维数是形状本身的维数：

Wolfram Language code: RegionDimension[Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}]]

成员检验：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {5, 5, 5}]}

获得点成员的条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体积：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

从一个点的距离：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {RegionDistance[ℛ, {0, 0, 0}], RegionDistance[ℛ, {0, 2, 2}]}

椭圆上到最近的点距离：

Wolfram Language code: Plot3D[RegionDistance[Ellipsoid[{0, 0}, {1, 2}], {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> {x^2 + (y^2/4) == 1}]

从一个点的符号距离：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {SignedRegionDistance[ℛ, {0, 2, 2}], SignedRegionDistance[ℛ, {0, 1 / 2, 0}]}

从一个椭圆的符号距离：

Wolfram Language code: Plot3D[SignedRegionDistance[Ellipsoid[{0, 0}, {1, 2}], {x, y}], {x, -3, 3}, {y, -3, 3}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

区域上的最近点：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {1, 2, 3}];
Wolfram Language code: {RegionNearest[ℛ, {3., 3, 3}], RegionNearest[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

到封闭球体的最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 4]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

椭球是有界的：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

在椭球区域上积分：

Wolfram Language code: ℛ = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

在椭球区域上优化：

Wolfram Language code: ℛ = Ellipsoid[{1, 2, 3}, {4, 5, 6}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]//RootReduce

求解椭圆区域上的方程：

Wolfram Language code: ℛ = Ellipsoid[{1, 2, 3}, {2, 3, 4}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

应用  (4)

球体是具有两个相等轴的椭球：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {a, a, c}]

计算体积：

Wolfram Language code: Volume[ℛ]

密度按 给出的椭圆体的总质量：

Wolfram Language code: ℛ = Ellipsoid[{a, b, c}, {Subscript[r, 1], Subscript[r, 2], Subscript[r, 3]}];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> Subscript[r, 1] > 0 && Subscript[r, 2] > 0 && Subscript[r, 3] > 0 && (a | b | c)∈Reals]

求 Ellipsoid 中的甲醇质量：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, Quantity[{4, 3, 2}, "Centimeters"]];

甲醇的密度：

Wolfram Language code: d = ChemicalData["Methanol", "Density"]

椭圆体的体积：

Wolfram Language code: v = Volume[ℛ]

甲醇在椭圆体的质量：

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> v}]

求区域边界框的有界 Ellipsoid：

Wolfram Language code: ℛ = Cone[{{0, 0, 0}, {0, 0, 3}}, 1];
Wolfram Language code: bounds = RegionBounds[ℛ];

计算边界框：

Wolfram Language code: boundingBox = Cuboid@@Transpose[bounds];

计算边界框的有界椭圆：

Wolfram Language code: r = (Sqrt[3]/2) EuclideanDistance@@@bounds;
Wolfram Language code: boundingEllipsoid = Ellipsoid[RegionCentroid[boundingBox], r];

计算边界实体的 Volume 的差：

Wolfram Language code: Volume[boundingEllipsoid] - Volume[boundingBox]

可视化有界曲面：

Wolfram Language code: Show[Graphics3D[{ℛ, EdgeForm[White], Opacity[0.2, Yellow], boundingBox, boundingEllipsoid}], Boxed -> False]

属性和关系  (4)

Disk 是 Ellipsoid 的一种特殊情形：

Wolfram Language code: RegionMember[Disk[{0, 0}, {1, 2}], {x, y}]
Wolfram Language code: RegionMember[Ellipsoid[{0, 0}, {1, 2}], {x, y}]

Ball 是 Ellipsoid 的一种特殊情形：

Wolfram Language code: RegionMember[Ball[{0, 0, 0}, 1], {x, y, z}]
Wolfram Language code: RegionMember[Ellipsoid[{0, 0, 0}, {1, 1, 1}], {x, y, z}]

Ellipsoid 是 Ball 的推广：

Wolfram Language code: Subscript[ℛ, 1] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 1, 1, 1}]; Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任何 Ellipsoid：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(Subscript[t, 1] - Subscript[c, 1])^2 + (1/4) (Subscript[t, 2] - Subscript[c, 2])^2 + (1/9) (Subscript[t, 3] - Subscript[c, 3])^2 + (1/16) (Subscript[t, 4] - Subscript[c, 4])^2 ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3], Subscript[t, 4]}]; Subscript[ℛ, 2] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 2, 3, 4}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (2)

随机椭球集合：

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Ellipsoid[RandomReal[50, {3}], RandomReal[{1, 5}, 3]]}, {100}]]

将椭球绕轴转动一圈：

Wolfram Language code: ℛ = Ellipsoid[{0, 0, 0}, {4, 3, 2}];
Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[ℛ, RotationTransform[c, {1, -2, 3}, {5, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 16}]}]
Wolfram Research (2014)，Ellipsoid，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Ellipsoid.html.

文本

Wolfram Research (2014)，Ellipsoid，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Ellipsoid.html.

CMS

Wolfram 语言. 2014. "Ellipsoid." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Ellipsoid.html.

APA

Wolfram 语言. (2014). Ellipsoid. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Ellipsoid.html 年

BibTeX

@misc{reference.wolfram_2026_ellipsoid, author="Wolfram Research", title="{Ellipsoid}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Ellipsoid.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipsoid, organization={Wolfram Research}, title={Ellipsoid}, year={2014}, url={https://reference.wolfram.com/language/ref/Ellipsoid.html}, note=[Accessed: 16-September-2026]}