WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EllipticExp[u,{a,b}]

EllipticLogの逆を与える．u==EllipticLog[{x,y},{a,b}]とするリスト{x,y}を生成する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
微分   
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

EllipticExp

EllipticExp[u,{a,b}]

EllipticLogの逆を与える．u==EllipticLog[{x,y},{a,b}]とするリスト{x,y}を生成する．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • EllipticExpは楕円曲線 に関する一般化された指数を与える．
  • 特別な引数の場合，EllipticExpは，自動的に厳密値を計算する．
  • EllipticExpは任意の数値精度で評価できる．

例題

すべて開く すべて閉じる

例  (2)

数値的に評価する：

Wolfram Language code: EllipticExp[-0.4, {4, 1}]

逆関数との関係をチェックする：

Wolfram Language code: EllipticLog[%, {4, 1}]

いくつかの実周期上にEllipticExpの成分をプロットする：

Wolfram Language code: Plot[{EllipticExp[x, {4, 1}]//First, EllipticExp[x, {4, 1}]//Last}, {x, 0, 4 2.83147}]

スコープ  (10)

数値評価  (4)

数値的に評価する：

Wolfram Language code: EllipticExp[5., {1, 2}]
Wolfram Language code: EllipticExp[-.4, {3, 2}]

高精度で評価する：

Wolfram Language code: N[EllipticExp[15 / 7, {5, 1}], 50]

出力精度は入力精度に従う：

Wolfram Language code: EllipticExp[0.211111111111111111, {5, 1}]

複素数入力：

Wolfram Language code: N[EllipticExp[27 + I, {5 - I, 2}]]

高精度で効率的に評価する：

Wolfram Language code: N[EllipticExp[157`10, {5, 1}], 50]//Timing
Wolfram Language code: N[EllipticExp[157`10000, {5, 1}], 50];//Timing

特定の値  (3)

固定点における値：

Wolfram Language code: EllipticExp[5, {0 , 0}]
Wolfram Language code: EllipticExp[Hypergeometric2F1[I 1 / 2, 1 / 2, 1 / 2, 3 / 2], {0 , 0}]
Wolfram Language code: EllipticExp[Hypergeometric2F1[ 1 / 2, 1 / 3, 1 / 2, 3 / 2], {0 , 0}]

記号的に評価する：

Wolfram Language code: EllipticExp[x, {0, 0}]//FunctionExpand

ゼロにおける値：

Wolfram Language code: EllipticExp[0, {1, 2}]

可視化  (2)

EllipticExp関数をさまざまなパラメータについてプロットする：

Wolfram Language code: Plot[{EllipticExp[u, {2, 3}], EllipticExp[u, {4, 3}], EllipticExp[-u, {4, 3}]}, {u, 0, 5}]

EllipticExp[z,{1,2}]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[EllipticExp[z, {1, 2}]], {z, -4 - 4I, 4 + 4 I}, IconizedObject[«PlotOptions»]]

EllipticExp[z,{1,2}]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[EllipticExp[z, {1, 2}]], {z, -4 - 4I, 4 + 4 I}, IconizedObject[«PlotOptions»]]

微分   (1)

u についての一次導関数：

Wolfram Language code: D[EllipticExp[u, {a, b}], u]

a=10 で b=1/3のとき，u についての一次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. { a -> 10, b -> 1 / 3}], {u, -3, 3}, PlotLegends -> {"First Derivative"}]

アプリケーション  (4)

楕円曲線 上で乗算を定義する：

Wolfram Language code: ellipticMultiply[{{x1_, y1_}, {x2_, y2_}}, {a_, b_}] := Module[{s = (y2 - y1) / (x2 - x1), x3, y3}, x3 = s ^ 2 - x1 - x2 - a; y3 = -y1 + s(x1 - x3); {x3, y3}]

楕円曲線上の乗算を使って有理数の加算を行う：

Wolfram Language code: ellipticMultiply[{EllipticExp[-1 / 3., {4, 1}], EllipticExp[1 / 2., {4, 1}]}, {4, 1}]

EllipticLogと比較する：

Wolfram Language code: EllipticLog[%, {4, 1}] == -1 / 3 + 1 / 2

楕円曲線上に整数をマップする：

Wolfram Language code: ContourPlot[y ^ 2 == x(x ^ 2 + 4.x + 1.), {x, -5, 5}, {y, -5, 5}, Epilog -> {Red, PointSize[Medium], Point[EllipticExp[#, {4., 1.}]& /@ Join[Range[-10, -1], Range[1, 10]]]}]

楕円指数関数を複素平面上で可視化する：

Wolfram Language code: Plot3D[Re[EllipticExp[x + I y, {1, 2}]], {x, -3, 3}, {y, -3, 3}]

楕円曲線 上で乗算を定義する：

Wolfram Language code: ellipticMultiply[{{x1_, y1_}, {x2_, y2_}}, {a_, b_}] := Module[{s = (y2 - y1) / (x2 - x1), x3, y3}, x3 = s ^ 2 - x1 - x2 - a; y3 = -y1 + s(x1 - x3);{x3, y3}]

楕円曲線上の乗算を使って有理数の加算を行う：

Wolfram Language code: p1 = EllipticExp[-1 / 3., {4, 1}]; p2 = EllipticExp[1 / 2., {4, 1}];
Wolfram Language code: p3 = ellipticMultiply[{p1, p2}, {4, 1}]

積の点におけるEllipticLogの値は対応する因子でのEllipticLogの値の和に等しい：

Wolfram Language code: EllipticLog[p3, {4, 1}] == EllipticLog[p1, {4, 1}] + EllipticLog[p2, {4, 1}]

特性と関係  (5)

微分：

Wolfram Language code: D[EllipticExp[u, {a, b}], u]

EllipticExp[u,{a,b}]によって返された点は を満足する：

Wolfram Language code: {x, y} = N[EllipticExp[1 / 2, {7, -2}], 16]
Wolfram Language code: With[{a = 7, b = -2}, y^2 == x^3 + a x^2 + b x]

EllipticExpは，WeierstrassP関数とその導関数に密接な関係がある：

Wolfram Language code: ellipticExp[u_, {a_, b_}] := {4 WeierstrassP[2u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}] - (a/3), 4WeierstrassPPrime[2u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]}

数値と比較する：

Wolfram Language code: ellipticExp[0.5, {3, 4}]
Wolfram Language code: EllipticExp[0.5, {3, 4}]

楕円指数関数とその導関数を評価する：

Wolfram Language code: u = -0.4;{a, b} = {4., 1.};
Wolfram Language code: eExp = EllipticExp[u, {a, b}]
Wolfram Language code: eExpPrime = EllipticExpPrime[u, {a, b}]

EllipticExpPrimeはEllipticExpの成分によって表すことができる：

Wolfram Language code: eExpPrime == {2Indexed[eExp, 2], 3Indexed[eExp, 1]^2 + 2a Indexed[eExp, 1] + b}

WeierstrassHalfPeriodsを使って線形独立のEllipticExpの2つの周期が計算できる：

Wolfram Language code: {a, b} = {4., 1.}; {p1, p2} = 2WeierstrassHalfPeriods[{(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]

複素平面の対応点におけるEllipticExpの数値評価と比較する：

Wolfram Language code: u = -0.4; {EllipticExp[u, {a, b}], EllipticExp[u + p1, {a, b}], EllipticExp[u + p2, {a, b}]}

考えられる問題  (1)

EllipticExpは二重周期の複素数関数であるので，逆の関係が常に当てはまるとは限らない：

Wolfram Language code: z = 12.4; EllipticExp[z, {4, 1}]
Wolfram Language code: z1 = EllipticLog[%, {4, 1}]

相違は格子の2つの周期と等しい：

Wolfram Language code: With[{a = 4, b = 1}, z == z1 + 4 WeierstrassHalfPeriodW3[{(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]]
Wolfram Research (1988), EllipticExp, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticExp.html.

テキスト

Wolfram Research (1988), EllipticExp, Wolfram言語関数， https://reference.wolfram.com/language/ref/EllipticExp.html.

CMS

Wolfram Language. 1988. "EllipticExp." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/EllipticExp.html.

APA

Wolfram Language. (1988). EllipticExp. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EllipticExp.html

BibTeX

@misc{reference.wolfram_2026_ellipticexp, author="Wolfram Research", title="{EllipticExp}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticExp.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticexp, organization={Wolfram Research}, title={EllipticExp}, year={1988}, url={https://reference.wolfram.com/language/ref/EllipticExp.html}, note=[Accessed: 08-September-2026]}