WOLFRAM

Wolfram 语言与系统参考资料中心

EllipticExp[u,{a,b}]

是与 EllipticLog 相反的. 它产生一个列表 {x,y} 以使得 u==EllipticLog[{x,y},{a,b}].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
微分  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

EllipticExp

EllipticExp[u,{a,b}]

是与 EllipticLog 相反的. 它产生一个列表 {x,y} 以使得 u==EllipticLog[{x,y},{a,b}].

更多信息

  • 数学函数，同时适合符号和数值操作.
  • EllipticExp 给出与椭圆曲线 相关的广义指数.
  • 对某些特定参数，EllipticExp 自动算出精确值.
  • EllipticExp 可求任意数值精度的值.

范例

打开所有单元 关闭所有单元

基本范例  (2)

数值计算：

Wolfram Language code: EllipticExp[-0.4, {4, 1}]

检查与反函数的关系：

Wolfram Language code: EllipticLog[%, {4, 1}]

绘制 EllipticExp 在数个实数周期内的分量：

Wolfram Language code: Plot[{EllipticExp[x, {4, 1}]//First, EllipticExp[x, {4, 1}]//Last}, {x, 0, 4 2.83147}]

范围  (10)

数值计算  (4)

数值化计算：

Wolfram Language code: EllipticExp[5., {1, 2}]
Wolfram Language code: EllipticExp[-.4, {3, 2}]

高精度计算：

Wolfram Language code: N[EllipticExp[15 / 7, {5, 1}], 50]

输出的精度与输入的精度一致：

Wolfram Language code: EllipticExp[0.211111111111111111, {5, 1}]

复数输入：

Wolfram Language code: N[EllipticExp[27 + I, {5 - I, 2}]]

高精度的高效计算：

Wolfram Language code: N[EllipticExp[157`10, {5, 1}], 50]//Timing
Wolfram Language code: N[EllipticExp[157`10000, {5, 1}], 50];//Timing

特殊值  (3)

在固定点的值：

Wolfram Language code: EllipticExp[5, {0 , 0}]
Wolfram Language code: EllipticExp[Hypergeometric2F1[I 1 / 2, 1 / 2, 1 / 2, 3 / 2], {0 , 0}]
Wolfram Language code: EllipticExp[Hypergeometric2F1[ 1 / 2, 1 / 3, 1 / 2, 3 / 2], {0 , 0}]

符号式计算：

Wolfram Language code: EllipticExp[x, {0, 0}]//FunctionExpand

零处的值：

Wolfram Language code: EllipticExp[0, {1, 2}]

可视化  (2)

绘制各种参数值的 EllipticExp 函数：

Wolfram Language code: Plot[{EllipticExp[u, {2, 3}], EllipticExp[u, {4, 3}], EllipticExp[-u, {4, 3}]}, {u, 0, 5}]

绘制 EllipticExp[z,{1,2}] 实部：

Wolfram Language code: ComplexContourPlot[Re[EllipticExp[z, {1, 2}]], {z, -4 - 4I, 4 + 4 I}, IconizedObject[«PlotOptions»]]

绘制 EllipticExp[z,{1,2}] 虚部：

Wolfram Language code: ComplexContourPlot[Im[EllipticExp[z, {1, 2}]], {z, -4 - 4I, 4 + 4 I}, IconizedObject[«PlotOptions»]]

微分  (1)

关于 u 的一阶导：

Wolfram Language code: D[EllipticExp[u, {a, b}], u]

当 a=10 且 b=1/3 时，绘制关于 u 的一阶导数：

Wolfram Language code: Plot[Evaluate[% /. { a -> 10, b -> 1 / 3}], {u, -3, 3}, PlotLegends -> {"First Derivative"}]

应用  (4)

在椭圆曲线 上定义加法：

Wolfram Language code: ellipticMultiply[{{x1_, y1_}, {x2_, y2_}}, {a_, b_}] := Module[{s = (y2 - y1) / (x2 - x1), x3, y3}, x3 = s ^ 2 - x1 - x2 - a; y3 = -y1 + s(x1 - x3); {x3, y3}]

在椭圆曲线上利用加法增加一个有理数：

Wolfram Language code: ellipticMultiply[{EllipticExp[-1 / 3., {4, 1}], EllipticExp[1 / 2., {4, 1}]}, {4, 1}]

与 EllipticLog 进行比较：

Wolfram Language code: EllipticLog[%, {4, 1}] == -1 / 3 + 1 / 2

在椭圆曲线上标出整数：

Wolfram Language code: ContourPlot[y ^ 2 == x(x ^ 2 + 4.x + 1.), {x, -5, 5}, {y, -5, 5}, Epilog -> {Red, PointSize[Medium], Point[EllipticExp[#, {4., 1.}]& /@ Join[Range[-10, -1], Range[1, 10]]]}]

在复平面内可视化椭圆指数：

Wolfram Language code: Plot3D[Re[EllipticExp[x + I y, {1, 2}]], {x, -3, 3}, {y, -3, 3}]

定义椭圆曲线 上的乘法：

Wolfram Language code: ellipticMultiply[{{x1_, y1_}, {x2_, y2_}}, {a_, b_}] := Module[{s = (y2 - y1) / (x2 - x1), x3, y3}, x3 = s ^ 2 - x1 - x2 - a; y3 = -y1 + s(x1 - x3);{x3, y3}]

在椭圆曲线上使用乘法来添加有理数：

Wolfram Language code: p1 = EllipticExp[-1 / 3., {4, 1}]; p2 = EllipticExp[1 / 2., {4, 1}];
Wolfram Language code: p3 = ellipticMultiply[{p1, p2}, {4, 1}]

乘积点的 EllipticLog 值等于相应因子的 EllipticLog 值之和：

Wolfram Language code: EllipticLog[p3, {4, 1}] == EllipticLog[p1, {4, 1}] + EllipticLog[p2, {4, 1}]

属性和关系  (5)

求导：

Wolfram Language code: D[EllipticExp[u, {a, b}], u]

由 EllipticExp[u,{a,b}] 返回的点 满足 ：

Wolfram Language code: {x, y} = N[EllipticExp[1 / 2, {7, -2}], 16]
Wolfram Language code: With[{a = 7, b = -2}, y^2 == x^3 + a x^2 + b x]

EllipticExp 与 WeierstrassP 函数及其导数有密切的关系：

Wolfram Language code: ellipticExp[u_, {a_, b_}] := {4 WeierstrassP[2u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}] - (a/3), 4WeierstrassPPrime[2u, {(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]}

比较数值：

Wolfram Language code: ellipticExp[0.5, {3, 4}]
Wolfram Language code: EllipticExp[0.5, {3, 4}]

计算椭圆指数及其导数：

Wolfram Language code: u = -0.4;{a, b} = {4., 1.};
Wolfram Language code: eExp = EllipticExp[u, {a, b}]
Wolfram Language code: eExpPrime = EllipticExpPrime[u, {a, b}]

EllipticExpPrime 可以用 EllipticExp 的分量来表示：

Wolfram Language code: eExpPrime == {2Indexed[eExp, 2], 3Indexed[eExp, 1]^2 + 2a Indexed[eExp, 1] + b}

WeierstrassHalfPeriods 可以用来计算 EllipticExp 的两个线性独立周期：

Wolfram Language code: {a, b} = {4., 1.}; {p1, p2} = 2WeierstrassHalfPeriods[{(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]

比较 EllipticExp 在复平面内同位点的数值计算：

Wolfram Language code: u = -0.4; {EllipticExp[u, {a, b}], EllipticExp[u + p1, {a, b}], EllipticExp[u + p2, {a, b}]}

可能存在的问题  (1)

EllipticExp 是一个多值复变函数，所以不能总保持反比关系：

Wolfram Language code: z = 12.4; EllipticExp[z, {4, 1}]
Wolfram Language code: z1 = EllipticLog[%, {4, 1}]

差异等于格的两个周期：

Wolfram Language code: With[{a = 4, b = 1}, z == z1 + 4 WeierstrassHalfPeriodW3[{(1/4)((a^2/3) - b), (1/8)(a/3)((b/2) - ((a/3))^2)}]]
Wolfram Research (1988)，EllipticExp，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticExp.html.

文本

Wolfram Research (1988)，EllipticExp，Wolfram 语言函数，https://reference.wolfram.com/language/ref/EllipticExp.html.

CMS

Wolfram 语言. 1988. "EllipticExp." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/EllipticExp.html.

APA

Wolfram 语言. (1988). EllipticExp. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/EllipticExp.html 年

BibTeX

@misc{reference.wolfram_2026_ellipticexp, author="Wolfram Research", title="{EllipticExp}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/EllipticExp.html}", note=[Accessed: 10-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_ellipticexp, organization={Wolfram Research}, title={EllipticExp}, year={1988}, url={https://reference.wolfram.com/language/ref/EllipticExp.html}, note=[Accessed: 10-July-2026]}