Wolfram言語＆システムドキュメントセンター

EmpiricalDistribution

EmpiricalDistribution[{x₁,x₂,…}]

データ値 x_iに基づいた経験分布を表す．

EmpiricalDistribution[{{x₁,y₁,…},{x₂,y₂,…},…}]

データ値{x_i,y_i,…}に基づいた多変量経験分布を表す．

EmpiricalDistribution[{w₁,w₂,…}{d₁,d₂,…}]

データ値 d_iが重み w_iで現れる経験分布を表す．

詳細

EmpiricalDistributionは任意の他の確率分布のように使えるDataDistributionオブジェクトを返す．
EmpiricalDistributionの値 x についての累積分布関数はで与えられる．
EmpiricalDistributionはMean，CDF，RandomVariate等の関数で使うことができる．

例題

すべて開くすべて閉じる

例 (2)

一変量データの経験分布を作成する：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 50];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

分布関数を可視化する：

Wolfram Language code: {DiscretePlot[PDF[𝒟, x], {x, data}], DiscretePlot[CDF[𝒟, x], {x, -4, 4, .01}]}

モーメントと分位数を計算する：

Wolfram Language code: Moment[𝒟, 2]

Wolfram Language code: Quantile[𝒟, 0.95]

二変量データの経験分布を作成する：

Wolfram Language code: data = BlockRandom[SeedRandom[0];RandomVariate[NormalDistribution[0, 2], {10, 2}]];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

推定CDFを可視化する：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -5, 5}, {y, -5, 5}, ExclusionsStyle -> Gray, Mesh -> None, PlotPoints -> 50]

共分散と一般的なモーメントを計算する：

Wolfram Language code: Covariance[𝒟]//MatrixForm

Wolfram Language code: Moment[𝒟, {1, 2}]

スコープ (19)

基本的な用法 (10)

一変量データの経験分布を作る：

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10];
data2 = RandomVariate[NormalDistribution[], 100];

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data1];
𝒟2 = EmpiricalDistribution[data2];

大きいデータ集合を使うともとになった分布がよりよく近似できる：

Wolfram Language code: Table[Plot[{CDF[𝒟, x], CDF[NormalDistribution[], x]}, {x, -5, 5}, Exclusions -> None], {𝒟, {𝒟1, 𝒟2}}]

単位付きの数量データについての経験分布を構築する：

Wolfram Language code: qa = QuantityArray[RandomReal[{45, 80}, 10 ^ 3], "Seconds"]

Wolfram Language code: 𝒟 = EmpiricalDistribution[qa]

選択的記述統計量を計算する：

Wolfram Language code: #[𝒟]& /@ {Mean, Variance, Skewness, Kurtosis}

厳密な数値データを使う：

Wolfram Language code: data = {2, √3, Pi, E, Log[5], 1, 2Pi};

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: CDF[𝒟, x]//PiecewiseExpand

各データ値に相当する重みのリストを指定する：

Wolfram Language code:

data = {1, 2, 3, 4, 5};
weights = {5, 4, 3, 2, 1};

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data];
𝒟2 = EmpiricalDistribution[weights -> data];

Wolfram Language code: Table[DiscretePlot[CDF[𝒟, x], {x, 0, 10, .01}], {𝒟, {𝒟1, 𝒟2}}]

記号による重みを使う：

Wolfram Language code:

data = Range[5];
weights = Array[w, 5];

Wolfram Language code: 𝒟 = EmpiricalDistribution[weights -> data];

分布の一般的なモーメント：

Wolfram Language code: Moment[𝒟, r]

4で評価された累積分布関数：

Wolfram Language code: CDF[𝒟, 4]

二変量データの経験分布を作る：

Wolfram Language code:

data1 = RandomVariate[BinormalDistribution[.5], 5];
data2 = RandomVariate[BinormalDistribution[.5], 100];

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data1];
𝒟2 = EmpiricalDistribution[data2];

大きいデータ集合を使うとより滑らかな推定が得られる：

Wolfram Language code:

Table[Plot3D[CDF[𝒟, {x, y}], {x, -5, 5}, {y, -5, 5}, Exclusions -> None, ColorFunction -> "AlpineColors"], {𝒟, {𝒟1, 𝒟2}}]

二変量データの重みのリストを指定する：

Wolfram Language code:

data = RandomVariate[BinormalDistribution[.5], 5];
weights = Range[5];

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data];
𝒟2 = EmpiricalDistribution[weights -> data];

Wolfram Language code:

Table[Plot3D[CDF[𝒟, {x, y}], {x, -5, 5}, {y, -5, 5}, Exclusions -> None, ColorFunction -> "SandyTerrain"], {𝒟, {𝒟1, 𝒟2}}]

より高次元でデータの経験分布を作る：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {25, 3}];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

一変量周辺分布の累積分布関数をプロットする：

Wolfram Language code: Table[DiscretePlot[Evaluate[CDF[MarginalDistribution[𝒟, i], x]], {x, -4, 4, .01}, PlotLabel -> i], {i, 3}]

二変量周辺分布の累積分布関数をプロットする：

Wolfram Language code:

Table[Plot3D[Evaluate[CDF[MarginalDistribution[𝒟, i], {x, y}]], {x, -4, 4}, {y, -4, 4}, Exclusions -> None, ColorFunction -> "DarkRainbow", PlotLabel -> i], {i, Subsets[Range[3], {2}]}]

EmpiricalDistributionは，入力がTimeSeriesのときにのみ値に使うことができる：

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{0.28997620491523546, 0.21469930011788044, 0.46098352552570165, 
    0.24470387685580416, 0.14486640814874496, 0.5709045541820718, 0.3328911094711541, 
    0.32651519192444917, 0.25437382941700937, 0.46257184080167396, 0. ... 3011563444, 111.83615205759298, 
     112.05218999953303, 112.0628205040245, 112.14947462367655, 112.61704830425128}}}, 1, 
  {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];

Wolfram Language code: res1 = EmpiricalDistribution[ts]

値のみを使う場合と比較する：

Wolfram Language code: res2 = EmpiricalDistribution[ts["Values"]]

Wolfram Language code: res1 == res2

EmpiricalDistributionは，入力がTemporalDataのときはすべての値に同時に働く：

Wolfram Language code: td = TemporalData[«4»];

Wolfram Language code: res1 = EmpiricalDistribution[td]

以下と同じである：

Wolfram Language code: res2 = EmpiricalDistribution[td["ValueList"]//Flatten]

Wolfram Language code: res1 == res2

分布特性 (9)

分布関数の経験推定値を得る：

Wolfram Language code: 𝒟 = EmpiricalDistribution[data = RandomVariate[NormalDistribution[], 25]];

HazardFunctionと PDFは離散的である：

Wolfram Language code: Table[DiscretePlot[f[𝒟, x], {x, data}, PlotLabel -> f], {f, {PDF, HazardFunction}}]

SurvivalFunctionとCDFは区分定数である：

Wolfram Language code: Table[DiscretePlot[f[𝒟, x], {x, -4, 4, .01}, PlotLabel -> f], {f, {CDF, SurvivalFunction}}]

モーメントを計算する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[NormalDistribution[], 25]];

特殊なモーメント：

Wolfram Language code: {Mean[𝒟], Variance[𝒟], Skewness[𝒟], Kurtosis[𝒟]}

一般的なモーメント：

Wolfram Language code: Table[Moment[𝒟, k], {k, 4}]

Wolfram Language code: Table[CentralMoment[𝒟, k], {k, 4}]

Wolfram Language code: Table[Cumulant[𝒟, k], {k, 4}]

Wolfram Language code: Table[FactorialMoment[𝒟, k], {k, 4}]

分位関数を推定する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[CauchyDistribution[0, 1], 100]];

Wolfram Language code: Plot[Quantile[𝒟, x]//Evaluate, {x, 0, 1}, Exclusions -> None, Filling -> Axis]

特殊な分位値：

Wolfram Language code: Quartiles[𝒟]

Wolfram Language code: InterquartileRange[𝒟]

Wolfram Language code: Quantile[𝒟, {0.05, 0.95}]

Wolfram Language code: Median[𝒟]

乱数集合を生成する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomReal[ChiSquareDistribution[2], 10 ^ 3]];

そのヒストグラムともとになっている密度の確率密度関数を比較する：

Wolfram Language code:

Show[Histogram[RandomVariate[𝒟, 10 ^ 4], Automatic, "ProbabilityDensity"], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 10}, PlotStyle -> Thick]]

確率と期待値を計算する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[NormalDistribution[], 100]];

Wolfram Language code: Probability[x > 2, x𝒟]

Wolfram Language code: Expectation[x^2 - 3x + 2, x𝒟]

母関数：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[NormalDistribution[], 10]];

Wolfram Language code: MomentGeneratingFunction[𝒟, t]

Wolfram Language code: CharacteristicFunction[𝒟, t]

二変量分布関数を推定する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[dat = RandomVariate[BinormalDistribution[.5], 10]];

CDFとSurvivalFunctionは区分定数である：

Wolfram Language code:

Table[Plot3D[f[𝒟, {x, y}]//Evaluate, {x, -4, 4}, {y, -4, 4}, Exclusions -> None, PlotLabel -> f, ColorFunction -> "DarkRainbow"], {f, {CDF, SurvivalFunction}}]

二変量モーメントを計算する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[d = RandomVariate[BinormalDistribution[.2], 100]];

特殊なモーメント：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Wolfram Language code: Covariance[𝒟]//MatrixForm

Wolfram Language code: Correlation[𝒟]//MatrixForm

一般的なモーメント：

Wolfram Language code: Moment[𝒟, {1, 2}]

Wolfram Language code: CentralMoment[𝒟, {1, 2}]

Wolfram Language code: Cumulant[𝒟, {1, 2}]

Wolfram Language code: FactorialMoment[𝒟, {1, 2}]

乱数集合を生成する：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[BinormalDistribution[.5], 1000]];

Wolfram Language code: ListPlot[RandomVariate[𝒟, 100]]

アプリケーション (8)

データの分布と理論分布を比較する：

Wolfram Language code: data = RandomVariate[ParetoDistribution[1, 2], 25];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: Plot[{CDF[𝒟, x], CDF[ParetoDistribution[1, 2], x]}, {x, 0, 10}]

多変量データを理論分布と比較する：

Wolfram Language code: data = RandomVariate[𝒹 = MultinormalDistribution[{0, 0}, IdentityMatrix[2]], 100];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: Plot3D[CDF[#, {x, y}], {x, -3, 3}, {y, -3, 3}, Exclusions -> None, Mesh -> None]& /@ {𝒟, 𝒹}

差：

Wolfram Language code:

Plot3D[CDF[𝒟, {x, y}] - CDF[𝒹, {x, y}], {x, -3, 3}, {y, -3, 3}, Exclusions -> None, ColorFunction -> "DarkRainbow", PlotRange -> {Full, Full, {-0.1, 0.1}}]

SmoothKernelDistributionを使って滑らかに表示する：

Wolfram Language code: data = RandomVariate[MixtureDistribution[{2 / 3, 1 / 3}, {NormalDistribution[-1, 1], NormalDistribution[0, 1]}], 15];

Wolfram Language code:

Subscript[𝒟, e] = {"Empirical", EmpiricalDistribution[data]};
Subscript[𝒟, s] = {"Smoothed", SmoothKernelDistribution[data]};

Wolfram Language code:

Table[DiscretePlot[CDF[𝒟[[2]], x], {x, -4, 4, .01}, PlotLabel -> 𝒟[[1]]], {𝒟, {Subscript[𝒟, e], Subscript[𝒟, s]}}]

HistogramDistributionをデータに設定されたビンデリミタと一緒に使ってEmpiricalDistributionの線形補間を行う：

Wolfram Language code: data = RandomVariate[MixtureDistribution[{2 / 3, 1 / 3}, {NormalDistribution[-1, 1], NormalDistribution[0, 1]}], 10];

Wolfram Language code:

Subscript[𝒟, e] = {"Empirical", EmpiricalDistribution[data]};
Subscript[𝒟, h] = {"Histogram", HistogramDistribution[data, {Union@data}]};

Wolfram Language code:

Table[DiscretePlot[CDF[𝒟[[2]], x], {x, -4, 4, .01}, PlotLabel -> 𝒟[[1]]], {𝒟, {Subscript[𝒟, e], Subscript[𝒟, h]}}]

1861年にQuintus Curtius Snodgrassの名で出版された10通の手紙はMark Twainによるものだと言われている．これらの手紙とMark Twainの作品の単語長の分布を比較する：

Wolfram Language code: ExampleData[{"Statistics", "MarkTwainAuthorship"}, "ColumnDescriptions"]

Wolfram Language code:

mTwain = ExampleData[{"Statistics", "MarkTwainAuthorship"}][[All, {1, 2}]];
QCS = ExampleData[{"Statistics", "MarkTwainAuthorship"}][[All, {1, 3}]];

Wolfram Language code:

Twain = EmpiricalDistribution[mTwain[[All, 2]] -> mTwain[[All, 1]]];
Subscript[𝒟, QCS] = EmpiricalDistribution[QCS[[All, 2]] -> QCS[[All, 1]]];
Subscript[𝒟, Eng] = EmpiricalDistribution[StringLength /@ WordData[All]];

英語一般との比較で上記の類似性が明らかになる：

Wolfram Language code:

Table[Plot[{CDF[Twain, x], CDF[𝒟, x]}, {x, 0, 30}, PlotRange -> All, Exclusions -> None], {𝒟, {Subscript[𝒟, QCS], Subscript[𝒟, Eng]}}]

しかし，このフィットの適合度検定はQCSの手紙を書いたのがTwainではないことを示している：

Wolfram Language code:

twain = Flatten[Table[ConstantArray[i[[1]], i[[2]]], {i, mTwain}]];
qcs = Flatten[Table[ConstantArray[i[[1]], i[[2]]], {i, QCS}]];

Wolfram Language code: DistributionFitTest[twain, qcs, "TestDataTable"]

スコットランドの山岳徒競走の高地の道と低地の道を選んだ者の優勝記録を比較する：

Wolfram Language code: ExampleData[{"Statistics", "ScottishHillRaces"}, "ColumnDescriptions"]

Wolfram Language code: data = QuantityArray[ExampleData[{"Statistics", "ScottishHillRaces"}][[All, {3, 4}]], {"Feet", "Minutes"}];

記録時間と高度の増加をプロットする：

Wolfram Language code: ListPlot[data, AxesLabel -> Automatic]

高度増加の中央値を求める：

Wolfram Language code: medEG = Median[data[[All, 1]]]

高度増加の中央値でレースを高地と低地に分ける：

Wolfram Language code:

nd = Normal[data];
Subscript[𝒟, HighRoad] = EmpiricalDistribution[Cases[nd, {eg_ /; eg > medEG, t_} :> t]];
Subscript[𝒟, LowRoad] = EmpiricalDistribution[Cases[nd, {eg_ /; eg <= medEG, t_} :> t]];

Wolfram Language code:

Plot[{CDF[Subscript[𝒟, HighRoad], Quantity[x, "Minutes"]], CDF[Subscript[𝒟, LowRoad], Quantity[x, "Minutes"]]}, {x, 0, 250}, Exclusions -> None, Filling -> Axis, PlotRange -> {0, 1}, AxesLabel -> {"min"}, PlotLegends -> {"SubscriptBox[𝒟, HighRoad]", "SubscriptBox[𝒟, LowRoad]"}]

低地の道を選んだ方が速いようである：

Wolfram Language code: {Median[Subscript[𝒟, HighRoad]], Median[Subscript[𝒟, LowRoad]]}

高地レースの記録時間は低地レースの記録時間よりも変化が大きい：

Wolfram Language code: {QuartileDeviation[Subscript[𝒟, HighRoad]], QuartileDeviation[Subscript[𝒟, LowRoad]]}

国立衛生研究所では人口の2%が何等かの疾病を抱えていると推測している．偽陽性率5%で95%疾病が検出できる検査が提唱された．陽性反応が出た人が実際に疾病に罹患している確率を求める：

Wolfram Language code:

sick = {1, 1, 0, 0};
positive = {1, 0, 1, 0};

Wolfram Language code: 𝒟 = EmpiricalDistribution[{p1, p2, p3, p4} -> Transpose[{sick, positive}]]

与えられた情報に基づく不明確率の方程式：

Wolfram Language code:

eqs = {Probability[s == 1, {s, p}𝒟] == (2/100), Probability[p == 1s == 1, {s, p}𝒟] == (95/100), Probability[p == 1s == 0, {s, p}𝒟] == (5/100)}

確率の総和が1になると仮定して方程式を解く：

Wolfram Language code: sol = Solve[eqs~Join~{p1 + p2 + p3 + p4 == 1}, {p1, p2, p3, p4}]//N

陽性反応が出た人が罹患している確率：

Wolfram Language code: Probability[s == 1p == 1, {s, p}𝒟] /. sol[[1]]

21人の学生が新たなリーディングプログラムに参加するように無作為に選ばれた．対照群の23人の学生は従来の方法で教育されている．プログラム後に2つのグループの学生のリーディングのスコアが記録された．スコアに対して置換に基づいた検定を行い新たなリーディングプログラムが成功だったかどうかを見る：

Wolfram Language code:

treatment = {24, 61, 59, 46, 43, 53, 43, 44, 52, 43, 57, 49, 58, 67, 62, 57, 56, 33, 71, 49, 54};
control = {42, 33, 46, 37, 62, 20, 43, 41, 10, 42, 53, 48, 55, 19, 17, 55, 37, 85, 26, 54, 60, 28, 42};

グループ間のテストスコアの平均差は検定統計として用いることができる：

Wolfram Language code: testStatistic = Mean[treatment] - Mean[control]//N

グループをランダムに置換して検定統計の帰無分布のシミュレーションを行う：

Wolfram Language code:

permute[treat_, cont_, nPerm_] := Table[With[{sample = RandomSample[Join[treat, cont]]}, Mean[Take[sample, Length[treat]] - Mean[Drop[sample, Length[treat]]]]], {nPerm}]

Wolfram Language code: 𝒟0 = permute[treatment, control, 25000];

Wolfram Language code: Histogram[𝒟0, Automatic, "PDF"]

5%レベルで新たなプログラムで違いが生まれたことが明らかである：

Wolfram Language code: empP[tstat_, 𝒟0_] := N@Probability[x ≥ tstat, xEmpiricalDistribution[𝒟0]]

Wolfram Language code: empP[testStatistic, 𝒟0]

LocationTestを使って仮説を直接調べることができる：

Wolfram Language code: LocationTest[{treatment, control}, AlternativeHypothesis -> "Greater"]

特性と関係 (8)

経験分布に従って生成された乱数はブートストラップサンプルを返す：

Wolfram Language code: dist = EmpiricalDistribution[Range[10]];

Wolfram Language code: ListPlot[RandomVariate[dist, 1000]]

EmpiricalDistributionはもとになっている分布の一定した推定器である：

Wolfram Language code: data = Table[RandomReal[d = NormalDistribution[], i], {i, {5, 10, 50, 100, 500, 1000}}];

Wolfram Language code: dists = EmpiricalDistribution /@ data;

Wolfram Language code: Table[Plot[{CDF[i, x], CDF[d, x]}, {x, -4, 4}, PlotLabel -> Row[{i[[4]], " points"}], Exclusions -> None], {i, dists}]

モーメントとそのデータのモーメント相等物：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: Mean[𝒟] == Mean[data]

Wolfram Language code: Moment[𝒟, r] == Moment[data, r]//Simplify

経験分布にはサンプルの分散よりも母集団が使われる：

Wolfram Language code: Variance[𝒟] == Variance[data]

Wolfram Language code: CentralMoment[𝒟, 2] == Variance[𝒟]

分位数はQuantileを直接データに適用したものに等しい：

Wolfram Language code: 𝒟 = EmpiricalDistribution[data = RandomVariate[NormalDistribution[], 7]];

Wolfram Language code: rng = Range[0, 1, 1 / 99];

Wolfram Language code: Total[Quantile[𝒟, rng] / Quantile[data, rng]] / 100

EmpiricalDistributionは打切りのないSurvivalDistributionに等しい：

Wolfram Language code: data = Range[100];

Wolfram Language code: d1 = EmpiricalDistribution[data];

Wolfram Language code: d2 = SurvivalDistribution[data];

Wolfram Language code: Total[Table[PDF[d1, x] - PDF[d2, x], {x, DistributionDomain[d1]}]]

データ値の和集合をHistogramDistributionのビンデリミタとして使う：

Wolfram Language code: data = {1, 1, 2, 2, 3, 4, 4, 4, 5, 6, 7};

Wolfram Language code:

𝒟1 = HistogramDistribution[data, {Join[Union[data], {Max[data] + 1}]}];
𝒟2 = EmpiricalDistribution[data];

結果の確率密度関数はEmpiricalDistributionの確率密度関数の零次補間である：

Wolfram Language code: Show[DiscretePlot[PDF[𝒟2, x], {x, data}, PlotStyle -> Green], Plot[PDF[𝒟1, x], {x, 0, 9}, Exclusions -> None]]

Nを厳密データに適用するとメモリ消費量が抑えられる：

Wolfram Language code: data = RandomChoice[{π, E, Sin[5], Sqrt[2], 1}, 10 ^ 4];

Wolfram Language code: c = RandomChoice[Range[500], 10 ^ 4];

Wolfram Language code:

𝒟 = EmpiricalDistribution[c data];
Subscript[𝒟, Num] = EmpiricalDistribution[N[c data]];

Wolfram Language code: {ByteCount[𝒟], ByteCount[Subscript[𝒟, Num]]}

累積分布関数は等価である：

Wolfram Language code: Table[Plot[CDF[i, x], {x, 0, 10}, Exclusions -> None], {i, {𝒟, Subscript[𝒟, Num]}}]

整数についてのEmpiricalDistributionはProbabilityDistributionを使って指定することができる：

Wolfram Language code: edist = EmpiricalDistribution[{1 / 6, 1 / 3, 1 / 3, 1 / 6} -> {1, 2, 3, 4}]

Wolfram Language code: pdist = ProbabilityDistribution[(1/6)Boole[x == 1 || x == 4] + (1/3)Boole[x == 2 || x == 3], {x, 1, 4, 1}]

Wolfram Language code: PDF[edist, x] == PDF[pdist, x]//Simplify

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EmpiricalDistribution

詳細

例題

例 (2)

スコープ (19)

基本的な用法 (10)

分布特性 (9)

アプリケーション (8)

特性と関係 (8)

テキスト

CMS

APA

BibTeX

BibLaTeX

EmpiricalDistribution

詳細

例題

例 (2)

スコープ (19)

基本的な用法 (10)

分布特性 (9)

アプリケーション (8)

特性と関係 (8)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX