Wolfram 语言与系统参考资料中心

EmpiricalDistribution

EmpiricalDistribution[{x₁,x₂,…}]

表示基于数据值 x_i 的经验分布函数.

EmpiricalDistribution[{{x₁,y₁,…},{x₂,y₂,…},…}]

表示基于数据值 {x_i,y_i,…} 的多变量经验分布函数.

EmpiricalDistribution[{w₁,w₂,…}{d₁,d₂,…}]

表示一种经验分布函数，其中出现数据值 d_i 的权重为 w_i.

范例

打开所有单元关闭所有单元

基本范例 (2)

创建一个单变量数据的经验分布：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 50];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

对分布函数作图:

Wolfram Language code: {DiscretePlot[PDF[𝒟, x], {x, data}], DiscretePlot[CDF[𝒟, x], {x, -4, 4, .01}]}

计算矩和分位数：

Wolfram Language code: Moment[𝒟, 2]

Wolfram Language code: Quantile[𝒟, 0.95]

创建一个双变量数据的经验分布：

Wolfram Language code: data = BlockRandom[SeedRandom[0];RandomVariate[NormalDistribution[0, 2], {10, 2}]];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

可视化计算出的 CDF：

Wolfram Language code: Plot3D[Evaluate[CDF[𝒟, {x, y}]], {x, -5, 5}, {y, -5, 5}, ExclusionsStyle -> Gray, Mesh -> None, PlotPoints -> 50]

计算协方差和一般矩：

Wolfram Language code: Covariance[𝒟]//MatrixForm

Wolfram Language code: Moment[𝒟, {1, 2}]

范围 (19)

基本使用 (10)

创建一个单变量数据的经验分布：

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10];
data2 = RandomVariate[NormalDistribution[], 100];

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data1];
𝒟2 = EmpiricalDistribution[data2];

大型数据集合会对底层分布进行较好地近似：

Wolfram Language code: Table[Plot[{CDF[𝒟, x], CDF[NormalDistribution[], x]}, {x, -5, 5}, Exclusions -> None], {𝒟, {𝒟1, 𝒟2}}]

为数量数据构建经验分布：

Wolfram Language code: qa = QuantityArray[RandomReal[{45, 80}, 10 ^ 3], "Seconds"]

Wolfram Language code: 𝒟 = EmpiricalDistribution[qa]

计算选定的描述性统计指标：

Wolfram Language code: #[𝒟]& /@ {Mean, Variance, Skewness, Kurtosis}

使用精确的数值型数据：

Wolfram Language code: data = {2, √3, Pi, E, Log[5], 1, 2Pi};

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: CDF[𝒟, x]//PiecewiseExpand

指定一个权重的列表，与每个数据值对应：

Wolfram Language code:

data = {1, 2, 3, 4, 5};
weights = {5, 4, 3, 2, 1};

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data];
𝒟2 = EmpiricalDistribution[weights -> data];

Wolfram Language code: Table[DiscretePlot[CDF[𝒟, x], {x, 0, 10, .01}], {𝒟, {𝒟1, 𝒟2}}]

使用符号表示的权值：

Wolfram Language code:

data = Range[5];
weights = Array[w, 5];

Wolfram Language code: 𝒟 = EmpiricalDistribution[weights -> data];

该分布的一般矩：

Wolfram Language code: Moment[𝒟, r]

在 4 处计算累积分布函数：

Wolfram Language code: CDF[𝒟, 4]

创建一个双变量数据的经验分布：

Wolfram Language code:

data1 = RandomVariate[BinormalDistribution[.5], 5];
data2 = RandomVariate[BinormalDistribution[.5], 100];

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data1];
𝒟2 = EmpiricalDistribution[data2];

较大的数据集可以产生较平滑的估计：

Wolfram Language code:

Table[Plot3D[CDF[𝒟, {x, y}], {x, -5, 5}, {y, -5, 5}, Exclusions -> None, ColorFunction -> "AlpineColors"], {𝒟, {𝒟1, 𝒟2}}]

指定双变量数据的权重列表：

Wolfram Language code:

data = RandomVariate[BinormalDistribution[.5], 5];
weights = Range[5];

Wolfram Language code:

𝒟1 = EmpiricalDistribution[data];
𝒟2 = EmpiricalDistribution[weights -> data];

Wolfram Language code:

Table[Plot3D[CDF[𝒟, {x, y}], {x, -5, 5}, {y, -5, 5}, Exclusions -> None, ColorFunction -> "SandyTerrain"], {𝒟, {𝒟1, 𝒟2}}]

创建较高维数的数据的经验分布：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {25, 3}];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

绘制单变量边缘分布的累积分布函数：

Wolfram Language code: Table[DiscretePlot[Evaluate[CDF[MarginalDistribution[𝒟, i], x]], {x, -4, 4, .01}, PlotLabel -> i], {i, 3}]

绘制双变量边缘分布的累积分布函数：

Wolfram Language code:

Table[Plot3D[Evaluate[CDF[MarginalDistribution[𝒟, i], {x, y}]], {x, -4, 4}, {y, -4, 4}, Exclusions -> None, ColorFunction -> "DarkRainbow", PlotLabel -> i], {i, Subsets[Range[3], {2}]}]

EmpiricalDistribution 只当输入是 TimeSeries 时作用于数值:

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{0.28997620491523546, 0.21469930011788044, 0.46098352552570165, 
    0.24470387685580416, 0.14486640814874496, 0.5709045541820718, 0.3328911094711541, 
    0.32651519192444917, 0.25437382941700937, 0.46257184080167396, 0. ... 3011563444, 111.83615205759298, 
     112.05218999953303, 112.0628205040245, 112.14947462367655, 112.61704830425128}}}, 1, 
  {"Continuous", 1}, {"Discrete", 1}, 1, 
  {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];

Wolfram Language code: res1 = EmpiricalDistribution[ts]

与只使用数值比较：

Wolfram Language code: res2 = EmpiricalDistribution[ts["Values"]]

Wolfram Language code: res1 == res2

EmpiricalDistribution 当输入是 TemporalData 时，作用于所有数值：

Wolfram Language code: td = TemporalData[«4»];

Wolfram Language code: res1 = EmpiricalDistribution[td]

与下面相同：

Wolfram Language code: res2 = EmpiricalDistribution[td["ValueList"]//Flatten]

Wolfram Language code: res1 == res2

分布属性 (9)

获得分布函数的经验估计：

Wolfram Language code: 𝒟 = EmpiricalDistribution[data = RandomVariate[NormalDistribution[], 25]];

PDF 与 HazardFunction 是离散的：

Wolfram Language code: Table[DiscretePlot[f[𝒟, x], {x, data}, PlotLabel -> f], {f, {PDF, HazardFunction}}]

CDF 和 SurvivalFunction 为分段函数，在各段均为常数：

Wolfram Language code: Table[DiscretePlot[f[𝒟, x], {x, -4, 4, .01}, PlotLabel -> f], {f, {CDF, SurvivalFunction}}]

计算矩：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[NormalDistribution[], 25]];

特殊矩：

Wolfram Language code: {Mean[𝒟], Variance[𝒟], Skewness[𝒟], Kurtosis[𝒟]}

一般矩：

Wolfram Language code: Table[Moment[𝒟, k], {k, 4}]

Wolfram Language code: Table[CentralMoment[𝒟, k], {k, 4}]

Wolfram Language code: Table[Cumulant[𝒟, k], {k, 4}]

Wolfram Language code: Table[FactorialMoment[𝒟, k], {k, 4}]

估计分位数函数：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[CauchyDistribution[0, 1], 100]];

Wolfram Language code: Plot[Quantile[𝒟, x]//Evaluate, {x, 0, 1}, Exclusions -> None, Filling -> Axis]

特殊的分位数值：

Wolfram Language code: Quartiles[𝒟]

Wolfram Language code: InterquartileRange[𝒟]

Wolfram Language code: Quantile[𝒟, {0.05, 0.95}]

Wolfram Language code: Median[𝒟]

生成一组随机数：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomReal[ChiSquareDistribution[2], 10 ^ 3]];

比较直方图与底层密度的概率密度函数：

Wolfram Language code:

Show[Histogram[RandomVariate[𝒟, 10 ^ 4], Automatic, "ProbabilityDensity"], Plot[PDF[ChiSquareDistribution[2], x], {x, 0, 10}, PlotStyle -> Thick]]

计算概率和期望：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[NormalDistribution[], 100]];

Wolfram Language code: Probability[x > 2, x𝒟]

Wolfram Language code: Expectation[x^2 - 3x + 2, x𝒟]

母函数：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[NormalDistribution[], 10]];

Wolfram Language code: MomentGeneratingFunction[𝒟, t]

Wolfram Language code: CharacteristicFunction[𝒟, t]

估计双变量分布函数：

Wolfram Language code: 𝒟 = EmpiricalDistribution[dat = RandomVariate[BinormalDistribution[.5], 10]];

CDF 和 SurvivalFunction 为分段函数，在各段均为常数：

Wolfram Language code:

Table[Plot3D[f[𝒟, {x, y}]//Evaluate, {x, -4, 4}, {y, -4, 4}, Exclusions -> None, PlotLabel -> f, ColorFunction -> "DarkRainbow"], {f, {CDF, SurvivalFunction}}]

计算双变量矩：

Wolfram Language code: 𝒟 = EmpiricalDistribution[d = RandomVariate[BinormalDistribution[.2], 100]];

特殊矩：

Wolfram Language code: {Mean[𝒟], Variance[𝒟]}

Wolfram Language code: Covariance[𝒟]//MatrixForm

Wolfram Language code: Correlation[𝒟]//MatrixForm

一般矩：

Wolfram Language code: Moment[𝒟, {1, 2}]

Wolfram Language code: CentralMoment[𝒟, {1, 2}]

Wolfram Language code: Cumulant[𝒟, {1, 2}]

Wolfram Language code: FactorialMoment[𝒟, {1, 2}]

生成一组随机数：

Wolfram Language code: 𝒟 = EmpiricalDistribution[RandomVariate[BinormalDistribution[.5], 1000]];

Wolfram Language code: ListPlot[RandomVariate[𝒟, 100]]

应用 (8)

比较数据的分布与理论分布：

Wolfram Language code: data = RandomVariate[ParetoDistribution[1, 2], 25];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: Plot[{CDF[𝒟, x], CDF[ParetoDistribution[1, 2], x]}, {x, 0, 10}]

比较多变量数据与理论分布：

Wolfram Language code: data = RandomVariate[𝒹 = MultinormalDistribution[{0, 0}, IdentityMatrix[2]], 100];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: Plot3D[CDF[#, {x, y}], {x, -3, 3}, {y, -3, 3}, Exclusions -> None, Mesh -> None]& /@ {𝒟, 𝒹}

两者之差：

Wolfram Language code:

Plot3D[CDF[𝒟, {x, y}] - CDF[𝒹, {x, y}], {x, -3, 3}, {y, -3, 3}, Exclusions -> None, ColorFunction -> "DarkRainbow", PlotRange -> {Full, Full, {-0.1, 0.1}}]

用 SmoothKernelDistribution 生成平滑的表示：

Wolfram Language code: data = RandomVariate[MixtureDistribution[{2 / 3, 1 / 3}, {NormalDistribution[-1, 1], NormalDistribution[0, 1]}], 15];

Wolfram Language code:

Subscript[𝒟, e] = {"Empirical", EmpiricalDistribution[data]};
Subscript[𝒟, s] = {"Smoothed", SmoothKernelDistribution[data]};

Wolfram Language code:

Table[DiscretePlot[CDF[𝒟[[2]], x], {x, -4, 4, .01}, PlotLabel -> 𝒟[[1]]], {𝒟, {Subscript[𝒟, e], Subscript[𝒟, s]}}]

利用以数据为各区间的分界符的 HistogramDistribution 创建 EmpiricalDistribution 的一个线性插值：

Wolfram Language code: data = RandomVariate[MixtureDistribution[{2 / 3, 1 / 3}, {NormalDistribution[-1, 1], NormalDistribution[0, 1]}], 10];

Wolfram Language code:

Subscript[𝒟, e] = {"Empirical", EmpiricalDistribution[data]};
Subscript[𝒟, h] = {"Histogram", HistogramDistribution[data, {Union@data}]};

Wolfram Language code:

Table[DiscretePlot[CDF[𝒟[[2]], x], {x, -4, 4, .01}, PlotLabel -> 𝒟[[1]]], {𝒟, {Subscript[𝒟, e], Subscript[𝒟, h]}}]

在1861年以笔名 Quintus Curtius Snodgrass 发表的10封书信被认为是马克吐温的亲笔. 将这些书信的长度分布与马克吐温的某些作品比较：

Wolfram Language code: ExampleData[{"Statistics", "MarkTwainAuthorship"}, "ColumnDescriptions"]

Wolfram Language code:

mTwain = ExampleData[{"Statistics", "MarkTwainAuthorship"}][[All, {1, 2}]];
QCS = ExampleData[{"Statistics", "MarkTwainAuthorship"}][[All, {1, 3}]];

Wolfram Language code:

Twain = EmpiricalDistribution[mTwain[[All, 2]] -> mTwain[[All, 1]]];
Subscript[𝒟, QCS] = EmpiricalDistribution[QCS[[All, 2]] -> QCS[[All, 1]]];
Subscript[𝒟, Eng] = EmpiricalDistribution[StringLength /@ WordData[All]];

与英语语言比较，一般强调相似性：

Wolfram Language code:

Table[Plot[{CDF[Twain, x], CDF[𝒟, x]}, {x, 0, 30}, PlotRange -> All, Exclusions -> None], {𝒟, {Subscript[𝒟, QCS], Subscript[𝒟, Eng]}}]

拟合优度检验表明马克吐温没有撰写该 QCS 书信：

Wolfram Language code:

twain = Flatten[Table[ConstantArray[i[[1]], i[[2]]], {i, mTwain}]];
qcs = Flatten[Table[ConstantArray[i[[1]], i[[2]]], {i, QCS}]];

Wolfram Language code: DistributionFitTest[twain, qcs, "TestDataTable"]

比较在苏格兰山比赛中走高路和走低路的运动员获胜次数的分布：

Wolfram Language code: ExampleData[{"Statistics", "ScottishHillRaces"}, "ColumnDescriptions"]

Wolfram Language code: data = QuantityArray[ExampleData[{"Statistics", "ScottishHillRaces"}][[All, {3, 4}]], {"Feet", "Minutes"}];

画出比赛用时和攀升的海拔高度：

Wolfram Language code: ListPlot[data, AxesLabel -> Automatic]

求出海拔攀升高度的中位数：

Wolfram Language code: medEG = Median[data[[All, 1]]]

以海拔攀升的中位数高度为基准，将比赛分为高路和低路：

Wolfram Language code:

nd = Normal[data];
Subscript[𝒟, HighRoad] = EmpiricalDistribution[Cases[nd, {eg_ /; eg > medEG, t_} :> t]];
Subscript[𝒟, LowRoad] = EmpiricalDistribution[Cases[nd, {eg_ /; eg <= medEG, t_} :> t]];

Wolfram Language code:

Plot[{CDF[Subscript[𝒟, HighRoad], Quantity[x, "Minutes"]], CDF[Subscript[𝒟, LowRoad], Quantity[x, "Minutes"]]}, {x, 0, 250}, Exclusions -> None, Filling -> Axis, PlotRange -> {0, 1}, AxesLabel -> {"min"}, PlotLegends -> {"SubscriptBox[𝒟, HighRoad]", "SubscriptBox[𝒟, LowRoad]"}]

看上去走低路速度较快：

Wolfram Language code: {Median[Subscript[𝒟, HighRoad]], Median[Subscript[𝒟, LowRoad]]}

相较走低路的运动员，走高路运动员的比赛时间波动程度更大：

Wolfram Language code: {QuartileDeviation[Subscript[𝒟, HighRoad]], QuartileDeviation[Subscript[𝒟, LowRoad]]}

国立卫生研究院估计有 2% 的人口患有某种疾病. 针对这种疾病的检验表明该疾病出现的概率为 95%，其中假阳性的比例为 5%. 假设某病人经检验发现结果为阳性，求该病人的确患有该疾病的概率：

Wolfram Language code:

sick = {1, 1, 0, 0};
positive = {1, 0, 1, 0};

Wolfram Language code: 𝒟 = EmpiricalDistribution[{p1, p2, p3, p4} -> Transpose[{sick, positive}]]

基于给定的信息，有关未知概率的方程：

Wolfram Language code:

eqs = {Probability[s == 1, {s, p}𝒟] == (2/100), Probability[p == 1s == 1, {s, p}𝒟] == (95/100), Probability[p == 1s == 0, {s, p}𝒟] == (5/100)}

假定概率之和为1，求解以下方程：

Wolfram Language code: sol = Solve[eqs~Join~{p1 + p2 + p3 + p4 == 1}, {p1, p2, p3, p4}]//N

如果检验结果为阳性，某病人患有该疾病的概率是：

Wolfram Language code: Probability[s == 1p == 1, {s, p}𝒟] /. sol[[1]]

随机选择21个学生参加一个新组织的阅读辅导项目. 另外，有23个学生作为对照小组接受传统的阅读辅导. 对这两个小组分别记录学生的阅读测验得分. 对这些得分执行一次基于排列的检验，以确定新组织的阅读辅导项目是否成功：

Wolfram Language code:

treatment = {24, 61, 59, 46, 43, 53, 43, 44, 52, 43, 57, 49, 58, 67, 62, 57, 56, 33, 71, 49, 54};
control = {42, 33, 46, 37, 62, 20, 43, 41, 10, 42, 53, 48, 55, 19, 17, 55, 37, 85, 26, 54, 60, 28, 42};

两个小组之间的测验得分的平均差值可以作为检验统计量：

Wolfram Language code: testStatistic = Mean[treatment] - Mean[control]//N

通过对小组随即排列，模拟检验统计量的零分布：

Wolfram Language code:

permute[treat_, cont_, nPerm_] := Table[With[{sample = RandomSample[Join[treat, cont]]}, Mean[Take[sample, Length[treat]] - Mean[Drop[sample, Length[treat]]]]], {nPerm}]

Wolfram Language code: 𝒟0 = permute[treatment, control, 25000];

Wolfram Language code: Histogram[𝒟0, Automatic, "PDF"]

在 5% 显著性水平下，下面证明了新组织的阅读辅导项目的确会带来不同的效果：

Wolfram Language code: empP[tstat_, 𝒟0_] := N@Probability[x ≥ tstat, xEmpiricalDistribution[𝒟0]]

Wolfram Language code: empP[testStatistic, 𝒟0]

LocationTest 可用于直接进行假设检验：

Wolfram Language code: LocationTest[{treatment, control}, AlternativeHypothesis -> "Greater"]

属性和关系 (8)

由经验分布生成的随机数是自助抽样样本：

Wolfram Language code: dist = EmpiricalDistribution[Range[10]];

Wolfram Language code: ListPlot[RandomVariate[dist, 1000]]

EmpiricalDistribution 是底层函数的一致估计量：

Wolfram Language code: data = Table[RandomReal[d = NormalDistribution[], i], {i, {5, 10, 50, 100, 500, 1000}}];

Wolfram Language code: dists = EmpiricalDistribution /@ data;

Wolfram Language code: Table[Plot[{CDF[i, x], CDF[d, x]}, {x, -4, 4}, PlotLabel -> Row[{i[[4]], " points"}], Exclusions -> None], {i, dists}]

矩和它们对于数据的矩的相等性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10];

Wolfram Language code: 𝒟 = EmpiricalDistribution[data];

Wolfram Language code: Mean[𝒟] == Mean[data]

Wolfram Language code: Moment[𝒟, r] == Moment[data, r]//Simplify

对经验分布使用总体方差，而非样本方差：

Wolfram Language code: Variance[𝒟] == Variance[data]

Wolfram Language code: CentralMoment[𝒟, 2] == Variance[𝒟]

分位数等价于直接应用于数据的 Quantile：

Wolfram Language code: 𝒟 = EmpiricalDistribution[data = RandomVariate[NormalDistribution[], 7]];

Wolfram Language code: rng = Range[0, 1, 1 / 99];

Wolfram Language code: Total[Quantile[𝒟, rng] / Quantile[data, rng]] / 100

EmpiricalDistribution 等价于无删截的 SurvivalDistribution：

Wolfram Language code: data = Range[100];

Wolfram Language code: d1 = EmpiricalDistribution[data];

Wolfram Language code: d2 = SurvivalDistribution[data];

Wolfram Language code: Total[Table[PDF[d1, x] - PDF[d2, x], {x, DistributionDomain[d1]}]]

将数据值的交集用作 HistogramDistribution 的箱分界符：

Wolfram Language code: data = {1, 1, 2, 2, 3, 4, 4, 4, 5, 6, 7};

Wolfram Language code:

𝒟1 = HistogramDistribution[data, {Join[Union[data], {Max[data] + 1}]}];
𝒟2 = EmpiricalDistribution[data];

生成的概率密度函数是 EmpiricalDistribution 的概率密度函数的零阶插值：

Wolfram Language code: Show[DiscretePlot[PDF[𝒟2, x], {x, data}, PlotStyle -> Green], Plot[PDF[𝒟1, x], {x, 0, 9}, Exclusions -> None]]

将 N 应用于精确数据可以减少内存消耗：

Wolfram Language code: data = RandomChoice[{π, E, Sin[5], Sqrt[2], 1}, 10 ^ 4];

Wolfram Language code: c = RandomChoice[Range[500], 10 ^ 4];

Wolfram Language code:

𝒟 = EmpiricalDistribution[c data];
Subscript[𝒟, Num] = EmpiricalDistribution[N[c data]];

Wolfram Language code: {ByteCount[𝒟], ByteCount[Subscript[𝒟, Num]]}

累积分布函数是相等的：

Wolfram Language code: Table[Plot[CDF[i, x], {x, 0, 10}, Exclusions -> None], {i, {𝒟, Subscript[𝒟, Num]}}]

积分上的 EmpiricalDistribution 可以使用 ProbabilityDistribution 指定:

Wolfram Language code: edist = EmpiricalDistribution[{1 / 6, 1 / 3, 1 / 3, 1 / 6} -> {1, 2, 3, 4}]

Wolfram Language code: pdist = ProbabilityDistribution[(1/6)Boole[x == 1 || x == 4] + (1/3)Boole[x == 2 || x == 3], {x, 1, 4, 1}]

Wolfram Language code: PDF[edist, x] == PDF[pdist, x]//Simplify

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

EmpiricalDistribution

更多信息

范例

基本范例 (2)

范围 (19)

基本使用 (10)

分布属性 (9)

应用 (8)

属性和关系 (8)

文本

CMS

APA

BibTeX

BibLaTeX

EmpiricalDistribution

更多信息

范例

基本范例 (2)

范围 (19)

基本使用 (10)

分布属性 (9)

应用 (8)

属性和关系 (8)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX