Wolfram言語＆システムドキュメントセンター

EntityInstance

EntityInstance[entity,qualval]

限定子 qual の値が val である実体を表す．

EntityInstance[entity,{qual₁val₁,qual₂val₂,…}]

限定子 qual_iの値が val_iである実体を表す．

EntityInstance[entity,quantity]

quantity で限定された実体を表す．

詳細

Entity式は，インターフェースを使って作ることができる．
限定詞 qual は，entity のEntityPropertyの特性限定詞，QuantityVariable，あるいはFunctionの引数でよい．
entity[property]が qual に等しいパラメータを持つFunction[params,body]を返す場合は，関連付けられた値が body に代入され，params から qual が削除される．パラメータが残っていなければ，Functionラッパーが取り除かれる．

例題

すべて開くすべて閉じる

例 (4)

1950年のアイルランドを表す：

Wolfram Language code: EntityInstance[Entity["Country", "Ireland"], "Date" -> 1950]

当時の人口を返す：

Wolfram Language code: EntityValue[%, "Population"]

純関数として返された特性の値を指定する：

Wolfram Language code: Entity["Solid", "HalfTorus"]["SurfaceArea"]

Wolfram Language code:

EntityValue[
	EntityInstance[Entity["Solid", "HalfTorus"], { -> 1,  -> 2}], 
	"SurfaceArea"
	]

複数の特性について同じ値を指定する：

Wolfram Language code:

EntityValue[
	EntityInstance[Entity["Solid", "Ball"],  -> 1], 
	{"SurfaceArea", "Volume"}
	]

数量変数を含む特性の値を指定する：

Wolfram Language code:

EntityValue[
	EntityInstance[Entity["PhysicalSystem", "HarmonicOscillator1D"], ω -> Quantity[1, "Radians"/"Seconds"]], 
	{"Lagrangian", "EquationsOfMotion"}, 
	"PropertyAssociation"
	]

物質の質量を指定する：

Wolfram Language code: EntityValue[EntityInstance[Entity["Chemical", "MolecularOxygen"], Quantity[1, "Kilograms"]], "AbsoluteVolume"]

スコープ (8)

特性の限定子 (2)

特性の内側に限定子を使って1980年における特性を指定する：

Wolfram Language code:

EntityValue[Entity["Country", "Spain"], {EntityProperty["Country", "Population", "Date" -> 1980], EntityProperty["Country", "PopulationGrowth", "Date" -> 1980]}]

これは，特性が限定されていない実体の例を使うことに等しい：

Wolfram Language code:

EntityValue[EntityInstance[Entity["Country", "Spain"], "Date" -> 1980], {EntityProperty["Country", "Population"], EntityProperty["Country", "PopulationGrowth"]}]

適用できない限定子は静かに無視される：

Wolfram Language code: EntityValue[EntityInstance[Entity["Country", "Spain"], "Date" -> 1980], "Name"]

日付 (1)

実体の例における日付の限定子は，規則（この場合は単一の限定子）として指定することができる：

Wolfram Language code: EntityValue[EntityInstance[Entity["Country", "Ireland"], "Date" -> 1950], "Population"]

規則のリストとして：

Wolfram Language code: EntityValue[EntityInstance[Entity["Country", "Ireland"], {"Date" -> 1950}], "Population"]

あるいはDateObjectとして：

Wolfram Language code: EntityValue[EntityInstance[Entity["Country", "Ireland"], DateObject[{1950}]], "Population"]

純関数の引数 (1)

立体の特性に現れる変数を得る：

Wolfram Language code: Entity["Solid", "HalfTorus"][EntityProperty["Solid", "Variables"]]

この特性は変数の純関数である：

Wolfram Language code:

Entity["Solid", "HalfTorus"][{EntityProperty["Solid", "Centroid"], EntityProperty["Solid", "SurfaceArea"], EntityProperty["Solid", "Inequalities"]}]

cが残りの変数の関数を得るように指定する：

Wolfram Language code:

EntityValue[EntityInstance[Entity["Solid", "HalfTorus"], { -> 10}], {EntityProperty["Solid", "Centroid"], EntityProperty["Solid", "SurfaceArea"], EntityProperty["Solid", "Inequalities"]}]

すべての変数を指定する：

Wolfram Language code:

EntityValue[EntityInstance[Entity["Solid", "HalfTorus"], { -> 10,  -> 2}], {EntityProperty["Solid", "Centroid"], EntityProperty["Solid", "SurfaceArea"], EntityProperty["Solid", "Inequalities"]}]

数量の変数値 (1)

調和振動子が従属する変数を得る：

Wolfram Language code: Entity["PhysicalSystem", "HarmonicOscillator1D"][EntityProperty["PhysicalSystem", "SystemVariables"]]

数量の変数を指定する：

Wolfram Language code:

EntityValue[EntityInstance[Entity["PhysicalSystem", "HarmonicOscillator1D"], {QuantityVariable["m", "Mass"] -> 1, QuantityVariable["ω", "AngularFrequency"] -> 1}], "EquationsOfMotionSolution"]

数量 (2)

1モルの水を指定する：

Wolfram Language code: EntityInstance[Entity["Chemical", "Water"], Quantity[1, "Moles"]]

その質量を得る：

Wolfram Language code: EntityValue[%, "AbsoluteMass"]

モル質量を使って質量を計算する：

Wolfram Language code: Entity["Chemical", "Water"][EntityProperty["Chemical", "MolarMass"]]Quantity[1, "Moles"]

結果は同じである：

Wolfram Language code: % == %%

50グラムのクロワッサンを指定する：

Wolfram Language code:

EntityInstance[
	Entity["Food", {
	"FoodType" -> Entity["FoodType", "Croissant"], 
	"RelativeWaterContent" -> Quantity[Interval[{0, 0.5}], "Grams" / "Grams"]
	}], 
	Quantity[50, "Grams"]
	]

ビタミンAの絶対含有量を得る：

Wolfram Language code: %["AbsoluteVitaminAContent"]

実体ストア (1)

「shape」実体を登録する：

Wolfram Language code:

EntityRegister[EntityStore["shape" -> <|
	"Entities" -> <|
	"rectangle" -> <|"variables" -> {, }, "area" -> Function[{, },  * ]|>, 
	"disk" -> <|"variables" -> {}, "area" -> Function[, π *  ^ 2]|>
	|>
	|>]]

半径2メートルの円板を表す：

Wolfram Language code: EntityInstance[Entity["shape", "disk"],  -> Quantity[2, "Meters"]]

面積を求める：

Wolfram Language code: %["area"]

1辺が指定された長方形：

Wolfram Language code: EntityInstance[Entity["shape", "rectangle"],  -> Quantity[9, "Centimeters"]]

この面積はもう一方の辺のFunctionとして与えられる：

Wolfram Language code: %["area"]

「shape」実体の登録を解除する：

Wolfram Language code: EntityUnregister["shape"]

特性と関係 (1)

未知あるいは適用不可能な例を含む式は静かに無視される：

Wolfram Language code:

EntityValue[
	Entity["Solid", "HalfTorus"], 
	"SurfaceArea"
	]

Wolfram Language code:

EntityValue[
	EntityInstance[Entity["Solid", "HalfTorus"], {"blah" -> 2}], 
	"SurfaceArea"
	]

複数の例を含む式は，適用可能なものだけに適用される：

Wolfram Language code:

EntityValue[
	EntityInstance[Entity["Solid", "HalfTorus"], {"blah" -> 2,  -> 1}], 
	"SurfaceArea"
	]

おもしろい例題 (1)

二重振子の動きの方程式を得る：

Wolfram Language code:

eqn = EntityValue[
	EntityInstance[Entity["PhysicalSystem", "DoublePendulum"], {Subscript[l, 1] -> 1, Subscript[m, 1] -> 1, Subscript[l, 2] -> 1, Subscript[m, 2] -> 1, g -> 9.81}], 
	"EquationsOfMotion"
	]

初期条件を選ぶ：

Wolfram Language code:

theta10 = 0.7;
theta20 = 0;

方程式を解く：

Wolfram Language code:

{theta1sol, theta2sol} = NDSolveValue[
	Join[
	eqn /. {Subscript[θ, 1] -> theta1, Subscript[θ, 2] -> theta2}, 
	{
	theta1[0] == theta10, 
	theta1'[0] == 0, 
	theta2[0] == theta20, 
	theta2'[0] == 0
	}
	], 
	{theta1, theta2}, 
	{t, 0, 10}
	]

2本の腕の時間進化をプロットする：

Wolfram Language code: Plot[{theta1sol[t], theta2sol[t]}, {t, 0, 10}]

二重振子をアニメーション化する：

Wolfram Language code:

Animate[
	Graphics[{
	Disk[{0, 0}, 0.1], 
	With[{p1 = RotationMatrix[theta1sol[t]].{0, -1}}, {
	Line[{{0, 0}, p1}], 
	Disk[p1, 0.1], 
	With[{p2 = p1 + RotationMatrix[theta2sol[t]].{0, -1}}, {
	Line[{p1, p2}], 
	Disk[p2, 0.1]
	}]
	}]
	}, 
	PlotRange -> {{-3, 3}, {-3, 1}}
	], 
	{t, 0, 10}, SaveDefinitions -> True
	]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

EntityInstance

詳細

例題

例 (4)

スコープ (8)

特性の限定子 (2)

日付 (1)

純関数の引数 (1)

数量の変数値 (1)

数量 (2)

実体ストア (1)

特性と関係 (1)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

EntityInstance

詳細

例題

例 (4)

スコープ (8)

特性の限定子 (2)

日付 (1)

純関数の引数 (1)

数量の変数値 (1)

数量 (2)

実体ストア (1)

特性と関係 (1)

おもしろい例題 (1)

関連項目

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX