WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

EntityProperty[type,pname]

EntityValueで使うために，pname で識別された特性を表す．

EntityProperty[class,pname]

計算された実体クラス class によって導入された特性を表す．

EntityProperty[type,pname,{qual1val1,qual2val2,…}]

限定子の規則 qualivaliによって変更された特性を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

EntityProperty   

実体タイプのリスト »

EntityProperty[type,pname]

EntityValueで使うために，pname で識別された特性を表す．

EntityProperty[class,pname]

計算された実体クラス class によって導入された特性を表す．

EntityProperty[type,pname,{qual1val1,qual2val2,…}]

限定子の規則 qualivaliによって変更された特性を表す．

詳細とオプション

  • 限定子がない特性について言及する際は，EntityPropertyのラッパーは，一般に，使っても使わなくてもよい．
  • EntityProperty[type,name]のタイプは，組込みの実体タイプまたはEntityRegisterで登録されたEntityStoreで指定されたタイプである．
  • type は"type"または"type""child1""child2"…の形式でよい．
  • EntityProperties[type]を使って指定タイプの特性リストを得る．
  • Entityオブジェクトの特性値はEntity[…][EntityProperty[…]]またはEntityProperty[…][Entity[…]]を使って得ることができる．
  • EntityProperty[…]["prop"]を使って特性のメタデータを検索することができる．メタデータ特性には以下が含まれる．
  • "Qualifiers"特性に使用可能な限定子のリスト
    "QualifierValues"各限定子に与えられる可能な値のリスト
    "Label"特性のラベル
    "Definition"特性のテキストによる詳細な定義
    "Source"特性のソース情報
    "PhysicalQuantity"実体 - 特性値に関連付けられた物理量
    "Unit"実体 - 特性値に関連付けられた共通単位
  • 限定子の値がAutomaticのときは，適用可能な形式の値が使えることを意味する．例えば，"Date"限定子の場合は，適切な日付または日付範囲が含まれる．
  • ExtendedEntityClassおよびAggregatedEntityClassは新たな特性を導入することができる．新たに導入された特性についてのEntityPropertyの第1引数はその特性の実体クラスである．
  • EntityProperty式のInformationは，その式に関連付けられたEntityTypeNameによって異なる特性を与える．

例題

すべて開く すべて閉じる

例  (3)

"Aircraft"タイプの特性は巡航速度を表す：

Wolfram Language code: EntityProperty["Aircraft", "CruiseSpeed"]

コンコルドの巡航速度を取り出す：

Wolfram Language code: Entity["Aircraft", "Concorde"][EntityProperty["Aircraft", "CruiseSpeed"]]

アメリカ合衆国の人口を求める：

Wolfram Language code: Entity["Country", "UnitedStates"]["Population"]

1980年の人口を求める：

Wolfram Language code: Entity["Country", "UnitedStates"][EntityProperty["Country", "Population", {"Date" -> 1980}]]

Datedを使って同じクエリを行う：

Wolfram Language code: Entity["Country", "UnitedStates"][Dated["Population", 1980]]

分子量の"Unit"を求める：

Wolfram Language code: EntityProperty["Chemical", "MolecularMass"]["Unit"]

を使ってカフェインの分子量について尋ねる：

Wolfram Language code: ["molecular mass of caffeine"]

スコープ  (2)

都市の人口特性について使用可能な限定子を得る：

Wolfram Language code: EntityProperty["City", "Population"]["Qualifiers"]

"Age"限定子の可能な値を得る：

Wolfram Language code: Lookup[EntityProperty["City", "Population"]["QualifierValues"], "Age"]

"Age"限定子の値を"Adult"にして使う：

Wolfram Language code: EntityValue[ Entity["City", {"Boston", "Massachusetts", "UnitedStates"}], EntityProperty["City", "Population", {"Age" -> "Adult"}] ]

EntityPropertyは，特性についてより限定的な限定子を持つことができる：

Wolfram Language code: population = Hold[["population of spain in 1960"]]

以下では，"Date"限定子が特定の年を指定している：

Wolfram Language code: InputForm[population]

アプリケーション  (1)

1900年から2010年までの5年ごとの日付範囲を作る：

Wolfram Language code: years = DateRange[DateObject[{1900}], DateObject[{2010}], Quantity[5, "Years"]]

該当年のオランダの人口を求める：

Wolfram Language code: populations = Entity["Country", "Netherlands"][Map[EntityProperty["Country", "Population", {"Date" -> #}]&, years]]

このデータを使って日付プロットを作る：

Wolfram Language code: DateListPlot[Thread[{years, populations}], Filling -> Axis, PlotLabel -> "Population over time", PlotTheme -> "Scientific"]

特性と関係  (1)

以下ではEntityPropertyラッパーは任意であり，特性名を使うだけで十分である：

Wolfram Language code: Entity["Country", "UnitedStates"]["Population"] === Entity["Country", "UnitedStates"][EntityProperty["Country", "Population"]]
Wolfram Language code: Entity["Mountain", "MountEverest"]["Elevation"] === Entity["Mountain", "MountEverest"][EntityProperty["Mountain", "Elevation"]]

考えられる問題  (1)

一度に1つの特性で実体を呼び出すのは特性の単一のリストで呼び出すのよりも遅い：

Wolfram Language code: Table[ Entity["Country", "SouthKorea"][EntityProperty["Country", "Population", {"Date" -> DateObject[{year}]}]], {year, Range[1900, 2010, 10]}]//AbsoluteTiming

実体特性が1回の呼出しでリクエストされているので，以下の形式の方が速い：

Wolfram Language code: Entity["Country", "Chile"][Table[EntityProperty["Country", "Population", {"Date" -> DateObject[{year}]}], {year, Range[1900, 2010, 10]}]]//AbsoluteTiming

実体とその特性はキャッシュされるので，続く呼出しは格段に速くなる：

Wolfram Language code: Entity["Country", "Chile"][Table[EntityProperty["Country", "Population", {"Date" -> DateObject[{year}]}], {year, Range[1900, 2010, 10]}]]//AbsoluteTiming
Wolfram Research (2014), EntityProperty, Wolfram言語関数， https://reference.wolfram.com/language/ref/EntityProperty.html （2019年に更新）.

テキスト

Wolfram Research (2014), EntityProperty, Wolfram言語関数， https://reference.wolfram.com/language/ref/EntityProperty.html （2019年に更新）.

CMS

Wolfram Language. 2014. "EntityProperty." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/EntityProperty.html.

APA

Wolfram Language. (2014). EntityProperty. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/EntityProperty.html

BibTeX

@misc{reference.wolfram_2026_entityproperty, author="Wolfram Research", title="{EntityProperty}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/EntityProperty.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_entityproperty, organization={Wolfram Research}, title={EntityProperty}, year={2019}, url={https://reference.wolfram.com/language/ref/EntityProperty.html}, note=[Accessed: 07-September-2026]}