WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Erf[z]

誤差関数を返す．

Erf[z0,z1]

一般化された誤差関数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Erf

Erf[z]

誤差関数を返す．

Erf[z0,z1]

一般化された誤差関数を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • Erf[z]はガウス分布の積分 を与える．
  • Erf[z0,z1]は， で与えられる．
  • Erf[z]は不連続な分枝切断線を持たない z に関する整関数である．
  • 特別な引数の場合，Erfは，自動的に厳密値を計算する．
  • Erfは任意の数値精度で評価できる．
  • Erfは自動的にリストに縫い込まれる．
  • ErfはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: Erf[0.95]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Erf[x], {x, -5, 5}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Erf[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[Erf[x], {x, 0, 10}]

Infinityにおける級数展開：

Wolfram Language code: Series[Erf[x], {x, ∞, 5}]//Normal

スコープ  (40)

数値評価  (6)

数値的に評価する：

Wolfram Language code: {Erf[1.5], Erf[1.5, 2]}

高精度で評価する：

Wolfram Language code: N[Erf[3 / 2], 50]

出力精度は入力精度に従う：

Wolfram Language code: Erf[1.5000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: Erf[1.5 - I]

Erfを高精度で効率よく評価する：

Wolfram Language code: Erf[1.2`500]//Timing
Wolfram Language code: Erf[1.2`5000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Erf[Interval[{-2.1, -1.9}]]
Wolfram Language code: Erf[2, Interval[{1.4, 1.5}]]
Wolfram Language code: Erf[CenteredInterval[2, 1 / 2]]
Wolfram Language code: Erf[1, CenteredInterval[2, 1 / 3]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Erf[ Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: Erf[{{0 , I π / 2}, {I π / 2, 0}}]

MatrixFunctionを使って行列のErf関数を計算することもできる：

Wolfram Language code: MatrixFunction[Erf, {{0, I π / 2}, {I π / 2, 0}}]

特定の値  (3)

簡単な厳密値は自動的に生成される：

Wolfram Language code: Erf[0]

無限大における値：

Wolfram Language code: Erf[{Infinity, -Infinity, I Infinity, -I Infinity}]
Wolfram Language code: Erf[-Infinity, Infinity]

Erfの零点を求める：

Wolfram Language code: xzero = Solve[Erf[x] == 0 && -1 < x < 1, x][[1, 1, 2]]
Wolfram Language code: Plot[Erf[x], {x, -1.5, 1.5}, Epilog -> Style[Point[{xzero, Erf[xzero]}], PointSize[Large], Red]]

可視化  (2)

Erf関数をプロットする：

Wolfram Language code: Plot[Erf[x], {x, -3, 3}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Erf[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Erf[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

関数の特性  (10)

Erfはすべての実数値と虚数値について定義される：

Wolfram Language code: FunctionDomain[Erf[x], x]
Wolfram Language code: FunctionDomain[Erf[z], z, Complexes]

Erfは–1から1までのすべての実数値を取る：

Wolfram Language code: FunctionRange[Erf[x], x, y]

Erfは奇関数である：

Wolfram Language code: Erf[-x] == -Erf[x]

Erfは鏡特性erf(TemplateBox[{z}, Conjugate])=TemplateBox[{{erf, (, z, )}}, Conjugate]を有する：

Wolfram Language code: FullSimplify[Erf[Conjugate[z]] == Conjugate[Erf[z]]]

Erfは x の解析関数である：

Wolfram Language code: FunctionAnalytic[Erf[x], x]

特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Erf[x], x]
Wolfram Language code: FunctionDiscontinuities[Erf[x], x]

Erfは非減少である：

Wolfram Language code: FunctionMonotonicity[Erf[x], x]

Erfは単射である：

Wolfram Language code: FunctionInjective[Erf[x], x]
Wolfram Language code: Plot[{Erf[x], .5}, {x, -5, 5}]

Erfは全射ではない：

Wolfram Language code: FunctionSurjective[Erf[x], x]
Wolfram Language code: Plot[{Erf[x], -2}, {x, -10, 10}]

Erfは非負でも非正でもない：

Wolfram Language code: FunctionSign[Erf[x], x]

Erfは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Erf[x], x]

微分  (3)

一次導関数：

Wolfram Language code: D[Erf[x], x]

高次導関数：

Wolfram Language code: Table[D[Erf[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

n 次導関数の式：

Wolfram Language code: D[Erf[x], {x, n}]

積分  (3)

Erfの不定積分：

Wolfram Language code: Integrate[Erf[x], x]

原点を中心とした区間における奇関数の定積分は0である：

Wolfram Language code: Integrate[Erf[x], {x, -4, 4}]

その他の積分例：

Wolfram Language code: Integrate[z^αErf[z^β], z]
Wolfram Language code: Integrate[z Exp[z]Erf[z], z]
Wolfram Language code: Integrate[1 - Erf[z]^2, {z, -Infinity, Infinity}]

級数展開  (4)

Erfのテイラー(Taylor)展開：

Wolfram Language code: Series[Erf[x], {x, 0, 7}]

の周りのErfの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[Erf[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{Erf[x], terms}, {x, -3, 3}]

Erfの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Erf[x], {x, 0, n}]

Erfの漸近展開：

Wolfram Language code: Series[Erf[x], {x, Infinity, 1}]//Normal

Erfはベキ級数に適用できる：

Wolfram Language code: Erf[Sin[x] + O[x] ^ 10]

積分変換  (2)

FourierTransformを使ってErfのフーリエ(Fourier)変換を計算する：

Wolfram Language code: FourierTransform[Erf[t], t, ω]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Erf[t], t, s]

関数の恒等式と簡約  (3)

誤差関数の積分定義：

Wolfram Language code: (2/Sqrt[π])Integrate[Exp[-t^2], {t, 0, x}]

基本的な算術演算を含む引数：

Wolfram Language code: Erf[I z]
Wolfram Language code: Erf[Sqrt[z^2]]//FunctionExpand

2引数の形は差分を与える：

Wolfram Language code: Erf[x, y]//FunctionExpand

関数表現  (4)

不完全Gammaによる誤差関数：

Wolfram Language code: (Sqrt[z^2] /z)(1 - (1/Sqrt[π])Gamma[(1/2), z^2])//FullSimplify

MeijerGReduceを使ってMeijerGによって表す：

Wolfram Language code: MeijerGReduce[Erf[x], x]
Wolfram Language code: Activate[%]

ErfはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Erf[x], x]

TraditionalFormによる表示：

Wolfram Language code: Erf[α]//TraditionalForm

一般化と拡張  (1)

2引数の形は差分を与える：

Wolfram Language code: Erf[z, w]//FunctionExpand

アプリケーション  (3)

NormalDistributionのCDFを誤差関数によって表す：

Wolfram Language code: CDF[NormalDistribution[0, σ], x]//FunctionExpand
Wolfram Language code: Plot[% /. σ -> 2, {x, -10, 10}]

正規確率変数の値が-n σとn σの間になる累積確率：

Wolfram Language code: Table[CDF[NormalDistribution[0, σ], n σ] - CDF[NormalDistribution[0, σ], -n σ], {n, 4}] //N

区分定数初期条件の熱伝導方程式の解：

Wolfram Language code: temp[x_, t_] := With[{η = (1/2 Sqrt[t])}, (Erf[(x + 1)η] - Erf[(x - 1)η]) / 2]

解が熱伝導方程式を満足するかどうか検証する：

Wolfram Language code: D[temp[x, t], t] == D[temp[x, t], x, x]// Simplify

異なる時間についての解をプロットする：

Wolfram Language code: Plot[Evaluate[{temp[x, 0.01], temp[x, 0.2], temp[x, 0.6], temp[x, 1.5]}], {x, -4, 4}]

超過損失再保険契約では，請求額が留保レベルと呼ばれる固定金額を超えた場合にのみ，保険会社と再保険会社の間で請求額が共有される．それ以外の場合，保険会社は保険金を全額支払う．保険金請求がパラメータ と で対数正規分布に従う場合に，保持レベル に対して保険会社と再保険会社が支払う金額 と の期待値を計算する．予想される保険会社の保険金支払額を求める：

Wolfram Language code: insurerPayouts = TransformedDistribution[Min[x, m], xLogNormalDistribution[μ, σ], Assumptions -> m > 0];
Wolfram Language code: Expectation[y, yinsurerPayouts]

再保険会社からの保険会社への期待支払額を求める：

Wolfram Language code: reinsurerPayouts = TransformedDistribution[Max[0, x - m], xLogNormalDistribution[μ, σ], Assumptions -> m > 0];
Wolfram Language code: Expectation[z, zreinsurerPayouts]

特性と関係  (3)

逆関数で構築する：

Wolfram Language code: {Erf[InverseErf[z]], InverseErf[Erf[z]]}
Wolfram Language code: PowerExpand[%]

超越方程式を解く：

Wolfram Language code: Solve[Erf[x] == 1 / 2, x]

Erfは多くの数学関数の特殊形に見られる：

Wolfram Language code: { GammaRegularized[1 / 2, z^2], HypergeometricU[1 / 2, 1 / 2, z^2], MeijerG[{{1 / 2}, {}}, {{0}, {-1 / 2}}, z^2]}//FunctionExpand

考えられる問題  (3)

大きい引数については，中間の値がアンダーフローすることがある：

Wolfram Language code: Erf[-2 10 ^ 8 - 10. ^ 3 I]

大きい実部の引数についての誤差関数は1に非常に近くなることがある：

Wolfram Language code: Erf[30.`20 + 10 ^ -1 I]

非常に大きい引数は未評価の結果を返すことがある：

Wolfram Language code: Erf[10. ^ 100 I]

おもしろい例題  (2)

クロソイド曲線をプロットする：

Wolfram Language code: ParametricPlot[ReIm[Erf[t + I t]], {t, -5, 5}, Axes -> None]

部分分子が連続する整数である連分数：

Wolfram Language code: With[{n = 12}, 1 / (1 + ContinuedFractionK[HoldForm[k], 1, {k, n}])]

その極限はErfで表すことができる：

Wolfram Language code: {ReleaseHold //@ %, Sqrt[(π E/2)] (1 - Erf[(1/Sqrt[2])])} //N
Wolfram Research (1988), Erf, Wolfram言語関数， https://reference.wolfram.com/language/ref/Erf.html （2022年に更新）.

テキスト

Wolfram Research (1988), Erf, Wolfram言語関数， https://reference.wolfram.com/language/ref/Erf.html （2022年に更新）.

CMS

Wolfram Language. 1988. "Erf." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/Erf.html.

APA

Wolfram Language. (1988). Erf. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Erf.html

BibTeX

@misc{reference.wolfram_2026_erf, author="Wolfram Research", title="{Erf}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Erf.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_erf, organization={Wolfram Research}, title={Erf}, year={2022}, url={https://reference.wolfram.com/language/ref/Erf.html}, note=[Accessed: 10-September-2026]}