Wolfram 语言与系统参考资料中心

Erf

Erf[z]

给出误差函数 .

Erf[z₀,z₁]

给出广义误差函数 .

范例

打开所有单元关闭所有单元

基本范例 (5)

数值计算：

Wolfram Language code: Erf[0.95]

在实数的子集上绘图：

Wolfram Language code: Plot[Erf[x], {x, -5, 5}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[Erf[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点处的级数展开式：

Wolfram Language code: Series[Erf[x], {x, 0, 10}]

Infinity 处的级数展开式：

Wolfram Language code: Series[Erf[x], {x, ∞, 5}]//Normal

范围 (40)

数值计算 (6)

数值计算：

Wolfram Language code: {Erf[1.5], Erf[1.5, 2]}

高精度计算：

Wolfram Language code: N[Erf[3 / 2], 50]

输出的精度和输入的精度一致：

Wolfram Language code: Erf[1.5000000000000000000000000000]

对复变量求值：

Wolfram Language code: Erf[1.5 - I]

在高精度条件下高效计算 Erf：

Wolfram Language code: Erf[1.2`500]//Timing

Wolfram Language code: Erf[1.2`5000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: Erf[Interval[{-2.1, -1.9}]]

Wolfram Language code: Erf[2, Interval[{1.4, 1.5}]]

Wolfram Language code: Erf[CenteredInterval[2, 1 / 2]]

Wolfram Language code: Erf[1, CenteredInterval[2, 1 / 3]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: Erf[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: Erf[{{0 , I π / 2}, {I π / 2, 0}}]

或用 MatrixFunction 计算矩阵形式的 Erf 函数：

Wolfram Language code: MatrixFunction[Erf, {{0, I π / 2}, {I π / 2, 0}}]

特殊值 (3)

自动生成简单精确值：

Wolfram Language code: Erf[0]

无穷处的值：

Wolfram Language code: Erf[{Infinity, -Infinity, I Infinity, -I Infinity}]

Wolfram Language code: Erf[-Infinity, Infinity]

求 Erf 的零点：

Wolfram Language code: xzero = Solve[Erf[x] == 0 && -1 < x < 1, x][[1, 1, 2]]

Wolfram Language code: Plot[Erf[x], {x, -1.5, 1.5}, Epilog -> Style[Point[{xzero, Erf[xzero]}], PointSize[Large], Red]]

可视化 (2)

绘制 Erf 函数：

Wolfram Language code: Plot[Erf[x], {x, -3, 3}]

绘制的实部：

Wolfram Language code: ComplexContourPlot[Re[Erf[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

绘制的虚部：

Wolfram Language code: ComplexContourPlot[Im[Erf[z]], {z, -2 - 2 I, 2 + 2 I}, Contours -> 20]

函数属性 (10)

Erf 是针对所有实数和复数定义的：

Wolfram Language code: FunctionDomain[Erf[x], x]

Wolfram Language code: FunctionDomain[Erf[z], z, Complexes]

Erf 的值域为 –1 和 1 之间的所有实数：

Wolfram Language code: FunctionRange[Erf[x], x, y]

Erf 是一个奇函数：

Wolfram Language code: Erf[-x] == -Erf[x]

Erf 具有镜像属性：

Wolfram Language code: FullSimplify[Erf[Conjugate[z]] == Conjugate[Erf[z]]]

Erf 是 x 的解析函数：

Wolfram Language code: FunctionAnalytic[Erf[x], x]

函数没有奇点和断点：

Wolfram Language code: FunctionSingularities[Erf[x], x]

Wolfram Language code: FunctionDiscontinuities[Erf[x], x]

Erf 非递减：

Wolfram Language code: FunctionMonotonicity[Erf[x], x]

Erf 是单射函数：

Wolfram Language code: FunctionInjective[Erf[x], x]

Wolfram Language code: Plot[{Erf[x], .5}, {x, -5, 5}]

Erf 不是满射函数：

Wolfram Language code: FunctionSurjective[Erf[x], x]

Wolfram Language code: Plot[{Erf[x], -2}, {x, -10, 10}]

Erf 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[Erf[x], x]

Erf 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[Erf[x], x]

微分 (3)

一阶导数：

Wolfram Language code: D[Erf[x], x]

高阶导数：

Wolfram Language code: Table[D[Erf[x], {x, n}], {n, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -4, 4}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[Erf[x], {x, n}]

积分 (3)

Erf 的不定积分：

Wolfram Language code: Integrate[Erf[x], x]

奇函数在以原点为中心的区间上的定积分为 0：

Wolfram Language code: Integrate[Erf[x], {x, -4, 4}]

更多积分：

Wolfram Language code: Integrate[z^αErf[z^β], z]

Wolfram Language code: Integrate[z Exp[z]Erf[z], z]

Wolfram Language code: Integrate[1 - Erf[z]^2, {z, -Infinity, Infinity}]

级数展开式 (4)

Erf 的泰勒展开式：

Wolfram Language code: Series[Erf[x], {x, 0, 7}]

绘制 Erf 在处的前三个近似式：

Wolfram Language code:

terms = Normal@Table[Series[Erf[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Erf[x], terms}, {x, -3, 3}]

Erf 级数展开式的通项:

Wolfram Language code: SeriesCoefficient[Erf[x], {x, 0, n}]

Erf 的渐近展开式：

Wolfram Language code: Series[Erf[x], {x, Infinity, 1}]//Normal

Erf 可被应用于幂级数：

Wolfram Language code: Erf[Sin[x] + O[x] ^ 10]

积分变换 (2)

用 FourierTransform 计算 Erf 的傅立叶变换：

Wolfram Language code: FourierTransform[Erf[t], t, ω]

LaplaceTransform：

Wolfram Language code: LaplaceTransform[Erf[t], t, s]

函数恒等式和化简 (3)

误差函数的积分定义：

Wolfram Language code: (2/Sqrt[π])Integrate[Exp[-t^2], {t, 0, x}]

含有基本算术运算的参数：

Wolfram Language code: Erf[I z]

Wolfram Language code: Erf[Sqrt[z^2]]//FunctionExpand

两个参数的形式会给出函数的差：

Wolfram Language code: Erf[x, y]//FunctionExpand

函数表示 (4)

用不完全 Gamma 函数表示的误差函数：

Wolfram Language code: (Sqrt[z^2] /z)(1 - (1/Sqrt[π])Gamma[(1/2), z^2])//FullSimplify

通过 MeijerGReduce 用 MeijerG 表示：

Wolfram Language code: MeijerGReduce[Erf[x], x]

Wolfram Language code: Activate[%]

Erf 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[Erf[x], x]

TraditionalForm 格式：

Wolfram Language code: Erf[α]//TraditionalForm

推广和延伸 (1)

两个自变量形式的差异：

Wolfram Language code: Erf[z, w]//FunctionExpand

应用 (3)

用错误函数表示 NormalDistribution 的 CDF：

Wolfram Language code: CDF[NormalDistribution[0, σ], x]//FunctionExpand

Wolfram Language code: Plot[% /. σ -> 2, {x, -10, 10}]

位于 -n σ 和 n σ 之间的正态随机变量值的累积概率：

Wolfram Language code: Table[CDF[NormalDistribution[0, σ], n σ] - CDF[NormalDistribution[0, σ], -n σ], {n, 4}] //N

求解关于分段常量初始条件的热方程：

Wolfram Language code: temp[x_, t_] := With[{η = (1/2 Sqrt[t])}, (Erf[(x + 1)η] - Erf[(x - 1)η]) / 2]

检验解是否满足热方程：

Wolfram Language code: D[temp[x, t], t] == D[temp[x, t], x, x]// Simplify

绘制不同时间的求解结果：

Wolfram Language code: Plot[Evaluate[{temp[x, 0.01], temp[x, 0.2], temp[x, 0.6], temp[x, 1.5]}], {x, -4, 4}]

根据超额损失再保险协议，只有当索赔额超过一个固定数额（称为自留额）时，保险人和再保险人之间才能共负索赔。否则，保险人全额支付赔款。如果索赔遵循参数为和的对数正态分布，计算自留额为时保险人和再保险人支付的金额和的期望值。求保险人的预期赔付率：

Wolfram Language code: insurerPayouts = TransformedDistribution[Min[x, m], xLogNormalDistribution[μ, σ], Assumptions -> m > 0];

Wolfram Language code: Expectation[y, yinsurerPayouts]

计算再保险人对保险人的预期赔付：

Wolfram Language code: reinsurerPayouts = TransformedDistribution[Max[0, x - m], xLogNormalDistribution[μ, σ], Assumptions -> m > 0];

Wolfram Language code: Expectation[z, zreinsurerPayouts]

属性和关系 (3)

用反函数组成：

Wolfram Language code: {Erf[InverseErf[z]], InverseErf[Erf[z]]}

Wolfram Language code: PowerExpand[%]

求解超越方程：

Wolfram Language code: Solve[Erf[x] == 1 / 2, x]

Erf 出现在许多数学函数的特例中：

Wolfram Language code:

{ GammaRegularized[1 / 2, z^2], HypergeometricU[1 / 2, 1 / 2, z^2], MeijerG[{{1 / 2}, {}}, {{0}, {-1 / 2}}, z^2]}//FunctionExpand

可能存在的问题 (3)

对于较大的参数，中间值可能会下溢：

Wolfram Language code: Erf[-2 10 ^ 8 - 10. ^ 3 I]

实部参数很大的误差函数非常接近 1：

Wolfram Language code: Erf[30.`20 + 10 ^ -1 I]

大型参数给出未计算的值：

Wolfram Language code: Erf[10. ^ 100 I]

巧妙范例 (2)

绘制回旋螺线：

Wolfram Language code: ParametricPlot[ReIm[Erf[t + I t]], {t, -5, 5}, Axes -> None]

部分分子为连续整数的连分数：

Wolfram Language code: With[{n = 12}, 1 / (1 + ContinuedFractionK[HoldForm[k], 1, {k, n}])]

极限可以 Erf 来表示：

Wolfram Language code: {ReleaseHold //@ %, Sqrt[(π E/2)] (1 - Erf[(1/Sqrt[2])])} //N

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Erf

更多信息

范例

基本范例 (5)

范围 (40)

数值计算 (6)

特殊值 (3)

可视化 (2)

函数属性 (10)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (2)

函数恒等式和化简 (3)

函数表示 (4)

推广和延伸 (1)

应用 (3)

属性和关系 (3)

可能存在的问题 (3)

巧妙范例 (2)

文本

CMS

APA

BibTeX

BibLaTeX

Erf

更多信息

范例

基本范例 (5)

范围 (40)

数值计算 (6)

特殊值 (3)

可视化 (2)

函数属性 (10)

微分 (3)

积分 (3)

级数展开式 (4)

积分变换 (2)

函数恒等式和化简 (3)

函数表示 (4)

推广和延伸 (1)

应用 (3)

属性和关系 (3)

可能存在的问题 (3)

巧妙范例 (2)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX