ExpIntegralEi

ExpIntegralEi[z]

指数積分関数を与える．

詳細

記号操作・数値操作の両方に適した数学関数である．
積分の主値を取ると， $TemplateBox[{z}, ExpIntegralEi]=-int_(-z)^inftye^(-t)/tdt$ となる．
ExpIntegralEi[z]は，複素 z 平面上，-∞〜0の範囲で不連続な分枝切断線を持つ．
特別な引数の場合，ExpIntegralEiは，自動的に厳密値を計算する．
ExpIntegralEiは任意の数値精度で評価できる．
ExpIntegralEiは，自動的にリストに縫い込まれる．
ExpIntegralEiはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開くすべて閉じる

例 (5)

数値的に評価する：

Wolfram Language code: ExpIntegralEi[1.8]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ExpIntegralEi[x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ExpIntegralEi[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点の分岐点付近での級数展開：

Wolfram Language code: Series[ExpIntegralEi[x], {x, 0, 5}, Assumptions -> x > 0]

Wolfram Language code: Series[ExpIntegralEi[x], {x, 0, 5}, Assumptions -> x < 0]

Infinityにおける級数展開：

Wolfram Language code: Series[ExpIntegralEi[ x], {x, ∞, 6}]//Normal

スコープ (37)

数値評価 (5)

高精度で数値的に評価する：

Wolfram Language code: N[ExpIntegralEi[2], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: ExpIntegralEi[2.0000000000000000000000]

ExpIntegralEiは複素数を入力として取ることができる：

Wolfram Language code: ExpIntegralEi[2. + I]

ExpIntegralEiを高精度で効率よく評価する：

Wolfram Language code: ExpIntegralEi[2`500]//Timing

Wolfram Language code: ExpIntegralEi[2`10000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: ExpIntegralEi[Interval[{1.1, 1.2}]]

Wolfram Language code: ExpIntegralEi[CenteredInterval[2, 1 / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: ExpIntegralEi[ Around[2, 0.01]]

配列の要素ごとの値を計算する：

Wolfram Language code: ExpIntegralEi[{{I π, I π / 2}, {0, -I }}]//FunctionExpand

MatrixFunctionを使って行列のExpIntegralEi関数を計算することもできる：

Wolfram Language code: MatrixFunction[ExpIntegralEi, {{I π, I π / 2}, {0, I}}]//FunctionExpand

特定の値 (3)

固定点における値：

Wolfram Language code: ExpIntegralEi[0]

無限大における値：

Wolfram Language code: ExpIntegralEi[{Infinity, -Infinity, I Infinity, -I Infinity}]

Wolfram Language code: ExpIntegralEi[ComplexInfinity]

ExpIntegralEiの零点を求める：

Wolfram Language code: xzero = Solve[ExpIntegralEi[x] == 0 && 0 < x < 0.5, x][[1, 1, 2]]//Quiet

Wolfram Language code: Plot[ExpIntegralEi[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, ExpIntegralEi[xzero]}], PointSize[Large], Red]]

可視化 (3)

ExpIntegralEi関数をプロットする：

Wolfram Language code: Plot[ExpIntegralEi[x], {x, -5, 5}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralEi[z]], {z, -10 - 10I, 10 + 10 I}, Contours -> 20]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralEi[z]], {z, -10 - 10I, 10 + 10 I}, Contours -> 20]

関数の特性 (10)

ExpIntegralEiは，0を除くすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ExpIntegralEi[x], x]

複素領域：

Wolfram Language code: FunctionDomain[ExpIntegralEi[z], z, Complexes]

ExpIntegralEiはすべての実数値を取る：

Wolfram Language code: FunctionRange[ExpIntegralEi[x], x, y]

ExpIntegralEiは鏡特性を有する：

Wolfram Language code: FullSimplify[ExpIntegralEi[Conjugate[z]] == Conjugate[ExpIntegralEi[z]]]

ExpIntegralEiは解析関数ではない：

Wolfram Language code: FunctionAnalytic[ExpIntegralEi[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[ExpIntegralEi[x], x]

ExpIntegralEiは実領域上で単調ではない：

Wolfram Language code: FunctionMonotonicity[ExpIntegralEi[x], x]

しかし，各半直線上では単調である：

Wolfram Language code: FunctionMonotonicity[{ExpIntegralEi[x], x > 0}, x]

Wolfram Language code: FunctionMonotonicity[{ExpIntegralEi[x], x < 0}, x]

ExpIntegralEiは単射ではない：

Wolfram Language code: FunctionInjective[ExpIntegralEi[x], x]

Wolfram Language code: Plot[{ExpIntegralEi[x], -1 / 2}, {x, -2, 2}]

ExpIntegralEiは全射である：

Wolfram Language code: FunctionSurjective[ExpIntegralEi[x], x]

Wolfram Language code: Plot[{ExpIntegralEi[x], 10}, {x, -10, 10}]

ExpIntegralEiは非負でも非正でもない：

Wolfram Language code: FunctionSign[{ExpIntegralEi[x], x ≠ 0}, x]

ExpIntegralEiは零点に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[ExpIntegralEi[x], x]

Wolfram Language code: FunctionDiscontinuities[ExpIntegralEi[x], x]

ExpIntegralEiは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[{ExpIntegralEi[x], x ≠ 0}, x]

しかし，負の実数上では凹である：

Wolfram Language code: FunctionConvexity[{ExpIntegralEi[x], x < 0}, x]

微分 (3)

一次導関数：

Wolfram Language code: D[ExpIntegralEi[x], x]

高次導関数：

Wolfram Language code: Table[D[ExpIntegralEi[x], {x, k}], {k, 1, 4}]

Wolfram Language code:

Plot[Evaluate[%], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[ExpIntegralEi[x], {x, n}]

積分 (3)

ExpIntegralEiの不定積分：

Wolfram Language code: Integrate[ExpIntegralEi[x], x]

ExpIntegralEiを含む関数の定積分：

Wolfram Language code: Integrate[Exp[-z x]ExpIntegralEi[x], {x, 0, Infinity}]

その他の積分例：

Wolfram Language code: Integrate[z^αExpIntegralEi[z^β], z]

Wolfram Language code: Integrate[Log[b x]ExpIntegralEi[a x], x]

級数展開 (3)

の周りのExpIntegralEiのテイラー(Taylor)展開：

Wolfram Language code: Series[ExpIntegralEi[x], {x, 1, 7}]

の周りのExpIntegralEiの最初の3つの近似をプロットする：

Wolfram Language code:

terms = Normal@{Series[ExpIntegralEi[x], {x, 1, 1}], Series[ExpIntegralEi[x], {x, 1, 3}], Series[ExpIntegralEi[x], {x, 1, 4}]};
Plot[{ExpIntegralEi[x], terms}, {x, -1, 3}]

無限大における級数展開を求める：

Wolfram Language code: Series[ExpIntegralEi[x], {x, Infinity, 3}]//Normal

任意の記号方向についての結果を与える：

Wolfram Language code: Series[ExpIntegralEi[x], {x, DirectedInfinity[], 1}]//Normal

ExpIntegralEiはベキ級数に適用できる：

Wolfram Language code: ExpIntegralEi[1 + x + (x^2/2) + (x^3/9) + O[x]^4]

関数の恒等式と簡約 (3)

FullSimplifyを使って指数積分を含む式を簡約する：

Wolfram Language code: FullSimplify[ExpIntegralEi[z] + (1/2)(Log[z] + Log[(1/z)])]

引数の簡約：

Wolfram Language code: ExpIntegralEi[Log[z]]//FunctionExpand

Wolfram Language code: ExpIntegralEi[I z] == CosIntegral[z] + I SinIntegral[z] - (1/2) (Log[-(I/z)] - Log[I z]) - Log[z]//FullSimplify

のとき，：

Wolfram Language code: FullSimplify[ExpIntegralEi[x] == -ExpIntegralE[1, -x], x < 0]

関数表現 (4)

積分表現：

Wolfram Language code: -Integrate[Exp[-t] / t, {t, -z, Infinity}, PrincipalValue -> True, Assumptions -> {z∈Reals, z ≥ 0}]

ExpIntegralEiはDifferentialRootとして表現できる：

Wolfram Language code: DifferentialRootReduce[ExpIntegralEi[x], x]

ExpIntegralEiはMeijerGによって表現できる：

Wolfram Language code: MeijerGReduce[ExpIntegralEi[x], x]

Wolfram Language code: Activate[%]//FullSimplify

TraditionalFormによる表示：

Wolfram Language code: ExpIntegralEi[x]//TraditionalForm

アプリケーション (3)

k!係数を含む古典的な漸近級数を計算する：

Wolfram Language code: Series[-Exp[1 / z] ExpIntegralEi[-1 / z], {z, 0, 10}, Assumptions -> z > 0]

複素平面上で虚部をプロットする：

Wolfram Language code: Plot3D[Im[ExpIntegralEi[x + I y]], {x, -3, 3}, {y, -3, 3}]

オイラー・ハイゼンベルク(Euler–Heisenberg)の有効作用の実部：

Wolfram Language code:

action[k_, {m_, e_}, {a_, b_}] := With[{x = k π (m^2/e a), y = k π (m^2/e b)}, -(e^2a b/4 π^3k)(Coth[k π (b/a)](CosIntegral[x] Cos[x] + (SinIntegral[x] - π / 2)Sin[x]) - 
	Coth[k π (a/b)](ExpIntegralEi[y] Exp[-y] + ExpIntegralEi[-y] Exp[y]) / 2)]

の最も次数が高い項を求める：

Wolfram Language code:

Assuming[{q > 0 && a > 0 && b > 0 && m > 0 && k > 0}, 
	Series[action[k, {m, q}, {a, b}], {q, 0, 4}]//Normal//FullSimplify]

特性と関係 (8)

FullSimplifyを使って指数積分を含む式を簡約する：

Wolfram Language code: FullSimplify[ExpIntegralEi[z] + (1/2)(Log[z] + Log[(1/z)])]

数値根を求める：

Wolfram Language code: FindRoot[ExpIntegralEi[z] == 0, {z, 1}]

積分と総和からExpIntegralEiを求める：

Wolfram Language code: Integrate[(E ^ t - 1) / t, {t, 0, z}, Assumptions -> z > 0]

Wolfram Language code: Underoverscript[∑, k = 1, ∞](z^k/k k!)//FunctionExpand

極限を計算する：

Wolfram Language code: Limit[Exp[2ExpIntegralEi[-x]] / x ^ 2, x -> 0]

微分方程式からExpIntegralEiを求める：

Wolfram Language code: DSolve[z Derivative[3][w][z] + 2 Derivative[2][w][z] - z Derivative[1][w][z] == 0, w, z]

ロンスキ(Wronski)の行列式を計算する：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {1, ExpIntegralEi[x], ExpIntegralEi[-x]}, {0, 1, 2}]]

積分：

Wolfram Language code: ∫z^αExpIntegralEi[z^β]ⅆz

積分変換：

Wolfram Language code: LaplaceTransform[ExpIntegralEi[t], t, s, Assumptions -> s > 1]

考えられる問題 (3)

ExpIntegralEiは中程度の大きさの引数の大きい値を取ることができる：

Wolfram Language code: ExpIntegralEi[Sqrt[I] 10000. ]

ExpIntegralEiは負の実軸上に，どちらの側からも極限としては求められない特別な値を持つ：

Wolfram Language code: N[ExpIntegralEi[-1 + {-10 ^ -10I, 0, 10 ^ -10 I}]]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[ExpIntegralEi[-10 ^ 60 I] + I Pi, 20]

Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[ExpIntegralEi[-10 ^ 60 I] + I Pi, 20]]

おもしろい例題 (1)

ネストした積分：

Wolfram Language code: NestList[Integrate[#, x]&, ExpIntegralEi[ x], 4]

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ExpIntegralEi

詳細

例題

例 (5)

スコープ (37)

数値評価 (5)

特定の値 (3)

可視化 (3)

関数の特性 (10)

微分 (3)

積分 (3)

級数展開 (3)

関数の恒等式と簡約 (3)

関数表現 (4)

アプリケーション (3)

特性と関係 (8)

考えられる問題 (3)

おもしろい例題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

ExpIntegralEi

詳細

例題

例 (5)

スコープ (37)

数値評価 (5)

特定の値 (3)

可視化 (3)

関数の特性 (10)

微分 (3)

積分 (3)

級数展開 (3)

関数の恒等式と簡約 (3)

関数表現 (4)

アプリケーション (3)

特性と関係 (8)

考えられる問題 (3)

おもしろい例題 (1)

関連項目

テクニカルノート

関連するガイド

関連リンク

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX