WOLFRAM

Wolfram 语言与系统参考资料中心

ExpIntegralEi[z]

给出指数积分函数 TemplateBox[{z}, ExpIntegralEi].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
函数表示  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ExpIntegralEi

ExpIntegralEi[z]

给出指数积分函数 TemplateBox[{z}, ExpIntegralEi].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (5)

数值计算：

Wolfram Language code: ExpIntegralEi[1.8]

在实数的子集上绘图：

Wolfram Language code: Plot[ExpIntegralEi[x], {x, -1, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ExpIntegralEi[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的分支点附近级数展开：

Wolfram Language code: Series[ExpIntegralEi[x], {x, 0, 5}, Assumptions -> x > 0]
Wolfram Language code: Series[ExpIntegralEi[x], {x, 0, 5}, Assumptions -> x < 0]

在 Infinity 的级数展开：

Wolfram Language code: Series[ExpIntegralEi[ x], {x, ∞, 6}]//Normal

范围  (37)

数值计算  (5)

高精度数值计算：

Wolfram Language code: N[ExpIntegralEi[2], 50]

输出精度与输入精度相一致：

Wolfram Language code: ExpIntegralEi[2.0000000000000000000000]

ExpIntegralEi 使用复数输入：

Wolfram Language code: ExpIntegralEi[2. + I]

在高精度条件下高效计算 ExpIntegralEi：

Wolfram Language code: ExpIntegralEi[2`500]//Timing
Wolfram Language code: ExpIntegralEi[2`10000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ExpIntegralEi[Interval[{1.1, 1.2}]]
Wolfram Language code: ExpIntegralEi[CenteredInterval[2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: ExpIntegralEi[ Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: ExpIntegralEi[{{I π, I π / 2}, {0, -I }}]//FunctionExpand

或用 MatrixFunction 计算矩阵形式的 ExpIntegralEi 函数：

Wolfram Language code: MatrixFunction[ExpIntegralEi, {{I π, I π / 2}, {0, I}}]//FunctionExpand

特殊值  (3)

固定点上的值：

Wolfram Language code: ExpIntegralEi[0]

无穷处的值：

Wolfram Language code: ExpIntegralEi[{Infinity, -Infinity, I Infinity, -I Infinity}]
Wolfram Language code: ExpIntegralEi[ComplexInfinity]

求 ExpIntegralEi 的零点：

Wolfram Language code: xzero = Solve[ExpIntegralEi[x] == 0 && 0 < x < 0.5, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[ExpIntegralEi[x], {x, 0, 1}, Epilog -> Style[Point[{xzero, ExpIntegralEi[xzero]}], PointSize[Large], Red]]

可视化  (3)

绘制 ExpIntegralEi 函数：

Wolfram Language code: Plot[ExpIntegralEi[x], {x, -5, 5}]

绘制 TemplateBox[{z}, ExpIntegralEi] 的实部：

Wolfram Language code: ComplexContourPlot[Re[ExpIntegralEi[z]], {z, -10 - 10I, 10 + 10 I}, Contours -> 20]

绘制 TemplateBox[{z}, ExpIntegralEi] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[ExpIntegralEi[z]], {z, -10 - 10I, 10 + 10 I}, Contours -> 20]

函数属性  (10)

ExpIntegralEi 是针对除 0 之外的所有实数定义的：

Wolfram Language code: FunctionDomain[ExpIntegralEi[x], x]

复定义域：

Wolfram Language code: FunctionDomain[ExpIntegralEi[z], z, Complexes]

ExpIntegralEi 的值域是所有实数：

Wolfram Language code: FunctionRange[ExpIntegralEi[x], x, y]

ExpIntegralEi 具有镜像属性 TemplateBox[{TemplateBox[{z}, Conjugate, SyntaxForm -> SuperscriptBox]}, ExpIntegralEi]=TemplateBox[{TemplateBox[{z}, ExpIntegralEi]}, Conjugate]：

Wolfram Language code: FullSimplify[ExpIntegralEi[Conjugate[z]] == Conjugate[ExpIntegralEi[z]]]

ExpIntegralEi 不是解析函数：

Wolfram Language code: FunctionAnalytic[ExpIntegralEi[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[ExpIntegralEi[x], x]

ExpIntegralEi 在实数上不是单调的：

Wolfram Language code: FunctionMonotonicity[ExpIntegralEi[x], x]

但是，它在每个半线上是单调的：

Wolfram Language code: FunctionMonotonicity[{ExpIntegralEi[x], x > 0}, x]
Wolfram Language code: FunctionMonotonicity[{ExpIntegralEi[x], x < 0}, x]

ExpIntegralEi 不是单射函数：

Wolfram Language code: FunctionInjective[ExpIntegralEi[x], x]
Wolfram Language code: Plot[{ExpIntegralEi[x], -1 / 2}, {x, -2, 2}]

ExpIntegralEi 是满射函数：

Wolfram Language code: FunctionSurjective[ExpIntegralEi[x], x]
Wolfram Language code: Plot[{ExpIntegralEi[x], 10}, {x, -10, 10}]

ExpIntegralEi 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[{ExpIntegralEi[x], x ≠ 0}, x]

ExpIntegralEi 在零处有奇点和断点：

Wolfram Language code: FunctionSingularities[ExpIntegralEi[x], x]
Wolfram Language code: FunctionDiscontinuities[ExpIntegralEi[x], x]

ExpIntegralEi 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[{ExpIntegralEi[x], x ≠ 0}, x]

但在负实数上是凹的：

Wolfram Language code: FunctionConvexity[{ExpIntegralEi[x], x < 0}, x]

微分  (3)

一阶导数：

Wolfram Language code: D[ExpIntegralEi[x], x]

高阶导数：

Wolfram Language code: Table[D[ExpIntegralEi[x], {x, k}], {k, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[ExpIntegralEi[x], {x, n}]

积分  (3)

ExpIntegralEi 的不定积分：

Wolfram Language code: Integrate[ExpIntegralEi[x], x]

含有 ExpIntegralEi 的函数的定积分：

Wolfram Language code: Integrate[Exp[-z x]ExpIntegralEi[x], {x, 0, Infinity}]

更多积分：

Wolfram Language code: Integrate[z^αExpIntegralEi[z^β], z]
Wolfram Language code: Integrate[Log[b x]ExpIntegralEi[a x], x]

级数展开式  (3)

ExpIntegralEi 在 处的泰勒展开式：

Wolfram Language code: Series[ExpIntegralEi[x], {x, 1, 7}]

绘制 ExpIntegralEi 在 处的前三个近似式：

Wolfram Language code: terms = Normal@{Series[ExpIntegralEi[x], {x, 1, 1}], Series[ExpIntegralEi[x], {x, 1, 3}], Series[ExpIntegralEi[x], {x, 1, 4}]}; Plot[{ExpIntegralEi[x], terms}, {x, -1, 3}]

求无穷处的级数展开式：

Wolfram Language code: Series[ExpIntegralEi[x], {x, Infinity, 3}]//Normal

给出在任意符号方向上的结果：

Wolfram Language code: Series[ExpIntegralEi[x], {x, DirectedInfinity[], 1}]//Normal

ExpIntegralEi 可用于幂级数：

Wolfram Language code: ExpIntegralEi[1 + x + (x^2/2) + (x^3/9) + O[x]^4]

函数恒等式和化简  (3)

用 FullSimplify 化简含有指数积分的表达式：

Wolfram Language code: FullSimplify[ExpIntegralEi[z] + (1/2)(Log[z] + Log[(1/z)])]

参数化简：

Wolfram Language code: ExpIntegralEi[Log[z]]//FunctionExpand
Wolfram Language code: ExpIntegralEi[I z] == CosIntegral[z] + I SinIntegral[z] - (1/2) (Log[-(I/z)] - Log[I z]) - Log[z]//FullSimplify

时，TemplateBox[{x}, ExpIntegralEi]=-TemplateBox[{1, {-, x}}, ExpIntegralE]：

Wolfram Language code: FullSimplify[ExpIntegralEi[x] == -ExpIntegralE[1, -x], x < 0]

函数表示  (4)

积分表示：

Wolfram Language code: -Integrate[Exp[-t] / t, {t, -z, Infinity}, PrincipalValue -> True, Assumptions -> {z∈Reals, z ≥ 0}]

ExpIntegralEi 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[ExpIntegralEi[x], x]

ExpIntegralEi 可以被表示为 MeijerG 的形式：

Wolfram Language code: MeijerGReduce[ExpIntegralEi[x], x]
Wolfram Language code: Activate[%]//FullSimplify

TraditionalForm 格式：

Wolfram Language code: ExpIntegralEi[x]//TraditionalForm

应用  (3)

计算系数 k! 的传统渐近级数：

Wolfram Language code: Series[-Exp[1 / z] ExpIntegralEi[-1 / z], {z, 0, 10}, Assumptions -> z > 0]

在复平面内绘制虚部：

Wolfram Language code: Plot3D[Im[ExpIntegralEi[x + I y]], {x, -3, 3}, {y, -3, 3}]

Euler–Heisenberg 有效作用的实部：

Wolfram Language code: action[k_, {m_, e_}, {a_, b_}] := With[{x = k π (m^2/e a), y = k π (m^2/e b)}, -(e^2a b/4 π^3k)(Coth[k π (b/a)](CosIntegral[x] Cos[x] + (SinIntegral[x] - π / 2)Sin[x]) - Coth[k π (a/b)](ExpIntegralEi[y] Exp[-y] + ExpIntegralEi[-y] Exp[y]) / 2)]

求 中的前导项：

Wolfram Language code: Assuming[{q > 0 && a > 0 && b > 0 && m > 0 && k > 0}, Series[action[k, {m, q}, {a, b}], {q, 0, 4}]//Normal//FullSimplify]

属性和关系  (8)

用 FullSimplify 来化简包含指数积分的表达式：

Wolfram Language code: FullSimplify[ExpIntegralEi[z] + (1/2)(Log[z] + Log[(1/z)])]

求数值根：

Wolfram Language code: FindRoot[ExpIntegralEi[z] == 0, {z, 1}]

从积分、求和中获得 ExpIntegralEi：

Wolfram Language code: Integrate[(E ^ t - 1) / t, {t, 0, z}, Assumptions -> z > 0]
Wolfram Language code: Underoverscript[∑, k = 1, ∞](z^k/k k!)//FunctionExpand

计算极限：

Wolfram Language code: Limit[Exp[2ExpIntegralEi[-x]] / x ^ 2, x -> 0]

从微分方程中获得 ExpIntegralEi：

Wolfram Language code: DSolve[z Derivative[3][w][z] + 2 Derivative[2][w][z] - z Derivative[1][w][z] == 0, w, z]

计算朗斯基矩阵：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {1, ExpIntegralEi[x], ExpIntegralEi[-x]}, {0, 1, 2}]]

积分：

Wolfram Language code: ∫z^αExpIntegralEi[z^β]ⅆz

积分变换：

Wolfram Language code: LaplaceTransform[ExpIntegralEi[t], t, s, Assumptions -> s > 1]

可能存在的问题  (3)

ExpIntegralEi 为适中的参数给出较大的值：

Wolfram Language code: ExpIntegralEi[Sqrt[I] 10000. ]

ExpIntegralEi 在负实数轴上有一个特殊值，该值不会作为从任意轴的极限：

Wolfram Language code: N[ExpIntegralEi[-1 + {-10 ^ -10I, 0, 10 ^ -10 I}]]

需要为 $MaxExtraPrecision 设置一个较大的值：

Wolfram Language code: N[ExpIntegralEi[-10 ^ 60 I] + I Pi, 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[ExpIntegralEi[-10 ^ 60 I] + I Pi, 20]]

巧妙范例  (1)

嵌套积分：

Wolfram Language code: NestList[Integrate[#, x]&, ExpIntegralEi[ x], 4]
Wolfram Research (1988)，ExpIntegralEi，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExpIntegralEi.html （更新于 2022 年）.

文本

Wolfram Research (1988)，ExpIntegralEi，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ExpIntegralEi.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "ExpIntegralEi." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ExpIntegralEi.html.

APA

Wolfram 语言. (1988). ExpIntegralEi. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ExpIntegralEi.html 年

BibTeX

@misc{reference.wolfram_2026_expintegralei, author="Wolfram Research", title="{ExpIntegralEi}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ExpIntegralEi.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_expintegralei, organization={Wolfram Research}, title={ExpIntegralEi}, year={2022}, url={https://reference.wolfram.com/language/ref/ExpIntegralEi.html}, note=[Accessed: 15-August-2026]}