WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FindIntegerNullVector[{x1,x2,…,xn}]

であるような整数 のリストを求める．

FindIntegerNullVector[{x1,x2,…,xn},d]

であるようなTemplateBox[{{{, {{a, _, 1}, ,, ..., ,, {a, _, n}}, }}}, Norm]<=d の整数 のリストを求める．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
WorkingPrecision  
ZeroTest  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

FindIntegerNullVector

FindIntegerNullVector[{x1,x2,…,xn}]

であるような整数 のリストを求める．

FindIntegerNullVector[{x1,x2,…,xn},d]

であるようなTemplateBox[{{{, {{a, _, 1}, ,, ..., ,, {a, _, n}}, }}}, Norm]<=d の整数 のリストを求める．

詳細とオプション

  • FindIntegerNullVectorは，PSLQあるいは番号識別としても知られている．
  • すべての aiが0である訳ではない．数 xiは実数でも複素数でもよい．複素数 xiについては，数 aiはガウス整数である．
  • FindIntegerNullVector[{x1,x2,…},d]では，指定されたノルム境界では整数零ベクトルは存在しないかもしれない．その場合，入力は未評価で返される．
  • 指定可能なオプション
  • WorkingPrecision Automatic内部計算で使う精度
    ZeroTest Automatic数が0であるかどうかをテストするメソッド
  • ZeroTest->Automaticと設定すると整数関係 をテストするメソッドが自動的に決められる．
  • 非厳密数 xiについては，求まった関係は入力の精度まで正しい．厳密数 xi については，求まった関係はPossibleZeroQを使って証明される．
  • 非厳密数 xiでWorkingPrecision->Automaticの場合，精度は入力精度であると解釈される．
  • 厳密数 xiでWorkingPrecision->Automaticの場合，精度はMachinePrecisionから始まってノルム境界 d が指定されていない場合に整数零ベクトルを求める場合には$MaxExtraPrecisionまで使われると考えられる．ノルム境界 d が定まっている場合には，零ベクトルを求めるかあるいは零ベクトルが存在しないことを証明するために十分な精度が使われる．

例題

すべて開く すべて閉じる

例  (3)

厳密入力：

Wolfram Language code: FindIntegerNullVector[{Log[2], Log[4]}]
Wolfram Language code: {Log[2], Log[4]}.%//Simplify

厳密ではない入力：

Wolfram Language code: FindIntegerNullVector[N@{Log[2], Log[4]}]

ノルム境界を有する厳密入力：

Wolfram Language code: FindIntegerNullVector[{Log[2], Log[4]}, 3]

2以下のノルムには零ベクトルがない：

Wolfram Language code: FindIntegerNullVector[{Log[2], Log[4]}, 2]

スコープ  (6)

次は，厳密な有理数のベクトルの整数零ベクトルを求める：

Wolfram Language code: v = Sin[Pi / 8] ^ Range[0, 4]
Wolfram Language code: rel = FindIntegerNullVector[v]
Wolfram Language code: Simplify[rel.v]

次は，8以下のノルムでは零ベクトルがないことを証明している：

Wolfram Language code: FindIntegerNullVector[v, 8]

零ベクトルのノルム近くの境界では，零ベクトルが存在しないことが証明できないことがある：

Wolfram Language code: FindIntegerNullVector[v, 9]

返された零ベクトルはノルム境界を満足しない：

Wolfram Language code: Norm[%]//N

FindIntegerNullVectorは数が整数上で線形非依存であることは証明できない：

Wolfram Language code: FindIntegerNullVector[{E, Pi}]

次は与えられれた境界以下では整数零ベクトルがないことを証明している：

Wolfram Language code: FindIntegerNullVector[{E, Pi}, 1000000]

厳密ではない入力の場合，関係は入力精度まで真である：

Wolfram Language code: FindIntegerNullVector[N[{E, Pi}, 20]]
Wolfram Language code: N[{E, Pi}, 20].%

与えられたノルム境界では零ベクトルは存在しない：

Wolfram Language code: FindIntegerNullVector[N[{E, Pi}, 20], 10]

次では零ベクトルは求まらないが，零ベクトルが存在しないことは小さいノルム境界についてしか証明されない：

Wolfram Language code: FindIntegerNullVector[N[{E, Pi}, 20], 10 ^ 9]

次は の20桁精度近似で零ベクトルを求める：

Wolfram Language code: v = {Log[2 ^ 12345 3 ^ 67890], Log[2 ^ 9876543], Log[3 ^ 6543210]}; r20 = FindIntegerNullVector[N[v, 20]]
Wolfram Language code: N[v, 20].r20

厳密ベクトル については結果は零ベクトルではない：

Wolfram Language code: N[r20.v, 50]

のより高精度の近似で求まった零ベクトルは厳密ベクトル についても零ベクトルである：

Wolfram Language code: r50 = FindIntegerNullVector[N[v, 50]]
Wolfram Language code: FullSimplify[r50.v]

これは厳密な複素数ベクトルのガウス整数零ベクトルを与える：

Wolfram Language code: v = {1, 2I + Sqrt[3], (2I + Sqrt[3]) ^ 2}
Wolfram Language code: FindIntegerNullVector[v]
Wolfram Language code: Expand[%.v]

これは近似複素数ベクトルのガウス整数零ベクトルを求める：

Wolfram Language code: v = N[{Log[-1024], 1234 Pi, Log[4]}, 20]
Wolfram Language code: FindIntegerNullVector[v]

オプション  (2)

WorkingPrecision  (1)

デフォルトで，最高$MachinePrecision+$MaxExtraPrecision桁の精度が使われる：

Wolfram Language code: v = Table[(2 ^ (1 / 6) + 3 ^ (1 / 5)) ^ i, {i, 0, 30}];
Wolfram Language code: FindIntegerNullVector[v]

より高いWorkingPrecisionを使うと零ベクトルが求まる：

Wolfram Language code: FindIntegerNullVector[v, WorkingPrecision -> 300]

ZeroTest  (1)

デフォルトで，関係の証明にはMethod->"ExactAlgebraics"のPossibleZeroQが使われる：

Wolfram Language code: a = Root[# ^ 7 + 5# - 7&, 1]; b = Root[# ^ 7 - 12# + 82&, 1]; c = RootReduce[12345a - 67890b];

次は，厳密メソッドを使って関係を証明する：

Wolfram Language code: FindIntegerNullVector[{a, b, c}]//Timing

次は，代りに高精度数値テストを使う：

Wolfram Language code: FindIntegerNullVector[{a, b, c}, ZeroTest -> (Quiet[N[#, 2000]] == 0&)]//Timing

アプリケーション  (3)

代数的数の最小多項式の係数を求める：

Wolfram Language code: a = Sqrt[2] + 3 ^ (1 / 3); FindIntegerNullVector[Table[a ^ i, {i, 0, 6}]]

次は，記号メソッドで最小多項式を求める：

Wolfram Language code: CoefficientList[MinimalPolynomial[a, x], x]

超越数間の関係を求める：

Wolfram Language code: FindIntegerNullVector[{Sin[1] ^ 3, Sin[1], Sin[3]}]

の近似値を計算するMachinの公式の係数を求める：

Wolfram Language code: FindIntegerNullVector[{π, ArcTan[1 / 5], ArcTan[1 / 239]}]
Wolfram Language code: %.{π, ArcTan[1 / 5], ArcTan[1 / 239]}//FullSimplify

特性と関係  (3)

FindIntegerNullVectorは指定されたベクトルの整数零ベクトルを返す：

Wolfram Language code: FindIntegerNullVector[{Log[2], Log[3], Log[72]}]
Wolfram Language code: %.{Log[2], Log[3], Log[72]}//Simplify

整数零ベクトルは同次線形方程式の自明ではない整数解である：

Wolfram Language code: coeffs = {Cos[4], Cos[1] ^ 4, Cos[1] ^ 2, 1}; vars = {x, y, z, t}; eqn = coeffs.vars == 0
Wolfram Language code: FindIntegerNullVector[coeffs]
Wolfram Language code: eqn /. Thread[vars -> %]//Simplify

FindInstanceを使って方程式の解を求める：

Wolfram Language code: FindInstance[eqn && x ≠ 0, vars, Integers]

近似を使って代数的数の最小多項式の係数を求める：

Wolfram Language code: a = N[Sqrt[2] + Sqrt[3], 20]
Wolfram Language code: FindIntegerNullVector[a ^ Range[0, 4]]

RootApproximantを使って代数的数をその近似から求める：

Wolfram Language code: RootApproximant[a]

考えられる問題  (2)

数の間の関係を求めるためには近似精度が十分ではないかもしれない：

Wolfram Language code: v = (Sqrt[2] + Sqrt[3] + Sqrt[5]) ^ Range[0, 8];
Wolfram Language code: FindIntegerNullVector[N[v]]
Wolfram Language code: N[v.%, 20]

より高い精度で近似を行うと真の関係が得られる：

Wolfram Language code: FindIntegerNullVector[N[v, 50]]
Wolfram Language code: Expand[v.%]

非代数的数に対しての数値的なゼロテストは零ベクトルではない結果も許容する：

Wolfram Language code: FindIntegerNullVector[{Pi, Rationalize[N[Pi, 100], 0]}]

次は記号的ゼロテストメソッドがどれも適用されない場合にゼロテストに使われた精度を与える：

Wolfram Language code: ztprec = SystemOptions["ZeroTestNumericalPrecision"]

ゼロテストの精度をより高くすると，FindIntegerNullVectorはベクトルを正しく棄却する：

Wolfram Language code: SetSystemOptions["ZeroTestNumericalPrecision" -> 200];
Wolfram Language code: FindIntegerNullVector[{Pi, Rationalize[N[Pi, 100], 0]}]

システムオプションをもとの値にリセットする：

Wolfram Language code: SetSystemOptions["ZeroTestNumericalPrecision" -> ztprec];
Wolfram Research (2010), FindIntegerNullVector, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindIntegerNullVector.html.

テキスト

Wolfram Research (2010), FindIntegerNullVector, Wolfram言語関数， https://reference.wolfram.com/language/ref/FindIntegerNullVector.html.

CMS

Wolfram Language. 2010. "FindIntegerNullVector." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FindIntegerNullVector.html.

APA

Wolfram Language. (2010). FindIntegerNullVector. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FindIntegerNullVector.html

BibTeX

@misc{reference.wolfram_2026_findintegernullvector, author="Wolfram Research", title="{FindIntegerNullVector}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/FindIntegerNullVector.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_findintegernullvector, organization={Wolfram Research}, title={FindIntegerNullVector}, year={2010}, url={https://reference.wolfram.com/language/ref/FindIntegerNullVector.html}, note=[Accessed: 07-September-2026]}