WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Flat

シンボルの属性で，このシンボル f がネストしている場合に自動的にフラットにする（ネストをほどく）ことを指定する．この属性はパターンマッチの際に考慮される．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Flat

Flat

シンボルの属性で，このシンボル f がネストしている場合に自動的にフラットにする（ネストをほどく）ことを指定する．この属性はパターンマッチの際に考慮される．

詳細

  • Flatは数学的な特性である結合律に対応する．
  • 属性Flatを与えられているシンボル f では，f[f[a,b],f[c]]が自動的に f[a,b,c]へと還元される．
  • PlusやTimesそしてDotのような関数はFlatである．
  • Flatである関数 f では，パターン f[x_,y_]における変数 x と y は，引数の任意の列に対応することができる．
  • 属性Flatは，Flat関数に値を割り当てる前に，設定されなければならない．

例題

すべて開く すべて閉じる

例  (3)

平坦な関数を持つネストした式は平坦化される：

Wolfram Language code: SetAttributes[f, Flat]
Wolfram Language code: f[f[a, b], f[c, f[d, e]]]

Flatは結合律の概念を実装する：

Wolfram Language code: Attributes[Plus]
Wolfram Language code: a + (b + c)

Flatはパターンマッチに結合性を使うことができる：

Wolfram Language code: a + b + c /. x_ + y_ -> {x, y}

スコープ  (3)

結合性の関数を持つネストした式は平坦化される：

Wolfram Language code: Attributes[NonCommutativeMultiply]
Wolfram Language code: (a**(b**c))**(d)

パターンマッチングで，Flatは要素列の置換を許容する：

Wolfram Language code: SetAttributes[f, Flat]
Wolfram Language code: f[a, b, c, d, e] /. f[b, c, d] -> x
Wolfram Language code: f[a, b, c, d, e] /. f[b, c, d] -> f[x, y]
Wolfram Language code: f[a, b, c, d, e] /. f[b] -> x

平坦で順序を問わない関数の場合，引数の部分集合が一致することがある：

Wolfram Language code: SetAttributes[f, {Flat, Orderless}]
Wolfram Language code: f[a, b, c, d, e] /. f[d, b] -> x

特性と関係  (5)

平坦な関数を持つネストした式は自動的に平坦化される：

Wolfram Language code: f[f[a, b], f[c, f[d, e]]]
Wolfram Language code: Flatten[%]
Wolfram Language code: SetAttributes[g, Flat]
Wolfram Language code: g[g[a, b], g[c, g[d, e]]]

平坦な関数の場合，2引数の場合の定義で通常は十分である：

Wolfram Language code: SetAttributes[g, {Flat, OneIdentity}]
Wolfram Language code: g[x_, y_] := x + y
Wolfram Language code: g[a, b, c, d]

平らな頭部を持つ式は，任意の列とマッチする場合はその全体がマッチされるとみなされる：

Wolfram Language code: a + b + Sin[a + b] /. a + b -> 5

以下と比較する：

Wolfram Language code: {a + b, Sin[a + b]} /. a + b -> 5

ReplaceRepeatedは出現するすべてを確実に置換するのに役立つかもしれない：

Wolfram Language code: a + b + Sin[a + b] //. a + b -> 5

BlankがFlat関数 f 内の列をマッチするとき，頭部 f はそのまま保持される：

Wolfram Language code: SetAttributes[f, Flat]
Wolfram Language code: f[a, b, c] /. f[a, x_] -> {x}
Wolfram Language code: f[a, b, c] /. f[x_] -> {x}

BlankSequenceやBlankNullSequenceのような連続パターンはFlatの影響は受けない：

Wolfram Language code: f[a, b, c] /. f[a, z__] :> {z}
Wolfram Language code: f[a, b, c] /. f[a, z___] :> {z}

OneIdentityではない関数 f については，f[x_]が f[expr]と比較される際に，パターンマッチはまず x_を f[expr]にバインドしようとし，それが失敗したときに限って expr にバインドしようとする：

Wolfram Language code: SetAttributes[f, Flat]
Wolfram Language code: f[3] /. f[z_] /; IntegerQ[Echo[z]] :> z

関数がOneIdentity属性も持つ場合は，最初の試みは省かれる：

Wolfram Language code: SetAttributes[fo, {Flat, OneIdentity}]
Wolfram Language code: fo[3] /. fo[z_] /; IntegerQ[Echo[z]] :> z

考えられる問題  (4)

平坦で順序を問わない関数の場合，パターンマッチにはたくさんの場合を試さなければならないことがある：

Wolfram Language code: SetAttributes[f, {Flat, OneIdentity, Orderless}]
Wolfram Language code: ReplaceList[f[a, b, c, d], f[x_, y_] :> {x, y}]

Longestを使うと，短い部分式についての追加的なマッチを防ぐことができる：

Wolfram Language code: SetAttributes[f, {Flat, OneIdentity}]
Wolfram Language code: Replace[f[a, b, c, d], f[x_, y__, z_] :> {y}]
Wolfram Language code: Replace[f[a, b, c, d], f[x_, Longest[y__], z_] :> {y}]

平坦な関n f については，パターン f[_]は f と1つあるいは複数の引数をマッチする：

Wolfram Language code: SetAttributes[f, Flat]
Wolfram Language code: MatchQ[f[1, 2], f[_]]

Repeatedを，たとえ平坦な関数の中でも1つの引数のみをマッチするパターンとして使うことができる：

Wolfram Language code: MatchQ[f[1, 2], f[Repeated[_, {1}]]]

x_は平坦な関数の頭部とともにマッチされるので，制約は思いがけない動作をするかもしれない：

Wolfram Language code: Replace[a + b + c , Plus[a, x_] :> x]

x_Plus はPlus[b,c]とマッチするので次の制約はうまくいく：

Wolfram Language code: Replace[a + b + c , Plus[a, x_Plus] :> x]

x_はPlusとSymbolの両方の頭部を持つことはできないので，次は失敗する：

Wolfram Language code: Replace[a + b + c , Plus[a, x_Symbol] :> x]

BlankSequenceを左辺に使うとより一貫した結果が与えられる：

Wolfram Language code: Replace[a + b + c, Plus[a, x__Symbol] :> Plus[x]]
Wolfram Research (1988), Flat, Wolfram言語関数， https://reference.wolfram.com/language/ref/Flat.html.

テキスト

Wolfram Research (1988), Flat, Wolfram言語関数， https://reference.wolfram.com/language/ref/Flat.html.

CMS

Wolfram Language. 1988. "Flat." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Flat.html.

APA

Wolfram Language. (1988). Flat. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Flat.html

BibTeX

@misc{reference.wolfram_2026_flat, author="Wolfram Research", title="{Flat}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Flat.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_flat, organization={Wolfram Research}, title={Flat}, year={1988}, url={https://reference.wolfram.com/language/ref/Flat.html}, note=[Accessed: 07-September-2026]}