WOLFRAM

Wolfram 语言与系统参考资料中心

FlightData[spec,options]

返回具有规范 spec 的一个航班或一组所选航班的属性子集.

FlightData[spec,prop,options]

返回规范 spec 的属性 prop 的值.

FlightData[spec,prop,datespec,options]

返回特定时间或时间范围 datespec 的属性 prop 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
UnitSystem  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

FlightData

FlightData[spec,options]

返回具有规范 spec 的一个航班或一组所选航班的属性子集.

FlightData[spec,prop,options]

返回规范 spec 的属性 prop 的值.

FlightData[spec,prop,datespec,options]

返回特定时间或时间范围 datespec 的属性 prop 的值.

更多信息和选项

  • FlightData 目前提供有关美国境内已向 FAA 提交飞行计划的航班的信息. 这包括有限范围的历史航班.
  • FlightData 提供从一个机场到另一个机场的航班信息，即使飞机以不同的航班号继续飞往其他机场.
  • spec 可以是 "Flight" 实体或 "Flight" 实体列表、"Airport" 实体，和用 "FlightNumber" 和 "Airline" 作为键或以路线作为规则的关联.
  • "Flight" 实体可以使用一个其他的 spec 查询找到.
  • 当 spec 是 "Airport" 实体时，FlightData 返回有关进出该机场的所有航班信息.
  • 对于路线，规则的第一个参数是始发机场，第二个参数是到达机场. FlightData 将返回沿该路线的所有航班的结果. All 可以替换规则参数之一，以查找进出指定机场的所有航班.
  • 到达和出发属性包括：
  • "ArrivalAirport"航班目的地机场
    "ArrivalDelay"比原定到达时间延迟
    "ArrivalTime"实际到达时间
    "DepartureAirport"航班始发机场
    "DepartureDelay"比原定出发时间延迟
    "DepartureTime"实际出发时间
    "OriginalArrivalTime"原始到达时间
    "OriginalDepartureTime"原始出发时间
  • 航班状态属性包括：
  • "FlightDuration"飞行时间
    "FlightStatus"航班状态
    "LandedQ"飞机是否已经降落
    "TimeSinceTakeOff"起飞后的飞行时间
    "TimeToLanding"距离着陆的时间
  • 与时间无关的航班属性包括：
  • "AircraftType"航班使用的飞机
    "Airline"航班的航空公司
    "FlightNumber"航班号
    "Flights"spec 的 "Flight" 实体
    "FutureFlights"此飞机或航班号在未来 10 天内的航班
    "PreviousFlights"此飞机或航班号在过去 10 天内的航班
  • 基于时间序列的属性包括：
  • "Altitude"飞机相对于平均海平面的高度
    "DirectionHeading"飞机相对于真北的方向
    "FlightMap"飞行的 GeoGraphics 地图
    "FlightPath"飞行路径
    "Position"飞机的地理位置
    "RateOfClimb"爬升率
    "Speed"飞机的速度
  • 与时间相关的汇总属性包括：
  • "DistanceTraveled"已旅行的距离
    "MaxAltitude"最大高度
    "MaxSpeed"最大速度
    "MeanCruisingSpeed"平均速度，不包括起飞或着陆
    "MeanSpeed"平均速度
  • 默认情况下，"Flight" 实体的 FlightData 返回的是 "Airline"、"ArrivalAirport"、"ArrivalDelay"、"ArrivalTime"、"DepartureAirport"、"DepartureDelay"、"DepartureTime"、"DistanceTraveled"、"FlightDuration"、 "FlightNumber"、"FlightPath"、"FlightStatus"、"OriginalArrivalTime" 和 "OriginalDepartureTime" 属性的关联.
  • 默认情况下，航线、机场或航空公司与航班号关联的 FlightData 将返回 "Flights" 属性.
  • prop 也可以指定为 "PropertyAssociation" 或 "Dataset"，它们分别返回所有属性的 Association 和这些属性的 Dataset. 还支持属性列表.
  • "ArrivalTime"、"DepartureTime"、"OriginalArrivalTime" 和 "OriginalDepartureTime" 以当地时间返回.
  • 时间序列结果以始发机场的时区返回.
  • 如果可能，时间序列结果包括到达和出发时间和从其他属性解释的值.
  • datespec 可以是单个日期，指定为日期列表或 DateObject，或两个此类日期的列表，定义一段时间. 对于单次时间，将计算该特定时间的结果. 对于日期范围，结果包括相关的 TimeSeries（例如 "Altitude" 或 "Speed"）或在该范围内计算（例如 "MaxSpeed" 或 "FlightMap"）.
  • 如果没有指定航班的 datespec，FlightData 将返回由 Now 定义的当前本地时间的结果. 在处理航线和机场时，结果反映的是当天的航班. 如果可能，那一天定义为始发机场的时区从午夜到下一个午夜.
  • FlightData[spec,prop,airline,datespec] 可用于过滤指定航空公司的航线结果. 对于单次航班的情况，将忽略航空公司参数.
  • 选项 UnitSystem 可用于控制结果的单位. 可以使用以下设置：
  • "Imperial"以英制单位返回结果
    "Metric"以公制单位返回结果

范例

打开所有单元 关闭所有单元

基本范例  (4)

绘制特定航班的飞行路径：

Wolfram Language code: flight = First[FlightData[Entity["Airport", "KSMF"] -> Entity["Airport", "KSEA"], "Flights", Yesterday]]

绘制飞行路线图：

Wolfram Language code: FlightData[flight, "FlightMap"]

查找特定航空公司、航班号和特定日期的 "Flight" 实体：

Wolfram Language code: FlightData[Association["Airline" -> Entity["Airline", "SouthwestAirlinesCo::tcv64"], "FlightNumber" -> 1644], "Flights", DateObject[{2021, 9, 7}]]

获取昨天两个机场之间的 "Flight" 实体：

Wolfram Language code: FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "Flights", Yesterday]//Shallow

获取从纽约市到萨克拉门托市的飞行时间：

Wolfram Language code: FlightData[Association["Airline" -> Entity["Airline", "SouthwestAirlinesCo::tcv64"], "FlightNumber" -> 1644], "FlightDuration"]

获取机场在特定日期的所有出发航班：

Wolfram Language code: FlightData[Entity["Airport", "LAX"] -> All, "Flights", DateObject[{2019, 7, 1}, "Day", "Gregorian", -7.]]//Shallow

范围  (9)

检查所有可用的属性：

Wolfram Language code: FlightData["Properties"]

获取特定航班的所有可用属性：

Wolfram Language code: flight = First[FlightData[Association["Airline" -> Entity["Airline", "SouthwestAirlinesCo::tcv64"], "FlightNumber" -> 1644], "Flights"]]
Wolfram Language code: FlightData[flight, "PropertyAssociation"]

查找航班的特定属性：

Wolfram Language code: FlightData[flight, "ArrivalDelay"]

查看随时间推移航班的飞行速度：

Wolfram Language code: flight = First[FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "Flights", Yesterday]]
Wolfram Language code: speed = FlightData[flight, "Speed", All]; DateListPlot[speed]

检查萨克拉门托国际机场目前的计划起飞时间：

Wolfram Language code: assoc = FlightData[Entity["Airport", "SMF"] -> All, "DepartureTime"];
Wolfram Language code: TimelinePlot[Values[assoc]]

查找到达洛根机场的航班的始发机场：

Wolfram Language code: DeleteDuplicates[Values[FlightData[All -> Entity["Airport", "BOS"], "DepartureAirport"]]]//Shallow

查看昨天从 JFK 飞往 PDX 的航班时间：

Wolfram Language code: FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "FlightDuration", Yesterday]

获取所有进出波特兰国际机场的航班的航空公司数据：

Wolfram Language code: DeleteCases[Union[Values[FlightData[Entity["Airport", "PDX"], "Airline"]]], _Missing]

查找 2022 年 4 月 15 日萨克拉门托国际机场 JetBlue 航空公司所有航班的出发时间：

Wolfram Language code: FlightData[Entity["Airport", "KSMF"], "DepartureTime", Entity["Airline", "JetBlueAirways::f8z3c"], DateObject[{2022, 4, 15}, "Day"]]

查找从哈兹菲尔德-杰克逊亚特兰大国际机场出发的所有西南航空公司班机的目的地：

Wolfram Language code: Union[Values[FlightData[Entity["Airport", "ATL"] -> All, "ArrivalAirport", Entity["Airline", "SouthwestAirlinesCo::tcv64"]]]]//Shallow

选项  (1)

UnitSystem  (1)

控制结果是以公制还是英制单位返回：

Wolfram Language code: flight = First[FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "Flights", Yesterday]]
Wolfram Language code: FlightData[flight, "DistanceTraveled", UnitSystem -> "Imperial"]
Wolfram Language code: FlightData[flight, "DistanceTraveled", UnitSystem -> "Metric"]

应用  (6)

绘制早上 5 点后离开肯尼迪机场的航班图：

Wolfram Language code: paths = Values[FlightData[Entity["Airport", "JFK"] -> All, "FlightPath", {DateObject[{2018, 1, 1, 5}, "Hour", "Gregorian", "America/New_York"], DateObject[{2018, 1, 1, 12}, "Hour", "Gregorian", "America/New_York"]}]];
Wolfram Language code: after = TrueQ[DateObject[{2018, 1, 1, 5, 0, 0}, "Instant", "Gregorian", "America/New_York"] <= #]& /@ Values[FlightData[Entity["Airport", "JFK"] -> All, "DepartureTime", {DateObject[{2018, 1, 1, 5}, "Hour", "Gregorian", "America/New_York"], DateObject[{2018, 1, 1, 12}, "Hour", "Gregorian", "America/New_York"]}]];
Wolfram Language code: paths = DeleteCases[Pick[paths, after], _Missing];
Wolfram Language code: GeoGraphics[{Red, Arrowheads[{{Automatic, 0.99}}], Arrow /@ paths}]

检查离开丹佛的航班的高度：

Wolfram Language code: flights = FlightData[Entity["Airport", "KDEN"] -> All, "Flights", {DateObject[{2021, 9, 13, 6}, "Hour", "Gregorian", -7.], DateObject[{2021, 9, 13, 12}, "Hour", "Gregorian", -7.]}];
Wolfram Language code: altitude = FlightData[flights, "Altitude", All];

删除缺少起飞信息的航班并将时间序列移到一个公共的起点：

Wolfram Language code: takeoff[ts_] := Module[{ft = ts["FirstTime"], fv = ts["FirstValue"]}, If[TrueQ[Quantity[5000, "Feet"] < fv < Quantity[6000, "Feet"]], TimeSeriesShift[TimeSeriesWindow[ts, {ft, ft + 5400}], {{0}}], Nothing] ]
Wolfram Language code: alts = takeoff /@ Values[altitude];
Wolfram Language code: DateListPlot[alts, GridLines -> {None, {Entity["City", {"Denver", "Colorado", "UnitedStates"}][EntityProperty["City", "Elevation"]]}}]

探索从阿尔伯克基起飞的航班的常见飞行路线：

Wolfram Language code: flights = FlightData[Entity["Airport", "KABQ"] -> All, "FlightPath", DateObject[{2021, 9, 1}]];
Wolfram Language code: GeoGraphics[{Blue, Line /@ flights}, GeoRange -> Quantity[100, "Miles"], GeoCenter -> Entity["Airport", "KABQ"]]

检查一天中奥黑尔机场在 10 分钟窗口期的航班起飞时间：

Wolfram Language code: dTimes = Values[FlightData[Entity["Airport", "KORD"] -> All, "DepartureTime", Yesterday]]; DateHistogram[dTimes, Quantity[10, "Minutes"]]

了解从肯尼迪机场到美国各地机场的航班相对流量：

Wolfram Language code: outgoing = Tally[FlightData[Entity["Airport", "KJFK"] -> All, "ArrivalAirport", Yesterday]];
Wolfram Language code: GeoGraphValuePlot[Prepend[#, Entity["Airport", "KJFK"]]& /@ outgoing, GeoRange -> Entity["Country", "UnitedStates"], GraphLayout -> "Geodesic", VertexSize -> Medium, VertexLabels -> Placed["Name", Tooltip]]

检查从洛杉矶飞往纽约市的航班的可见区域：

Wolfram Language code: flight = First[FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "Flights", Yesterday]]; locs = FlightData[flight, "FlightPath"]; GeoGraphics[{Blue, Line[locs], Opacity[0.15, Pink], GeoVisibleRegionBoundary[locs]}]

属性和关系  (1)

FlightsOverhead 查找当前头顶上的航班并提供可视化：

Wolfram Language code: ResourceFunction["FlightsOverhead"][Here, "Flights"]
Wolfram Language code: ResourceFunction["FlightsOverhead"][Here, "SkyMap"]

可能存在的问题  (2)

航班信息的采样并不总是在进行，在某些情况下，对于长时间的飞行，航班信息可能会丢失：

Wolfram Language code: path = FlightData[Entity["Flight", "202109010000228562"], "FlightPath"];
Wolfram Language code: incr = Flatten[Differences /@ Partition[path[[1, All, 4]], 2, 2]]
Wolfram Language code: Histogram[Rest[incr]]

在可能的情况下，该数据会增加到达和出发的位置和时间：

Wolfram Language code: GeoGraphics[Arrow[path]]

当天的查询可能包括缺失的飞行路径数据：

Wolfram Language code: flightpaths = FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "FlightPath"];
Wolfram Language code: Select[flightpaths, !FreeQ[#, Missing]&]

巧妙范例  (3)

检查一个地区上空的航班密度：

Wolfram Language code: flightpaths = Values[FlightData[Entity["Airport", "KORD"], "Position", {DateObject[{2020, 1, 1}], DateObject[{2020, 1, 2}]}]];
Wolfram Language code: positions = Flatten[Map[#["Values"]&, flightpaths]];
Wolfram Language code: GeoHistogram[positions, GeoRange -> Quantity[50, "Miles"], GeoCenter -> Entity["City", {"Chicago", "Illinois", "UnitedStates"}]]

探索飞行速度和高度之间的关系：

Wolfram Language code: flights = FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "Flights", Yesterday];
Wolfram Language code: altitudeSpeedPlot[flight_, opts___] := Module[{alt = FlightData[flight, "Altitude", All], speed = FlightData[flight, "Speed", All], minT, maxT}, {minT, maxT} = MinMax[alt["Times"]]; ParametricPlot[ Tooltip[{QuantityMagnitude[alt[t], "Meters"], QuantityMagnitude[speed[t], "Kilometers" / "Hours"] }, flight], {t, minT, maxT}, opts, AspectRatio -> 1, AxesLabel -> {"altitude (m)", "speed (km/h)"}, PlotRange -> All]]
Wolfram Language code: Show[altitudeSpeedPlot[#, PlotStyle -> RandomColor[]] & /@ flights]

提取从东到西飞行的航班高度值：

Wolfram Language code: altitudeEW = #["Elevation"]& /@ FlightData[Entity["Airport", "KLAX"] -> Entity["Airport", "JFK"], "FlightPath", {Yesterday, Today}];

将此与从西向东飞行的航班值进行比较：

Wolfram Language code: altitudeWE = #["Elevation"]& /@ FlightData[Entity["Airport", "JFK"] -> Entity["Airport", "KLAX"], "FlightPath", {Yesterday, Today}];

比较两者以发现连接两个机场的航路内的飞行高度：

Wolfram Language code: Histogram[Flatten[Values[#]]& /@ {altitudeEW, altitudeWE}, {1000}]
Wolfram Research (2021)，FlightData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FlightData.html.

文本

Wolfram Research (2021)，FlightData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FlightData.html.

CMS

Wolfram 语言. 2021. "FlightData." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FlightData.html.

APA

Wolfram 语言. (2021). FlightData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FlightData.html 年

BibTeX

@misc{reference.wolfram_2026_flightdata, author="Wolfram Research", title="{FlightData}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/FlightData.html}", note=[Accessed: 10-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_flightdata, organization={Wolfram Research}, title={FlightData}, year={2021}, url={https://reference.wolfram.com/language/ref/FlightData.html}, note=[Accessed: 10-October-2026]}