WOLFRAM

Wolfram 语言与系统参考资料中心

FromTabular[tab,"form"]

将 Tabular 对象 tab 转换为 "form" 给出的对象.

FromTabular[tab,"form",assoc]

使用关联 assoc 中的指令来提供转换的详细信息.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
行和列  
数据集  
TimeSeries  
TemporalData  
应用  
销售数据  
金融时间序列  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

FromTabular

FromTabular[tab,"form"]

将 Tabular 对象 tab 转换为 "form" 给出的对象.

FromTabular[tab,"form",assoc]

使用关联 assoc 中的指令来提供转换的详细信息.

更多信息

  • FromTabular 通常用于控制如何将 Tabular 对象转换为其他数据对象.
  • 在 FromTabular[tab,form,…] 中，结构规范 "form" 可以包括：
  • "Columns"TabularColumn 对象的集合
    "Rows"行列表
    "Matrix"值矩阵
    "Dataset"多层次数据
    "TimeSeries"TimeSeries 对象
    "TemporalData"TemporalData 对象
  • 关联 assoc 可以包含有关如何将表格转换为不同形式的具体信息.
  • 当转换为 TimeSeries 或 TemporalData 时，assoc 中的可能键包括：
  • "TimeColumn""RowNumber"用作时间的列（将使用第一个带有时间相关的键的列；如果没有，则使用 Tabular 的第一列，并回退到 Automatic 时间指定）
    "ValueColumns"Automatic用作值的列（默认除时间列外的所有列）

范例

打开所有单元 关闭所有单元

基本范例  (1)

从 Tabular 对象转换为行向数据：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {2, 4, 6}}, {"a", "b", "c"}]
Wolfram Language code: FromTabular[tab, "Rows"]

转换为列：

Wolfram Language code: FromTabular[tab, "Columns"]

获取 Dataset：

Wolfram Language code: FromTabular[tab, "Dataset"]

范围  (15)

行和列  (5)

从无列键的 Tabular 对象中获取行：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}]

返回行列表：

Wolfram Language code: FromTabular[tab, "Rows"]

从有列键的 Tabular 对象中获取行：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, {"a", "b", "c"}]

返回与列键关联的列表：

Wolfram Language code: FromTabular[tab, "Rows"]
Wolfram Language code: Values[%]

直接获取值：

Wolfram Language code: FromTabular[tab, "Matrix"]

从无列键的 Tabular 对象中获取列：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}]

返回 TabularColumn 对象的列表：

Wolfram Language code: FromTabular[tab, "Columns"]

使它们标准化：

Wolfram Language code: Normal /@ %

直接从 Tabular 中获取列表：

Wolfram Language code: tab["ColumnList"]

从有列键的 Tabular 对象中获取列：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, {"a", "b", "c"}]

返回有列键的关联：

Wolfram Language code: FromTabular[tab, "Columns"]

使列标准化：

Wolfram Language code: Normal /@ %

获取列的列表：

Wolfram Language code: tab["ColumnList"]

获取带有列表项的 Tabular 对象：

Wolfram Language code: tab = Tabular[RandomInteger[10, {4, 3, 2}]]

"Rows" 和 "Columns" 形式都只影响 Tabular 对象的两个顶层：

Wolfram Language code: FromTabular[tab, "Rows"]//MatrixForm[#, TableDepth -> 2]&
Wolfram Language code: FromTabular[tab, "Columns"]//Normal//MatrixForm[#, TableDepth -> 2]&

数据集  (4)

从无列键的 Tabular 对象中获取 Dataset 表达式：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}]
Wolfram Language code: FromTabular[tab, "Dataset"]

使用 Dataset 获得相同的结果：

Wolfram Language code: Dataset[tab]

从有列键的 Tabular 对象中获取 Dataset 表达式：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, {"a", "b", "c"}]

列键被保留：

Wolfram Language code: FromTabular[tab, "Dataset"]

取一个带有键列的 Tabular 对象：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}}, <|"ColumnKeys" -> {"A", "b", "c"}, "KeyColumns" -> {"A"}|>]

键列转换为数据集的行键：

Wolfram Language code: FromTabular[tab, "Dataset"]

标准化以将键列项视为关联键：

Wolfram Language code: %//Normal

取带有两个键列的 Tabular 对象：

Wolfram Language code: tab = Tabular[{{1, 2, 3}, {4, 5, 6}, {7, 8, 9}}, <|"ColumnKeys" -> {"A", "B", "c"}, "KeyColumns" -> {"A", "B"}|>]

键列 "A" 和 "B" 转换为数据集嵌套层的键：

Wolfram Language code: FromTabular[tab, "Dataset"]

标准化以将键列项视为关联键：

Wolfram Language code: %//Normal

TimeSeries  (3)

将无列键的 Tabular 对象转换为 TimeSeries：

Wolfram Language code: tab = ToTabular[{{11, 22, 33}, {.1, .3, .2}, {"dog", "cat", "fox"}, {Yesterday, Today, Tomorrow}}, "Columns"]
Wolfram Language code: FromTabular[tab, "TimeSeries"]

The time stamps are taken to be the first column:

Wolfram Language code: Normal[%]

指定要使用哪些列来表示时间和值：

Wolfram Language code: FromTabular[tab, "TimeSeries", <|"TimeColumn" -> 4, "ValueColumns" -> {3, 1}|>]
Wolfram Language code: Normal[%]

将有列键的 Tabular 对象转换为 TimeSeries：

Wolfram Language code: tab = ToTabular[{"val1" -> {1, 2, 3}, "val2" -> {.1, .3, .2}, "val3" -> {"dog", "cat", "fox"}, "dates" -> {Yesterday, Today, Tomorrow}}, "Columns"]
Wolfram Language code: FromTabular[tab, "TimeSeries"]

默认时间戳取自键为 "dates" 的列：

使用列名指定要用于时间和值的列：

Wolfram Language code: FromTabular[tab, "TimeSeries", <|"TimeColumn" -> "dates", "ValueColumns" -> {"val2", "val3", "val1"}|>]
Wolfram Language code: Normal[%]

对含有列键的 Tabular 对象进行转换时，会将键保留为元素的键：

Wolfram Language code: tab = ToTabular[{"a" -> {1, 2, 3}, "b" -> {.1, .3, .2}, "c" -> {"dog", "cat", "fox"}, "d" -> {Yesterday, Today, Tomorrow}}, "Columns"]
Wolfram Language code: FromTabular[tab, "TimeSeries"]
Wolfram Language code: %//ColumnKeys

为元素指定新名称：

Wolfram Language code: FromTabular[tab, "TimeSeries", <|"ComponentNames" -> {"c1", "c2", "c3"}|>]
Wolfram Language code: %//ColumnKeys

TemporalData  (3)

将无列键的 Tabular 对象转换为 TemporalData：

Wolfram Language code: ToTabular[{{1, 2, 3}, {.1, .3, .2}, {"dog", "cat", "fox"}, {Yesterday, Today, Tomorrow}}, "Columns"]
Wolfram Language code: FromTabular[%, "TemporalData"]

每个列会被转换成一个路径，默认时间戳为正整数：

Wolfram Language code: Normal[%]

将有列键的 Tabular 对象转换为 TemporalData：

Wolfram Language code: ToTabular[{"a" -> {1, 2, 3}, "b" -> {.1, .3, .2}, "c" -> {"dog", "cat", "fox"}, "d" -> {Yesterday, Today, Tomorrow}}, "Columns"]

指定要用于时间和值的列：

Wolfram Language code: FromTabular[%, "TemporalData", <|"TimeColumn" -> 4, "ValueColumns" -> {"c", "a"}|>]
Wolfram Language code: Information[%]

将有 ExtendedKey 的 Tabular 对象转换为 TemporalData：

Wolfram Language code: tab = Tabular[...]
Wolfram Language code: ColumnKeys[tab]
Wolfram Language code: FromTabular[tab, "TemporalData", <|"TimeColumn" -> "Time"|>]

每列数据均已被转换为一条路径：

Wolfram Language code: %["PathNames"]

应用  (2)

销售数据  (1)

获取零售数据：

Wolfram Language code: data = Tabular[{...}]

使用 PivotToColumns 将各个城市的销售额分开：

Wolfram Language code: PivotToColumns[data, "City" -> "Sales"]

创建一个使用 "Date" 作为 "TimeColumn" 的 TemporalData：

Wolfram Language code: td = FromTabular[%, "TemporalData", <|"TimeColumn" -> "Date"|>]

列标题存储在 "MetaInformation" 中：

Wolfram Language code: td["MetaInformation"]

可视化销售时间序列：

Wolfram Language code: DateListPlot[td, PlotLegends -> Last /@ td["PathNames"]]

金融时间序列  (1)

获取一个金融时间序列的 Tabular：

Wolfram Language code: data = Tabular[{...}];

显示数据及其图表：

Wolfram Language code: GraphicsRow@{data, DateListPlot[data -> {"Date", "Value"}]}

使用 FromTabular 创建 TimeSeries：

Wolfram Language code: ts = FromTabular[data, "TimeSeries", <|"TimeColumn" -> "Date"|>]

拟合时间序列模型：

Wolfram Language code: TimeSeriesModelFit[ts, "ARIMA"]
Wolfram Language code: Normal[%]

属性和关系  (1)

FromTabular[tab,"Rows"] 和 FromTabular[tab,"Columns"] 的结果实际上是彼此的转置：

Wolfram Language code: tab = Tabular[{{1, "a", True}, {2, "b", False}}]
Wolfram Language code: FromTabular[tab, "Rows"]
Wolfram Language code: FromTabular[tab, "Columns"]//Normal
Wolfram Language code: Transpose[%] === %%

可能存在的问题  (2)

当列具有指定键时，FromTabular[...,"Columns"] 返回 Association：

Wolfram Language code: tab = Tabular[Transpose@{{1, 2, 3}, {"cat", "fox", "dog"}}, {"a", "b"}]
Wolfram Language code: FromTabular[tab, "Columns"]

直接从 Tabular 对象获取列的列表：

Wolfram Language code: tab["ColumnList"]

对于无列键的 Tabular，FromTabular[...,"Columns"] 返回一个列表：

Wolfram Language code: Tabular[Transpose@{{1, 2, 3}, {"cat", "fox", "dog"}}]
Wolfram Language code: FromTabular[%, "Columns"]

对于 "TemporalData" 形式，FromTabular 从列创建多个路径，但只允许一组时间戳：

Wolfram Language code: tab = ToTabular[{"a" -> {1, 2, 3}, "b" -> {.1, .3, .2}, "c" -> {"dog", "cat", "fox"}, "d" -> {Yesterday, Today, Tomorrow}}, "Columns"]

仅接受第一列：

Wolfram Language code: FromTabular[tab, "TemporalData", <|"TimeColumn" -> {"b", "d"}|>]
Wolfram Language code: %["Paths"]

更改顺序：

Wolfram Language code: FromTabular[tab, "TemporalData", <|"TimeColumn" -> {"d", "b"}|>]
Wolfram Language code: %["DatePaths"]
Wolfram Research (2025)，FromTabular，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FromTabular.html.

文本

Wolfram Research (2025)，FromTabular，Wolfram 语言函数，https://reference.wolfram.com/language/ref/FromTabular.html.

CMS

Wolfram 语言. 2025. "FromTabular." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/FromTabular.html.

APA

Wolfram 语言. (2025). FromTabular. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/FromTabular.html 年

BibTeX

@misc{reference.wolfram_2026_fromtabular, author="Wolfram Research", title="{FromTabular}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/FromTabular.html}", note=[Accessed: 12-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_fromtabular, organization={Wolfram Research}, title={FromTabular}, year={2025}, url={https://reference.wolfram.com/language/ref/FromTabular.html}, note=[Accessed: 12-November-2026]}