WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FunctionContinuous[f,x]

が x∈Realsについて実数値連続関数かどうかを調べる．

FunctionContinuous[f,x,dom]

が x∈dom について連続関数かどうかを調べる．

FunctionContinuous[{f1,f2,…},{x1,x2,…},dom]

が x1,x2,…∈dom について連続関数かどうかを調べる．

FunctionContinuous[{funs,cons},xvars,dom]

が制約条件 cons で制限された xvars∈dom について連続関数かどうかを調べる．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Assumptions  
GenerateConditions  
PerformanceGoal  
アプリケーション  
連続関数のクラス  
微積分  
確率  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

FunctionContinuous

FunctionContinuous[f,x]

が x∈Realsについて実数値連続関数かどうかを調べる．

FunctionContinuous[f,x,dom]

が x∈dom について連続関数かどうかを調べる．

FunctionContinuous[{f1,f2,…},{x1,x2,…},dom]

が x1,x2,…∈dom について連続関数かどうかを調べる．

FunctionContinuous[{funs,cons},xvars,dom]

が制約条件 cons で制限された xvars∈dom について連続関数かどうかを調べる．

詳細とオプション

  • すべての とすべての について，すべての についてTemplateBox[{{x, -, y}}, Abs]<delta(x,epsilon) がTemplateBox[{{{f, (, x, )}, -, {f, (, y, )}}}, Abs]<epsilon を含意するような が存在するなら，関数 は集合 において連続である．
  • すべての とすべての について，すべての についてTemplateBox[{{{, {{{x, _, 1}, -, {y, _, 1}}, ,, ..., ,, {{x, _, n}, -, {y, _, n}}}, }}}, Norm]<delta({x_1,...,x_n},epsilon)がTemplateBox[{{{f, (, {{, {{x, _, 1}, ,, ..., ,, {x, _, n}}, }}, )}, -, {f, (, {{, {{y, _, 1}, ,, ..., ,, {y, _, n}}, }}, )}}}, Abs]<epsilon を含意するような が存在するなら，関数 は集合 において連続である．
  • funs に xvars 以外のパラメータが含まれているなら，結果は，通常は，ConditionalExpressionである．
  • dom の可能な値はRealsとComplexesである．デフォルトはRealsである．
  • dom がRealsなら，すべての変数，パラメータ，定数，関数の値は実数であるように制限される．
  • cons には，等式，不等式，それらの論理結合が含まれていてよい．
  • 関数 funs は制約条件 cons を満足するすべての値について定義されなければならない．
  • 次は，使用可能なオプションである．
  • Assumptions $Assumptionsパラメータについての仮定
    GenerateConditions Trueパラメータについての条件を生成するかどうか
    PerformanceGoal $PerformanceGoal速度と品質のどちらを優先させるか
  • 次は，GenerateConditionsの可能な設定である．
  • Automatic一般的ではない条件のみ
    Trueすべての条件
    False条件なし
    None条件が必要な場合は未評価で返す
  • PerformanceGoalの可能な値には"Speed"と"Quality"がある．

例題

すべて開く すべて閉じる

例  (4)

実関数の連続性を検証する：

Wolfram Language code: FunctionContinuous[Sin[x], x]

複素関数の連続性を検証する：

Wolfram Language code: FunctionContinuous[Sqrt[x], x, Complexes]

限定された領域上で連続性を検証する：

Wolfram Language code: FunctionContinuous[{Log[x], x > 0}, x]

多変量関数の連続性を検証する：

Wolfram Language code: FunctionContinuous[Gamma[x ^ 2 + y ^ 2 + 1, E ^ (x y)], {x, y}]

スコープ  (6)

一変量実関数：

Wolfram Language code: FunctionContinuous[Tanh[x], x]
Wolfram Language code: FunctionContinuous[Floor[x], x]
Wolfram Language code: Plot[{Tanh[x], Floor[x]}, {x, -3, 3}]

一変量複素関数：

Wolfram Language code: FunctionContinuous[Exp[z], z, Complexes]
Wolfram Language code: FunctionContinuous[Log[z], z, Complexes]
Wolfram Language code: GraphicsRow[ComplexPlot[#, {z, -2 - 2I, 2 + 2I}]& /@ {Exp[z], Log[z]}, ImageSize -> Medium]

領域が限定されている関数：

Wolfram Language code: FunctionContinuous[{Tan[x], -Pi / 2 < x < Pi / 2}, x]
Wolfram Language code: FunctionContinuous[{Log[z], Im[z] ≠ 0}, z]

多変量実関数：

Wolfram Language code: FunctionContinuous[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], {x, y}]
Wolfram Language code: FunctionContinuous[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 - 1)], {x, y}]
Wolfram Language code: GraphicsRow[Plot3D[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + #)], {x, -2, 2}, {y, -2, 2}]& /@ {1, -1}, ImageSize -> Medium]

多変量複素関数：

Wolfram Language code: FunctionContinuous[LaguerreL[E ^ (x + z), Sin[y z]], {x, y, z}, Complexes]
Wolfram Language code: FunctionContinuous[Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], {x, y}, Complexes]
Wolfram Language code: FunctionContinuous[{Erf[Sin[x + y] / (x ^ 2 + y ^ 2 + 1)], x ^ 2 + y ^ 2 ≠ -1}, {x, y}, Complexes]

記号パラメータの関数：

Wolfram Language code: FunctionContinuous[Gamma[x ^ 2 + a], x]
Wolfram Language code: FunctionContinuous[Sin[x y] / (x ^ 2 + a x y + y ^ 2 + b), {x, y}]

オプション  (4)

Assumptions  (1)

FunctionContinuousはパラメータ の任意の値については答を求められない：

Wolfram Language code: FunctionContinuous[Sin[x + y] / (Exp[x y] + a), {x, y}]

という仮定があればFunctionContinuousは成功する：

Wolfram Language code: FunctionContinuous[Sin[x + y] / (Exp[x y] + a), {x, y}, Assumptions -> a > 0]

GenerateConditions  (2)

デフォルトで，FunctionContinuousは記号パラメータについての条件を生成することがある：

Wolfram Language code: FunctionContinuous[Log[x ^ 2 + a], x]

GenerateConditionsNoneのときは，FunctionContinuousは条件付きの結果を与えるのではなく失敗する：

Wolfram Language code: FunctionContinuous[Log[x ^ 2 + a], x, GenerateConditions -> None]

以下は条件的に有効な結果を条件を述べずに返す：

Wolfram Language code: FunctionContinuous[Log[x ^ 2 + a], x, GenerateConditions -> False]

デフォルトで，すべての条件が報告される：

Wolfram Language code: FunctionContinuous[Cos[x y] / a, {x, y}]

GenerateConditionsAutomaticとすると，一般的に真である条件は報告されない：

Wolfram Language code: FunctionContinuous[Cos[x y] / a, {x, y}, GenerateConditions -> Automatic]

PerformanceGoal  (1)

PerformanceGoalを使って潜在的に高く付く計算を避ける：

Wolfram Language code: FunctionContinuous[1 / (x ^ 4 + a x ^ 3 y + b x y ^ 3 + y ^ 4 + c), {x, y}, PerformanceGoal -> "Speed"]

デフォルト設定は使用可能なあらゆるテクニックを使って結果を出そうとする：

Wolfram Language code: FunctionContinuous[1 / (x ^ 4 + a x ^ 3 y + b x y ^ 3 + y ^ 4 + c), {x, y}]

アプリケーション  (14)

連続関数のクラス  (6)

多項式は連続である：

Wolfram Language code: {FunctionContinuous[x, x], FunctionContinuous[x^2 + 1, x], FunctionContinuous[x^3 - 2 x^2 - 5 x + 6, x]}

Sin，Cos，Expは連続である：

Wolfram Language code: {FunctionContinuous[Sin[x], x], FunctionContinuous[Cos[x], x], FunctionContinuous[Exp[x], x]}

これらの関数を可視化する：

Wolfram Language code: Grid[Partition[Table[Plot[f, {x, -5, 5}], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}], 3]]

これらの関数は，複素平面上でも連続である：

Wolfram Language code: Table[FunctionContinuous[f, x, Complexes], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}]

これらの関数をTemplateBox[{}, Complexes]上で可視化する：

Wolfram Language code: Grid[Partition[Table[ComplexPlot3D[f, {x, 5}], {f, {x, x^2 + 1, x^3 - 2 x^2 - 5 x + 6, Sin[x], Cos[x], Exp[x]}}], 3]]

連続関数 の逆数は であるところではどこでも連続である：

Wolfram Language code: FunctionContinuous[{(1/x), x ≠ 0}, x]

したがって，有理関数は実数上で連続であることもあれば連続でないこともある：

Wolfram Language code: FunctionContinuous[(4/x^2 + 4), x]
Wolfram Language code: FunctionContinuous[(1/x^2 - 4), x]
Wolfram Language code: Plot[{(4/x^2 + 4), (1/x^2 - 4)}, {x, -4, 4}, PlotTheme -> {"DashedLines", "Detailed"}]

しかし，すべての非定数多項式が平面上に根を持つため，有理関数はTemplateBox[{}, Complexes]上では決して連続ではない：

Wolfram Language code: FunctionContinuous[(4/x^2 + 4), x, Complexes]

複素平面上で関数を可視化すると に爆発があるのが分かる：

Wolfram Language code: ComplexPlot3D[(4/x^2 + 4), {x, 4}]

CotとCscはSinとCosの有理関数なので，これらの関数は正弦が非零のところでは連続である：

Wolfram Language code: {FunctionContinuous[{Cot[x], (x/π)∉ℤ}, x], FunctionContinuous[{Csc[x], (x/π)∉ℤ}, x]}

これらの関数を正弦とともに可視化する：

Wolfram Language code: Plot[{Cot[x], Csc[x], Sin[x]}, {x, -3π, 3π}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

同様に，TanとSecは余弦が非零のときは連続である：

Wolfram Language code: {FunctionContinuous[{Tan[x], (x/π) - (1/2)∉ℤ}, x], FunctionContinuous[{Sec[x], (x/π) - (1/2)∉ℤ}, x]}
Wolfram Language code: Plot[{Tan[x], Sec[x], Cos[x]}, {x, -3π, 3π}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

これと同じ原理が双曲線三角関数のCothとCschにも当てはまる：

Wolfram Language code: {FunctionContinuous[{Coth[x], x ≠ 0}, x], FunctionContinuous[{Csch[x], x ≠ 0}, x]}

これらの関数をSinhとともに可視化する：

Wolfram Language code: Plot[{Coth[x], Csch[x], Sinh[x]}, {x, -3, 3}, PlotLegends -> "Expressions", PlotTheme -> "DashedLines"]

Coshは決して零にはならないので，残りの2つの関数のTanhとSechも連続である：

Wolfram Language code: Reduce[Cosh[x] == 0, x, Reals]
Wolfram Language code: {FunctionContinuous[Tanh[x], x], FunctionContinuous[Sech[x], x]}

連続関数の複合関数は連続である：

Wolfram Language code: FunctionContinuous[Sin[x ^ 2 + 3x + 2], x]
Wolfram Language code: FunctionContinuous[Exp[Sin[x]], x]
Wolfram Language code: FunctionContinuous[Cos[Sin[x]]^2 + Sin[x]Cos[x] + Exp[-x], x]

非連続関数 と連続関数 の複合関数は， が定義域を の連続小領域に写像する限り連続である．例として， をSqrtとしよう．Sqrtは実数上で不連続である：

Wolfram Language code: FunctionContinuous[Sqrt[x], x]

しかし，TemplateBox[{}, PositiveReals]では連続である：

Wolfram Language code: FunctionContinuous[{Sqrt[x], x > 0}, x]

ExpはTemplateBox[{}, Reals]->TemplateBox[{}, PositiveReals]に写像する：

Wolfram Language code: FunctionRange[E^x, x, y]

したがって，SqrtとExpの合成関数はTemplateBox[{}, Reals]上で連続である：

Wolfram Language code: FunctionContinuous[Sqrt[E^x], x]
Wolfram Language code: FunctionContinuous[x ^ (3 / 2), x]

多変量多項式は実数と複素数上で連続である：

Wolfram Language code: {FunctionContinuous[x ^ 2 + 3x y - 7y ^ 2, {x, y}], FunctionContinuous[x ^ 2 + 3x y - 7y ^ 2, {x, y}, ℂ]}

多変量有理関数は実数上で連続のこともあれば連続ではないこともある：

Wolfram Language code: {FunctionContinuous[(x^2 - y^2/x^2 + y^2 + 1), {x, y}], FunctionContinuous[(x^2 - y^2 + 1/x^2 - y), {x, y}]}

複素数上では常に不連続である：

Wolfram Language code: FunctionContinuous[(x^2 - y^2/x^2 + y^2 + 1), {x, y}, ℂ]

不連続有理関数が連続関数に拡張されることもある：

Wolfram Language code: f[x_, y_] := ( -6 + 8 x - 2 x^2 + 5 y - 6 x y + x^2 y - y^2 + x y^2/5 - 2 x + x^2 - 4 y + y^2) g[x_, y_] := Piecewise[{{0, x == 1 && y == 2}, {f[x, y], True}}]
Wolfram Language code: {FunctionContinuous[f[x, y], {x, y}], FunctionContinuous[g[x, y], {x, y}]}

一変量連続関数と合成することで，より連続的な関数が生成される：

Wolfram Language code: {FunctionContinuous[ArcTan[x ^ 2 + 3x y - 7y ^ 2], {x, y}], FunctionContinuous[Cos[(x^2 - y^2/x^2 + y^2 + 1)], {x, y}], FunctionContinuous[Sin[(x^2 - y^2/Exp[x^2 - y])], {x, y}]}

連続関数を可視化する：

Wolfram Language code: Grid[Partition[Table[Plot3D[f, {x, -5, 5}, {y, -5, 5}, PlotRange -> All, Exclusions -> None, ImageSize -> 165], {f, {x ^ 2 + 3x y + 7y ^ 2, (x^2 - y^2/x^2 + y^2 + 1), g[x, y], ArcTan[x ^ 2 + 3x y - 7y ^ 2], Cos[(x^2 - y^2/x^2 + y^2 + 1)], Sin[(x^2 - y^2 + 1/Exp[x^2 - y])]}}], 3]]

微積分  (5)

連続関数の極限は代入によって計算される：

Wolfram Language code: {FunctionContinuous[Cosh[x], x], Underscript[, x -> 0]Cosh[x], Cosh[0]}
Wolfram Language code: {FunctionContinuous[ArcTan[x], x], Underscript[, x -> 1]ArcTan[x], ArcTan[1]}
Wolfram Language code: {FunctionContinuous[BesselJ[1, x], x], Underscript[, x -> 1]BesselJ[1, 0], BesselJ[1, 0]}

関数とは零以外の実線上で一致する：

Wolfram Language code: Reduce[(Sin[x]/x) == Sinc[x], x, Reals]

Sincは連続である：

Wolfram Language code: FunctionContinuous[Sinc[x], x]
Wolfram Language code: {Sinc[0], Underscript[, x -> 0]Sinc[x]}

関数は連続ではない：

Wolfram Language code: FunctionContinuous[(Sin[x]/x), x]

特に，原点で連続ではないので，その極限は代入では計算できない：

Wolfram Language code: FunctionDiscontinuities[(Sin[x]/x), x]

この2つの関数は について等しいので，そこで同じ極限を持つ：

Wolfram Language code: Underscript[, x -> 0](Sin[x]/x) == Underscript[, x -> 0]Sinc[x]

次の関数は不連続である：

Wolfram Language code: f[x_] := Exp[-(1/x^2)]
Wolfram Language code: FunctionContinuous[f[x], x]

これは原点でのみ不連続である：

Wolfram Language code: FunctionDiscontinuities[f[x], x]

この不連続点は がそこで定義されていないことによる：

Wolfram Language code: f[0]

しかし， は のとき極限を持つ：

Wolfram Language code: Limit[f[x], x -> 0]

を の原点までの拡張として定義する：

Wolfram Language code: g[x_] := Piecewise[{{f[x], x != 0}, {0, x == 0}}]

この拡張は連続関数である：

Wolfram Language code: FunctionContinuous[g[x], x]

を可視化する：

Wolfram Language code: Plot[g[x], {x, -10, 10}, PlotRange -> All]

関数 は連続である：

Wolfram Language code: h[x_] := Piecewise[{{x*Sin[1/x], x != 0}, {0, x == 0}}]
Wolfram Language code: FunctionContinuous[h[x], x]

しかし，第1導関数は連続ではない：

Wolfram Language code: FunctionContinuous[h'[x], x]

したがって， は解析的ではない：

Wolfram Language code: FunctionAnalytic[h[x], x]

は滑らかに零まで行くが，その導関数は原点で激しく振動する：

Wolfram Language code: {MinLimit[h'[x], x -> 0], MaxLimit[h'[x], x -> 0]}

とその第1導関数を可視化する：

Wolfram Language code: Plot[{h[x], h'[x]}, {x, -1, 1}, PlotRange -> {-4, 4}, PlotTheme -> "DashedLines"]

有界の関数 の定積分は，たとえ が不連続でも連続である．次の について考える：

Wolfram Language code: f[x_] := Piecewise[{{-x + 1, x < 0}, {x, 0 < x < 1}, {x ^ 2, True}}]

これは不連続である：

Wolfram Language code: FunctionContinuous[f[x], x]

がその定積分の原点から任意の実数値までであると定義する：

Wolfram Language code: g[x_] = Integrate[f[t], {t, 0, x}, Assumptions -> x∈Reals];

関数 は連続である：

Wolfram Language code: FunctionContinuous[g[x], x]

この関数とその積分を可視化する：

Wolfram Language code: Plot[{f[x], g[x]}, {x, -2, 2}, PlotTheme -> {"Detailed", "DashedLines"}]

確率  (3)

連続確率分布のCDFは連続である：

Wolfram Language code: cdf1 = CDF[NormalDistribution[], x]; cdf2 = CDF[BetaDistribution[3, 1], x]; cdf3 = CDF[BinormalDistribution[0], {x, y}];
Wolfram Language code: {FunctionContinuous[cdf1, x], FunctionContinuous[cdf2, x], FunctionContinuous[cdf3, {x, y}]}

この関数を可視化する：

Wolfram Language code: Grid[{{Plot[cdf1, {x, -5, 5}], Plot[cdf2, {x, -5, 5}], Plot3D[cdf3, {x, -5, 5}, {y, -5, 5}]}}]

離散分布のCDFは不連続である：

Wolfram Language code: cdfs = {CDF[PoissonDistribution[1], n], CDF[BernoulliDistribution[(1/2)], n], CDF[GeometricDistribution[1 / 2], n]};
Wolfram Language code: Table[FunctionContinuous[cdf, n], {cdf, cdfs}]

これらの分布は区分定数累積分布関数を持つ：

Wolfram Language code: Table[Plot[cdf, {n, -5, 5}, ExclusionsStyle -> Dashed], {cdf, cdfs}]

混合分布のCDFは不連続である：

Wolfram Language code: cdf1 = CDF[CensoredDistribution[{-1, 2}, CauchyDistribution[0, 1]], x]; cdf2 = CDF[CensoredDistribution[{-1, 1}, NormalDistribution[]], x]; cdf3 = CDF[CensoredDistribution[{{-∞, 1 / 2}, {1 / 3, 3 / 5}}, BinormalDistribution[0]], {x, y}];
Wolfram Language code: {FunctionContinuous[cdf1, x], FunctionContinuous[cdf2, x], FunctionContinuous[cdf3, {x, y}]}

これらの分布は区分的ではあるが連続ではない累積分布関数を持つ：

Wolfram Language code: Grid[{{Plot[cdf1, {x, -5, 5}, ExclusionsStyle -> ColorData[106][2]], Plot[cdf2, {x, -5, 5}, ExclusionsStyle -> ColorData[106][2]], Plot3D[cdf3, {x, -5, 5}, {y, -5, 5}]}}]

特性と関係  (3)

連続関数の極限は定義域上の各点でその値と等しい：

Wolfram Language code: f = Sin[2 ^ x] ^ 2 + x / 3;
Wolfram Language code: FunctionContinuous[f, x]

Limitを使って極限を計算する：

Wolfram Language code: Limit[f, x -> 1] == (f /. x -> 1)

ある区間内で連続な関数はその最小値と最大値の間の各値に達する：

Wolfram Language code: f = Log[Cos[3x E ^ x] ^ 2 + 2x];
Wolfram Language code: FunctionContinuous[{f, 0 ≤ x ≤ 1}, x]

MinimizeとMaximizeを使って最小値と最大値を求める：

Wolfram Language code: {min, pmin} = Minimize[{f, 0 ≤ x ≤ 1}, x]
Wolfram Language code: {max, pmax} = Maximize[{f, 0 ≤ x ≤ 1}, x]

が最小値と最大値の間にあることを確認する：

Wolfram Language code: min < 1 / 2 < max

Solveを使って が値に達する点を求める：

Wolfram Language code: sols = Solve[f == 1 / 2 && 0 ≤ x ≤ 1, x]

特性を図示する：

Wolfram Language code: Plot[{f, 1 / 2}, {x, 0, 1}, Rule[...]]

FunctionAnalyticを使って関数が解析的かどうかをチェックする：

Wolfram Language code: f = 2 ^ Sin[x ^ 2 + 7] - x;
Wolfram Language code: FunctionAnalytic[f, x]

解析的関数は連続である：

Wolfram Language code: FunctionContinuous[f, x]

連続関数は解析的ではないことがある：

Wolfram Language code: FunctionContinuous[Abs[x], x]
Wolfram Language code: FunctionAnalytic[Abs[x], x]

考えられる問題  (2)

関数が連続であるためにはあらゆるところで定義されなければならない：

Wolfram Language code: FunctionContinuous[Sin[x] / x, x]
Wolfram Language code: FunctionContinuous[{Sin[x] / x, x ≠ 0}, x]
Wolfram Language code: FunctionContinuous[Sinc[x], x]

関数が実領域で連続であるためには，その関数は実数値でなければならない：

Wolfram Language code: FunctionContinuous[Sqrt[x], x]
Wolfram Language code: FunctionContinuous[{Sqrt[x], x ≥ 0}, x]
Wolfram Research (2020), FunctionContinuous, Wolfram言語関数， https://reference.wolfram.com/language/ref/FunctionContinuous.html.

テキスト

Wolfram Research (2020), FunctionContinuous, Wolfram言語関数， https://reference.wolfram.com/language/ref/FunctionContinuous.html.

CMS

Wolfram Language. 2020. "FunctionContinuous." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionContinuous.html.

APA

Wolfram Language. (2020). FunctionContinuous. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FunctionContinuous.html

BibTeX

@misc{reference.wolfram_2026_functioncontinuous, author="Wolfram Research", title="{FunctionContinuous}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FunctionContinuous.html}", note=[Accessed: 06-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_functioncontinuous, organization={Wolfram Research}, title={FunctionContinuous}, year={2020}, url={https://reference.wolfram.com/language/ref/FunctionContinuous.html}, note=[Accessed: 06-October-2026]}