WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FunctionConvexity[f,{x1,x2,…}]

実数上の変数 x1,x2,…を持つ関数 f の凸性を求める．

FunctionConvexity[{f,cons},{x1,x2,…}]

変数が凸領域を表す条件 cons で制約されているときの凸性を求める．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
Assumptions  
GenerateConditions  
PerformanceGoal  
StrictInequalities  
アプリケーション  
基本的なアプリケーション  
微積分  
幾何  
最適化  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

FunctionConvexity

FunctionConvexity[f,{x1,x2,…}]

実数上の変数 x1,x2,…を持つ関数 f の凸性を求める．

FunctionConvexity[{f,cons},{x1,x2,…}]

変数が凸領域を表す条件 cons で制約されているときの凸性を求める．

詳細とオプション

  • 凸性は，凸，凹，狭義凸，狭義凹としても知られている．
  • デフォルトで，次の定義が使われる．
  • +1凸，つまり，すべてのおよびすべての と について
    0アフィン ，つまり，すべてのとすべての と について
    -1凹，つまり，すべてのとすべての と について
    Indeterminate凸でも凹でもない
  • アフィン関数は凸かつ凹である．
  • StrictInequalitiesTrueと設定すると，以下の定義が使われる．
  • +1狭義凸，つまり，すべての およびすべての と について ，ただし
    -1狭義凹，つまり，すべてのおよびすべての と について ，ただし
    Indeterminate狭義凸でも狭義凹でもない
  • 関数 は，制約条件 cons を満足するすべての実数値の について実数値関数でなければならない．
  • cons は，凸領域を表す等式，不等式，それらの論理結合を含むことができる．
  • 次は，使用可能なオプションである．
  • Assumptions $Assumptionsパラメータについての仮定
    GenerateConditions Automaticパラメータについての条件を生成するかどうか
    PerformanceGoal $PerformanceGoal速度あるいは品質を優先するかどうか
    StrictInequalities False狭義凸性を必要とするかどうか
  • 次は，GenerateConditionsの可能な設定である．
  • Automatic一般的ではない条件のみ
    Trueすべての条件
    False条件なし
    None条件が必要な場合は未評価で返す
  • PerformanceGoalの可能な設定は"Speed"と"Quality"である．

例題

すべて開く すべて閉じる

例  (3)

一変量関数の凸性を求める：

Wolfram Language code: FunctionConvexity[Abs[x], x]

多変量関数の凸性を求める：

Wolfram Language code: FunctionConvexity[-Exp[x + y], {x, y}]

変数が条件によって制約されている関数の凸性を求める：

Wolfram Language code: FunctionConvexity[{x ^ 3 + y ^ 3, x ≥ 0 && y ≥ 0}, {x, y}]

スコープ  (7)

一変量関数：

Wolfram Language code: FunctionConvexity[Sin[x], x]
Wolfram Language code: FunctionConvexity[2 ^ x, x]
Wolfram Language code: FunctionConvexity[x - Sqrt[x ^ 2], x]
Wolfram Language code: Plot[{Sin[x], 2 ^ x, x - Sqrt[x ^ 2]}, {x, -3, 3}]

実数値ではない関数はIndeterminateの凸性を持つ：

Wolfram Language code: FunctionConvexity[Log[x], x]

この関数は正の について実数値で凸である：

Wolfram Language code: FunctionConvexity[{Log[x], x > 0}, x]

変数に制約条件がある一変量関数：

Wolfram Language code: FunctionConvexity[{Sin[x], 0 ≤ x ≤ Pi}, x]
Wolfram Language code: FunctionSign[{x - Sqrt[x ^ 2], x ≥ 0}, x]

関数の狭義凸性：

Wolfram Language code: FunctionConvexity[Abs[x], x, StrictInequalities -> True]
Wolfram Language code: FunctionConvexity[x ^ 2 Abs[x], x, StrictInequalities -> True]

TemplateBox[{x}, Abs]は凸であるが狭義の凸ではない．x^2 TemplateBox[{x}, Abs]は狭義の凸である：

Wolfram Language code: Plot[{Abs[x], x ^ 2Abs[x]}, {x, -2, 2}]

多変量関数：

Wolfram Language code: FunctionConvexity[x ^ 2 + y ^ 2, {x, y}]
Wolfram Language code: Plot3D[x ^ 2 + y ^ 2, {x, -2, 2}, {y, -2, 2}]
Wolfram Language code: FunctionConvexity[x ^ 2 - y ^ 2, {x, y}]
Wolfram Language code: Plot3D[x ^ 2 - y ^ 2, {x, -2, 2}, {y, -2, 2}]

変数に制約条件がある多変量関数：

Wolfram Language code: FunctionConvexity[{x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, -2 < x < 2 && -2 < y < 2}, {x, y}]
Wolfram Language code: Plot3D[x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, {x, -2, 2}, {y, -2, 2}]

別の領域では同じ関数が凸になる：

Wolfram Language code: FunctionConvexity[{x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, 0 < x < 2 && y > 0}, {x, y}]
Wolfram Language code: Plot3D[x ^ 3 + x ^ 2 y ^ 2 + y ^ 3, {x, 0, 2}, {y, 0, 2}]

記号パラメータを持つ関数：

Wolfram Language code: FunctionConvexity[a x ^ 2 + b x + c, x]
Wolfram Language code: FunctionConvexity[x ^ 2 + a x y + y ^ 2, {x, y}]

オプション  (5)

Assumptions  (1)

FunctionConvexityは以下では条件付きの答を返す：

Wolfram Language code: FunctionConvexity[x ^ 4 + a x ^ 2, x]

の値についての凸性をチェックする：

Wolfram Language code: FunctionConvexity[x ^ 4 + a x ^ 2, x, Assumptions -> a < 0]

GenerateConditions  (2)

デフォルトで，FunctionConvexityは記号パラメータについての条件を生成することがある：

Wolfram Language code: FunctionConvexity[a x ^ 2 + b y ^ 2, {x, y}]

GenerateConditionsNoneとすると，FunctionConvexityは条件付きの結果を返さずに失敗する：

Wolfram Language code: FunctionConvexity[a x ^ 2 + b y ^ 2, {x, y}, GenerateConditions -> None]

以下は条件付きで有効な結果を条件を述べずに返す：

Wolfram Language code: FunctionConvexity[a x ^ 2 + b y ^ 2, {x, y}, GenerateConditions -> False]

デフォルトで，すべての条件が報告される：

Wolfram Language code: FunctionConvexity[E ^ x / a ^ 2, x]

GenerateConditionsAutomaticとすると，一般的に真である条件は報告されない：

Wolfram Language code: FunctionConvexity[E ^ x / a ^ 2, x, GenerateConditions -> Automatic]

PerformanceGoal  (1)

PerformanceGoalを使って潜在的に高価な計算を避ける：

Wolfram Language code: FunctionConvexity[x ^ 6 + a x ^ 2 y ^ 4 + b x ^ 4 y ^ 2 + y ^ 6, {x, y}, PerformanceGoal -> "Speed"]

デフォルト設定は使用可能なすべてのテクニックを使って答を出そうとする：

Wolfram Language code: FunctionConvexity[x ^ 6 + a x ^ 2 y ^ 4 + b x ^ 4 y ^ 2 + y ^ 6, {x, y}]

StrictInequalities  (1)

デフォルトで，FunctionConvexityは狭義ではない凸性を計算する：

Wolfram Language code: FunctionConvexity[#, {x, y}]& /@ {x ^ 2, x ^ 2 + y ^ 2}

StrictInequalitiesTrueとすると，FunctionConvexityは狭義の符号を計算する：

Wolfram Language code: FunctionConvexity[#, {x, y}, StrictInequalities -> True]& /@ {x ^ 2, x ^ 2 + y ^ 2}

は凸だが狭義の凸ではない．は狭義の凸である：

Wolfram Language code: GraphicsRow[Plot3D[#, {x, -2, 2}, {y, -2, 2}]& /@ {x ^ 2, x ^ 2 + y ^ 2}, ImageSize -> 400]

アプリケーション  (17)

基本的なアプリケーション  (8)

の凸性をチェックする：

Wolfram Language code: FunctionConvexity[x ^ 2 - 1, x]

グラフ上の任意の2点を繋ぐ線分はそのグラフの上にある：

Wolfram Language code: Plot[x ^ 2 - 1, {x, -5, 5}, Rule[...]]

の凸性をチェックする：

Wolfram Language code: FunctionConvexity[x - E ^ x, x]

グラフ上の任意の2点を繋ぐ線分はそのグラフの下にある：

Wolfram Language code: Plot[x - E ^ x, {x, -3, 3}, Rule[...]]

の凸性をチェックする：

Wolfram Language code: FunctionConvexity[Sin[x], x]

は凸関数でも凹関数でもない：

Wolfram Language code: Plot[Sin[x], {x, -3Pi, 3Pi}, Rule[...]]

に制限されたは狭義の凹関数であることを示す：

Wolfram Language code: FunctionConvexity[{Sin[x], 0 ≤ x ≤ Pi}, x, StrictInequalities -> True]

TemplateBox[{x}, Abs]は凸だが狭義の凸ではない：

Wolfram Language code: FunctionConvexity[Abs[x], x]
Wolfram Language code: FunctionConvexity[Abs[x], x, StrictInequalities -> True]
Wolfram Language code: Plot[Abs[x], {x, -5, 5}, Rule[...]]

正の実数に制限されるTemplateBox[{x}, Abs]はアフィン関数である：

Wolfram Language code: FunctionConvexity[{Abs[x], x > 0}, x]

TemplateBox[{Norm, paclet:ref/Norm}, RefLink, BaseStyle -> {InlineFormula}][v,p]はについて凸だが狭義の凸ではない：

Wolfram Language code: FunctionConvexity[Norm[{x, y}, p], {x, y}, Assumptions -> p ≥ 1]
Wolfram Language code: FunctionConvexity[Norm[{x, y, z}, Infinity], {x, y, z}]
Wolfram Language code: FunctionConvexity[Norm[{x, y}, p], {x, y}, Assumptions -> p ≥ 1, StrictInequalities -> True]
Wolfram Language code: Plot3D[{Norm[{x, y}, 1], Norm[{x, y}, 2], Norm[{x, y}, Infinity]}, ...]

凸性が の関数の和は凸性 を有する：

Wolfram Language code: f = x ^ 2 + Sin[x]; g = x Erf[x] + E ^ (-x ^ 2);
Wolfram Language code: FunctionConvexity[f, x]
Wolfram Language code: FunctionConvexity[g, x]
Wolfram Language code: FunctionConvexity[f + g, x]
Wolfram Language code: Plot[{f, g, f + g}, {x, -3, 3}]

凸関数の否定は凹関数である：

Wolfram Language code: f = E ^ (x ^ 2);
Wolfram Language code: FunctionConvexity[f, x]
Wolfram Language code: FunctionConvexity[-f, x]
Wolfram Language code: Plot[{f, -f}, {x, -2, 2}]

凸関数の最大値は凸である：

Wolfram Language code: f = 3Abs[x]; g = E ^ x;
Wolfram Language code: FunctionConvexity[f, x]
Wolfram Language code: FunctionConvexity[g, x]
Wolfram Language code: FunctionConvexity[Max[f, g], x]
Wolfram Language code: Plot[{f, g, Max[f, g]}, {x, -2, 2}]

アフィン関数は凸であり凹である．したがって，その最大値は凸である：

Wolfram Language code: aff = Table[RandomReal[{-1, 1}]x + RandomReal[{-1, 1}]y + RandomReal[], {10}];
Wolfram Language code: FunctionConvexity[Max@@aff, {x, y}]
Wolfram Language code: Plot3D[Evaluate[Max@@aff], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

アフィン関数の最小値は凹である：

Wolfram Language code: FunctionConvexity[Min@@aff, {x, y}]
Wolfram Language code: Plot3D[Evaluate[Min@@aff], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

二次の TemplateBox[{x}, Transpose].A.x は が半正定値であるときかつそのときに限って凸である：

Wolfram Language code: Subscript[A, 1] = {{1, 2}, {3, 4}}; Subscript[f, 1] = {x, y}.Subscript[A, 1].{x, y};
Wolfram Language code: PositiveSemidefiniteMatrixQ[Subscript[A, 1]]
Wolfram Language code: FunctionConvexity[Subscript[f, 1], {x, y}]
Wolfram Language code: Plot3D[Subscript[f, 1], {x, -1, 1}, {y, -1, 1}, Mesh -> None]
Wolfram Language code: Subscript[A, 2] = {{1, -2}, {3, 4}}; Subscript[f, 2] = {x, y}.Subscript[A, 2].{x, y};
Wolfram Language code: PositiveSemidefiniteMatrixQ[Subscript[A, 2]]
Wolfram Language code: FunctionConvexity[Subscript[f, 2], {x, y}]
Wolfram Language code: Plot3D[Subscript[f, 2], {x, -1, 1}, {y, -1, 1}, Mesh -> None]

微積分  (2)

が非減少なら， は の凸関数である：

Wolfram Language code: f = 5t + Cos[5t];
Wolfram Language code: FunctionMonotonicity[f, t]
Wolfram Language code: Plot[f, {t, -3, 3}]
Wolfram Language code: g = Integrate[f, {t, 0, x}]
Wolfram Language code: FunctionConvexity[g, x]
Wolfram Language code: Plot[g, {x, -3, 3}]

凸関数の導関数は非減少である：

Wolfram Language code: f = E ^ -x + 25x ^ 2 + Sin[5x] - 100;
Wolfram Language code: FunctionConvexity[f, x]
Wolfram Language code: df = D[f, x]
Wolfram Language code: FunctionMonotonicity[df, x]

凸関数の第2導関数は非負である：

Wolfram Language code: ddf = D[df, x]
Wolfram Language code: FunctionSign[ddf, x]
Wolfram Language code: Plot[{f, df, ddf}, {x, -5, 5}]

幾何  (4)

が凸関数TemplateBox[{}, Reals]^n->TemplateBox[{}, Reals]なら，領域{x in TemplateBox[{}, Reals]^n|f(x)<=c}は凸である：

Wolfram Language code: f = Log[3 ^ (x + 2 y) + Exp[y + z]] + x ^ 2 + y ^ 2 + z ^ 2;
Wolfram Language code: FunctionConvexity[f, {x, y, z}]

ConvexRegionQを使ってが凸領域であることを確かめる：

Wolfram Language code: reg = ImplicitRegion@@{f ≤ 1, {x, y, z}};
Wolfram Language code: ConvexRegionQ[reg]
Wolfram Language code: RegionPlot3D[f ≤ 1, ...]

が凹関数TemplateBox[{}, Reals]^n->TemplateBox[{}, Reals]なら，領域{x in TemplateBox[{}, Reals]^n|f(x)>=c}は凸である：

Wolfram Language code: f = 3 - Exp[Norm[{x, y}, 3]];
Wolfram Language code: FunctionConvexity[f, {x, y}]

ConvexRegionQを使ってが凸領域であることを確かめる：

Wolfram Language code: reg = ImplicitRegion@@{f ≥ 1, {x, y}};
Wolfram Language code: ConvexRegionQ[reg]
Wolfram Language code: RegionPlot[f ≥ 1, {x, -1, 1}, {y, -1, 1}]

が凸関数なら，エピグラフは凸集合である：

Wolfram Language code: f = Cosh[x];
Wolfram Language code: FunctionConvexity[f, x]

ConvexRegionQを使ってが凸領域であることを確かめる：

Wolfram Language code: reg = ImplicitRegion@@{f ≤ y, {x, y}};
Wolfram Language code: ConvexRegionQ[reg]
Wolfram Language code: Plot[f, {x, -2, 2}, Filling -> Top]

が凹関数なら，ハイプグラフは凸集合である：

Wolfram Language code: f = Log[x];
Wolfram Language code: FunctionConvexity[{f, x > 0}, x]

領域は凸である：

Wolfram Language code: Plot[f, {x, 0, 2}, Filling -> Bottom]

最適化  (3)

凸関数の極小値は大域的最小値である：

Wolfram Language code: f = Ramp[x];
Wolfram Language code: FunctionConvexity[f, x]

極小値と最小値の集合は非正の半直線である：

Wolfram Language code: Plot[f, {x, -1, 1}]

狭義の凸関数は最大で1つの極小値を持つ：

Wolfram Language code: f = (x - 3y - 7) ^ 2 + (x + y - 5) ^ 2 + (2x - 3y - 4) ^ 2;
Wolfram Language code: FunctionConvexity[f, {x, y}, StrictInequalities -> True]
Wolfram Language code: {mval, mpoint} = Minimize[f, {x, y}]
Wolfram Language code: Show[{Plot3D[{f, mval}, {x, -5, 5}, {y, -5, 5}, PlotStyle -> Opacity[0.7]], Graphics3D[{Red, PointSize[Large], Point[{x, y, mval} /. mpoint]}]}]

狭義の凸関数は極小値を持たないことがある：

Wolfram Language code: f = Exp[x] + Exp[y];
Wolfram Language code: FunctionConvexity[f, {x, y}, StrictInequalities -> True]
Wolfram Language code: Minimize[f, {x, y}]
Wolfram Language code: Plot3D[f, {x, -3, 3}, {y, -3, 3}]

特性と関係  (2)

凸関数のSumとMaxは凸である：

Wolfram Language code: f = (Abs[x] ^ 3 + Abs[y] ^ 3) ^ (1 / 3); g = Log[E ^ x + E ^ y];
Wolfram Language code: FunctionConvexity[#, {x, y}]& /@ {f, g, f + g, Max[f, g]}
Wolfram Language code: GraphicsGrid[Map[Plot3D[#, {x, -2, 2}, {y, -2, 2}]&, {{f, g}, {f + g, Max[f, g]}}, {2}], ImageSize -> 400]

凸関数の第2導関数は非負である：

Wolfram Language code: f = x ^ 4 - 12x Cos[x] - 4x ^ 2 Sin[x] + 12Sin[x]
Wolfram Language code: FunctionConvexity[f, x]

Dを使って導関数を計算する：

Wolfram Language code: g = D[f, {x, 2}]

FunctionSignを使って導関数が非負であることを確かめる：

Wolfram Language code: FunctionSign[g, x]

関数と導関数をプロットする：

Wolfram Language code: Plot[{f, g}, {x, -7, 7}]
Wolfram Research (2020), FunctionConvexity, Wolfram言語関数， https://reference.wolfram.com/language/ref/FunctionConvexity.html.

テキスト

Wolfram Research (2020), FunctionConvexity, Wolfram言語関数， https://reference.wolfram.com/language/ref/FunctionConvexity.html.

CMS

Wolfram Language. 2020. "FunctionConvexity." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FunctionConvexity.html.

APA

Wolfram Language. (2020). FunctionConvexity. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FunctionConvexity.html

BibTeX

@misc{reference.wolfram_2026_functionconvexity, author="Wolfram Research", title="{FunctionConvexity}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/FunctionConvexity.html}", note=[Accessed: 01-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_functionconvexity, organization={Wolfram Research}, title={FunctionConvexity}, year={2020}, url={https://reference.wolfram.com/language/ref/FunctionConvexity.html}, note=[Accessed: 01-November-2026]}