WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

FussellVeselyImportance[rdist,t]

時間 t におけるReliabilityDistribution rdist の全成分のFussell–Vesely重要度を与える．

FussellVeselyImportance[fdist,t]

時間 t におけるFailureDistribution fdist の全成分のFussell–Vesely重要度を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
ReliabilityDistributionモデル  
FailureDistributionモデル  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

FussellVeselyImportance

FussellVeselyImportance[rdist,t]

時間 t におけるReliabilityDistribution rdist の全成分のFussell–Vesely重要度を与える．

FussellVeselyImportance[fdist,t]

時間 t におけるFailureDistribution fdist の全成分のFussell–Vesely重要度を与える．

詳細

  • 成分 の時間 におけるFussell–Vesely重要度は で与えられる．ただし，は成分 を含む最小カットセットの少なくとも1つが時間 で故障する確率，は時間 で系が故障する確率である．最小カットセットとは，それが故障すると系が故障する成分の最小セットのことである．
  • 結果は rdist あるいは fdist で与えられる分布リストの成分順で返される．

例題

すべて開く すべて閉じる

例  (3)

異なる寿命分布を持ち，直列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

結果はReliabilityDistributionにおける分布リストと同じ順で与えられる：

Wolfram Language code: FussellVeselyImportance[ℛ, t]
Wolfram Language code: {Subscript[fv, x], Subscript[fv, y]} = FussellVeselyImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[fv, x], Subscript[fv, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

異なる寿命分布を持ち，並列接続された2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: FussellVeselyImportance[ℛ, t]

故障の木に基づいたモデリングを使って系を定義する：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: FussellVeselyImportance[ℱ, t]
Wolfram Language code: Plot[%, {t, 0, 8}, Filling -> Axis]

スコープ  (16)

ReliabilityDistributionモデル  (8)

寿命分布が等しい直列接続の2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらの成分の信頼性が変わっても系の信頼性が同じように変わる：

Wolfram Language code: FussellVeselyImportance[ℛ, t]

寿命分布が等しい3つの成分のうちの2つが動くためには必要な系：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

成分は等しく重要である：

Wolfram Language code: FussellVeselyImportance[ℛ, t]//Simplify

寿命分布が等しい単純な混合系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: fv = FussellVeselyImportance[ℛ, t]

成分xの信頼性を変更すると系の信頼性に最も大きい影響がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, {x, y, z}}], {t, 0, 6}, PlotRange -> All]

ある成分と並列に繋がれている直列接続の系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: fv = FussellVeselyImportance[ℛ, t]

x成分の向上が系の信頼性に最大の効果がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, {x, y, z}}], {t, 0, 4}]

単純な混合系におけるパラメータの変化の効果を見る：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[2], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: fv = FussellVeselyImportance[ℛ, t]

並列成分の1つであるzを悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {fv /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

分布が異なる他の2つの成分と並列の1つの成分：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

時間のある1点における重要性尺度を厳密な結果として求める：

Wolfram Language code: FussellVeselyImportance[ℛ, 3 / 2]

機械精度の結果：

Wolfram Language code: FussellVeselyImportance[ℛ, 1.5]

記号式として：

Wolfram Language code: FussellVeselyImportance[ℛ, t]

任意の有効なReliabilityDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1 / 2], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: FussellVeselyImportance[ℛ, t]

寿命の後期にスタンドバイ成分yの信頼性を変えるとより効果がある：

Wolfram Language code: Plot[%, {t, 0, 6}, Filling -> Axis]

部分系の重要性尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: fv = FussellVeselyImportance[ℛ, t]

重要度を時間に沿ってプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, {z, r}}], {t, 0, 4}]

FailureDistributionモデル  (8)

2つの基本事象のどちらかが頂上事象に繋がる：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらかの事象の信頼性を変えると頂上事象が同様に変わる：

Wolfram Language code: FussellVeselyImportance[ℱ, t]

両方の基本事象が一緒になってはじめて頂上事象が起る：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

FussellVeselyImportanceは両方の事象を同様に重要なものとして順位付ける：

Wolfram Language code: FussellVeselyImportance[ℱ, t]

基本事象の分布が等しいボーティングゲート：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

任意の事象の信頼性を変えると頂上事象の信頼性が同じように変わる：

Wolfram Language code: FussellVeselyImportance[ℱ, t]//Simplify

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

基本事象xが最も重要である：

Wolfram Language code: fv = FussellVeselyImportance[ℱ, t]

事象xの信頼性を変えることが頂上事象の信頼性に最も影響がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: fv = FussellVeselyImportance[ℱ, t]

事象xを向上させることが頂上事象を防ぐ上で最大の効果がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

単純な混合系におけるパラメータの変更の効果を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: fv = FussellVeselyImportance[ℱ, t]

基本事象の1つであるzを悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {fv /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

任意の有効なFailureDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[3]};
Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: FussellVeselyImportance[ℱ, t]

寿命の初期段階でスタンドバイ成分yの信頼性を変えるとより効果がある：

Wolfram Language code: Plot[Evaluate@%, {t, 0, 5}, Filling -> Axis]

部分系の重要性尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: fv = FussellVeselyImportance[ℱ, t]

時間に沿って重要度をプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, {z, f}}], {t, 0, 4}]

アプリケーション  (3)

3時間持続しなければならない系で最も重要な成分はどれかを求める：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[3], WeibullDistribution[2, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∧(y∨z))∨v, {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];

Fussell–Vesely重要度によると成分vが最も重要である：

Wolfram Language code: fv = FussellVeselyImportance[ℛ, 3.]

炭鉱での問題の一つに，石炭の山の間の空洞に渡した橋からブルドーザーが落ちることがある．ブルドーザーは空洞の存在を知った上でその上に来ることもあれば，知らずに来ることもある：

Wolfram Language code: dozerOverVoid = intentional∨unintentional;

空洞は石炭の地中流出によって形成される．これは，コンベヤーベルトの下から石炭を搬出し開放供給機を撤去することで生じる：

Wolfram Language code: subsurfaceFlow = conveyorOperation∧feeder;

地表に流れがないことも原因となる．石炭が凍結すると地表の流れが止まる：

Wolfram Language code: frozenArch = temperature∧inactivity∧waterContent;

石炭をぎっしり詰めても地表の流れが無くなる：

Wolfram Language code: compaction = waterContent∧force;
Wolfram Language code: noSurfaceFlow = compaction∨frozenArch;

完全な故障の木：

Wolfram Language code: dozerFalls = dozerOverVoid∧(subsurfaceFlow∧noSurfaceFlow);

事象について次の分布を仮定する：

Wolfram Language code: vars = {conveyorOperation, intentional, feeder, force, inactivity, temperature, unintentional, waterContent};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {5.25, 0.00525, 1.768, 0.0175, 0.000175, 0.0175, 0.1075, 3.5};
Wolfram Language code: dists = Table[{vars[[i]], lifetimes[[i]]}, {i, Length[vars]}];
Wolfram Language code: ℱ = FailureDistribution[dozerFalls, dists];

どのような行為が事故防止に繋がるかを知るために，基本事象の重要度を計算する：

Wolfram Language code: fv = FussellVeselyImportance[ℱ, t]

重要度が最も高いのは重要度が1の事象であることが分かる：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {fv, vars}], {t, 0, 300}, PlotRange -> All]

重要度が1の基本事象を求める：

Wolfram Language code: Cases[Transpose[{fv, vars}], {1, _}]

弁が1つで余分なポンプが2つ付いた揚水装置を考える．成分の信頼度は確率で与えられる：

Wolfram Language code: ℛ = ReliabilityDistribution[valve∧(pump1∨pump2), {{valve, BernoulliDistribution[0.99]}, {pump1, BernoulliDistribution[0.97]}, {pump2, BernoulliDistribution[0.97]}}];

どの成分が最も重要かを求める：

Wolfram Language code: FussellVeselyImportance[ℛ, t]//Refine[#, t < 1]&

特性と関係  (6)

直列接続のFussellVeselyImportanceは確率によって定義することができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}}];
Wolfram Language code: FussellVeselyImportance[ℛ, t]
Wolfram Language code: Refine[Table[Probability[𝒯 ≤ t, 𝒯d] / Probability[𝒯 ≤ t, 𝒯ℛ], {d, {Subscript[𝒟, 1], Subscript[𝒟, 2]}}], t > 0]
Wolfram Language code: % - %%//FullSimplify

すべての並列な系のFussellVeselyImportanceは 1である：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: FussellVeselyImportance[ℛ, t]

並列構造にある部分系の重要度は等しい：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}, {z, ErlangDistribution[α, β]}}];
Wolfram Language code: fv = FussellVeselyImportance[ℛ, t]
Wolfram Language code: fv[[2]] - fv[[3]]

CriticalityFailureImportanceは常にFussell–Vesely重要度以下である：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, WeibullDistribution[1 / 2, 3]}, {y, ExponentialDistribution[2]}}];
Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]; fv = FussellVeselyImportance[ℛ, t];
Wolfram Language code: Plot[{First[cf], First[fv]}, {t, 0, 10}]

信頼性が高い成分のCriticalityFailureImportanceはFussell–Veselyに近付く：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}}];

差を計算する：

Wolfram Language code: cf = CriticalityFailureImportance[ℛ, t]; fv = FussellVeselyImportance[ℛ, t];

故障率 がに近付くとき，差は常にである：

Wolfram Language code: Limit[fv - cf, λ -> 0]

無関係な成分の重要度は0である：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: FussellVeselyImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]
Wolfram Research (2012), FussellVeselyImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/FussellVeselyImportance.html.

テキスト

Wolfram Research (2012), FussellVeselyImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/FussellVeselyImportance.html.

CMS

Wolfram Language. 2012. "FussellVeselyImportance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/FussellVeselyImportance.html.

APA

Wolfram Language. (2012). FussellVeselyImportance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/FussellVeselyImportance.html

BibTeX

@misc{reference.wolfram_2026_fussellveselyimportance, author="Wolfram Research", title="{FussellVeselyImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/FussellVeselyImportance.html}", note=[Accessed: 06-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_fussellveselyimportance, organization={Wolfram Research}, title={FussellVeselyImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/FussellVeselyImportance.html}, note=[Accessed: 06-July-2026]}