WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

GeoRange

地理関数のオプションで，含める経緯度の範囲を指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

GeoRange

GeoRange

地理関数のオプションで，含める経緯度の範囲を指定する．

詳細

  • GeoRangeはGeoGraphics，GeoImage，DynamicGeoGraphics，GeoElevationDataおよび他の地理関数で使うことができる．
  • 使用可能な設定値
  • All全世界に相当する領域が含まれる
    Automatic表示する領域を自動的に選択する
    Full地理画像で使われる場合はAllに等しい
    {{lat1,lat2},{lon1,lon2}}緯度と経度についての明示的な限界
    {All,{lon1,lon2}}全緯度範囲，経度範囲を指定
    {{lat1,lat2},All}全経度範囲，緯度範囲を指定
    rメートル単位であると仮定した明示的な半径
    quantity指定された，あるいは計算された地理中心周囲の明示的な半径
    entityentity の"Polygon"特性に対応する領域
    georegionGeoBounds が計算できる任意の領域
    "Country"包み込む国の境界ボックスを使う
    "World"全世界の境界ボックスを使う
  • AllとFullは，どちらも，対応する軸．すなわち，緯度{-90,90}，経度{-180,180}の完全な範囲を意味する．であるから，両者は，それ自体で使われる場合は"World"に等しい．しかし，{All,{-100,100}}のように個別範囲としても使うことができる．
  • 明示的な範囲は，度を単位とした緯度と経度の範囲{{latmin,latmax},{lonmin,lonmax}}で指定される．
  • 経度範囲{lonmin,lonmax}に対しては，上側境界 lonmaxは360を法として取られ，となるようにする．
  • entity を指定すると，その"Polygon"特性の地理境界ボックスが使われる．
  • 実体または地理プリミティブによって与えられる任意の地理領域について，GeoRangegeoregion は範囲GeoBounds[georegion,Scaled[0.05]]を表す．
  • GeoRangequantity は，GeoCenterによって，あるいはGeoGraphicsの地理プリミティブによって指定された中心の周りの，半径 quantity の地理的中心を包み込む範囲を表す．
  • GeoRangeAutomaticは，GeoGraphics[…]の第1引数に対するGeoBounds[…]の充填された結果によって与えられた領域を選択する．点状の場合は，その点の周りの半径約10マイルの地理円板が使われる．入力についての位置情報がない場合は，GeoGraphics[]におけるのと同じように，完全な地理範囲が使われる．
  • GeoRangePaddingを使ってGeoRangeで定義される境界ボックスを拡張することができる．
  • OptionsとAbsoluteOptionsは，地図で使われるGeoRangeの明示的な形を抽出する．

例題

すべて開く すべて閉じる

例  (6)

コペンハーゲンを中心とした半径50マイルの範囲の地図を描く：

Wolfram Language code: GeoGraphics[GeoRange -> Quantity[50, "Miles"], GeoCenter -> Entity["City", {"Copenhagen", "Copenhagen", "Denmark"}]]

実際に使われた地理範囲を得る：

Wolfram Language code: Options[%, GeoRange]

経緯度の明示的な範囲を度で指定する：

Wolfram Language code: GeoGraphics[GeoRange -> {{53, 58}, {7, 17}}]

地理実体を指定する：

Wolfram Language code: GeoGraphics[GeoRange -> Entity["Country", "France"]]

プロットする領域を自動的に選択する：

Wolfram Language code: GeoHistogram[GeoPosition[«1»], GeoRange -> Automatic]

国の周囲を示す地理範囲を選ぶ：

Wolfram Language code: GeoGraphics[GeoMarker[Entity["City", {"Panama", "Panama", "Panama"}]], GeoRange -> "Country"]

全世界の衛星画像：

Wolfram Language code: GeoImage[GeoRange -> "World"]

スコープ  (14)

位置情報なしのデフォルトのGeoRangeの値はユーザ位置の周りの世界全体である：

Wolfram Language code: GeoGraphics[]

点の周りでGeoRangeがデフォルトで選択するのは，点の周り約10マイルの充填された地理円板である：

Wolfram Language code: GeoGraphics[Here]

拡張領域についてGeoRangeがデフォルトで選択するのは，その領域の地理境界の充填されたものである：

Wolfram Language code: GeoGraphics[Polygon@Entity["AdministrativeDivision", {"Kentucky", "UnitedStates"}], GeoBackground -> "StreetMapVectorLabels"]

緯度と経度の範囲を度で指定する：

Wolfram Language code: GeoGraphics[GeoRange -> {{0, 90}, {0, 180}}]

指定された地理位置を含む国を示す：

Wolfram Language code: GeoGraphics[GeoPosition[{40, -100}], GeoRange -> "Country"]

ボンヌ図法を使って全世界をプロットする：

Wolfram Language code: GeoGraphics[Polygon[EntityClass["Country", "Asia"]], GeoRange -> "World", GeoProjection -> "Bonne", GeoBackground -> "Plain"]

中心子午線を変える：

Wolfram Language code: GeoGraphics[Polygon[EntityClass["Country", "Asia"]], GeoRange -> "World", GeoCenter -> 100, GeoProjection -> "Bonne", GeoBackground -> "Plain"]

実体の地理範囲を指定する：

Wolfram Language code: GeoGraphics[GeoRange -> Entity["City", {"Denver", "Colorado", "UnitedStates"}]]

実体クラスの地理範囲を指定する：

Wolfram Language code: GeoGraphics[GeoRange -> EntityClass["Country", "Europe"]]

使用されている実際の地理範囲をチェックする：

Wolfram Language code: Options[%, GeoRange]

これは，厳密には指定された領域のGeoBoundsと対応しないが，5%の充填範囲にあたる：

Wolfram Language code: GeoBounds[EntityClass["Country", "Europe"]]
Wolfram Language code: GeoBounds[EntityClass["Country", "Europe"], Scaled[0.05]]

任意の領域を使って地理範囲を指定する：

Wolfram Language code: georegion = {Entity["Country", "Ecuador"], Entity["Country", "Venezuela"], Brown, Entity["Country", "Colombia"]["Polygon"]}
Wolfram Language code: GeoGraphics[GeoRange -> georegion, GeoBackground -> "Basic"]

使用されている実際の地理範囲をチェックする：

Wolfram Language code: Options[%, GeoRange]

これは，与えられた領域の地理境界を5%充填することにあたる：

Wolfram Language code: GeoBounds[georegion, Scaled[0.05]]

ブエノスアイレスの周囲1000kmの地理円を含む範囲に相当する地域：

Wolfram Language code: GeoGraphics[GeoRange -> Quantity[1000, "Kilometers"], GeoCenter -> Entity["City", {"BuenosAires", "BuenosAires", "Argentina"}], GeoBackground -> "ClassicDark"]

明示的な距離で地理範囲を設定する：

Wolfram Language code: GeoGraphics[{Polygon[Entity["City", {"Roswell", "NewMexico", "UnitedStates"}]]}, GeoRange -> Quantity[10, "Kilometers"], GeoRangePadding -> None]

純粋な数として指定された地理半径の単位はメートルであると仮定される：

Wolfram Language code: GeoGraphics[{Polygon[Entity["City", {"Roswell", "NewMexico", "UnitedStates"}]]}, GeoRange -> 10000, GeoRangePadding -> None]
Wolfram Language code: range = GeoRange /. Options[%, GeoRange]
Wolfram Language code: GeoDistance[Sequence@@({#, Mean[range[[2]]]}& /@ range[[1]]), UnitSystem -> "Metric"] / 2
Wolfram Language code: GeoDistance[Sequence@@({Mean[range[[1]]], #}& /@ range[[2]]), UnitSystem -> "Metric"] / 2

緯度あるいは経度を使った全範囲：

Wolfram Language code: GeoGraphics[GeoRange -> {Full, {-50, 50}}]
Wolfram Language code: GeoGraphics[GeoRange -> {{-90, 0}, All}]

世界全体を描いてブラジルを示す：

Wolfram Language code: GeoGraphics[{GeoStyling[Green], Polygon[Entity["Country", "Brazil"]]}, GeoRange -> "World", GeoBackground -> "ReliefMap"]

世界全体を含む明示的な地理範囲を指定する：

Wolfram Language code: GeoGraphics[Polygon[Entity["Country", "Brazil"]], GeoRange -> {{-90, 90}, {-180, 180}}]

シンボルAllを使って適切な中心を選択する：

Wolfram Language code: GeoGraphics[Polygon[Entity["Country", "Brazil"]], GeoRange -> All]

地理範囲を，点状（多角形は使用不可）の場所とデフォルトの地理範囲充填で指定する：

Wolfram Language code: GeoGraphics[GeoRange -> Entity["City", {"Kathmandu", "Kathmandu", "Nepal"}]]

特性と関係  (5)

360度を超える経度範囲は，360度になるように左から切り取られる：

Wolfram Language code: GeoGraphics[GeoRange -> {{-90, 90}, {-100, 500}}, Frame -> True]
Wolfram Language code: AbsoluteOptions[%, GeoRange]

経度範囲は常に東に向かって計測される：

Wolfram Language code: GeoGraphics[GeoRange -> {Full, {120, -120}}, Frame -> True]
Wolfram Language code: AbsoluteOptions[%, GeoRange]

GeoRangeは，投影される地球の部分を定義する：

Wolfram Language code: GeoGraphics[GeoRange -> {{30, 85}, {-10, 50}}, GeoProjection -> "Albers", Frame -> True, GeoBackground -> "ReliefMap"]
Wolfram Language code: AbsoluteOptions[%, GeoZoomLevel]

GeoGridRangeは，その地図の部分を投影された座標で選ぶ：

Wolfram Language code: GeoGraphics[GeoRange -> {{30, 85}, {-10, 50}}, GeoProjection -> "Albers", Frame -> True, GeoGridRange -> {{-0.2, 0.2}, {-0.4, 0}}, GeoBackground -> "ReliefMap"]

デフォルトで，地理範囲は地図の格子範囲全体を覆うように充填される：

Wolfram Language code: GeoGraphics[Polygon[CountryData["EuropeSovereign"]], GeoRange -> {{35, 60}, {-5, 20}}, GeoBackground -> "Plain"]

使用可能な多角形がない実体クラスを指定すると，指定されたクラスの成員に適した地理範囲が使われる：

Wolfram Language code: GeoGraphics[GeoRange -> EntityClass["Building", "AcropolisAthens"]]
Wolfram Language code: GeoGraphics[{Red, PointSize[.03], Point[EntityClass["Building", "AcropolisAthens"]]}]

考えられる問題  (1)

を超える緯度の値は切り取られ，メッセージが生成される：

Wolfram Language code: GeoGraphics[GeoRange -> {{-100, 70}, {-200, 100}}, Frame -> True]

AbsoluteOptionsを使って，切り取られた結果の地理範囲を見る：

Wolfram Language code: AbsoluteOptions[%, GeoRange]
Wolfram Research (2014), GeoRange, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoRange.html （2021年に更新）.

テキスト

Wolfram Research (2014), GeoRange, Wolfram言語関数， https://reference.wolfram.com/language/ref/GeoRange.html （2021年に更新）.

CMS

Wolfram Language. 2014. "GeoRange." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/GeoRange.html.

APA

Wolfram Language. (2014). GeoRange. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/GeoRange.html

BibTeX

@misc{reference.wolfram_2026_georange, author="Wolfram Research", title="{GeoRange}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/GeoRange.html}", note=[Accessed: 14-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_georange, organization={Wolfram Research}, title={GeoRange}, year={2021}, url={https://reference.wolfram.com/language/ref/GeoRange.html}, note=[Accessed: 14-November-2026]}