WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

HeunT[q,α,γ,δ,ϵ,z]

三重合流型Heun関数を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
微分  
積分  
級数展開  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

HeunT

HeunT[q,α,γ,δ,ϵ,z]

三重合流型Heun関数を与える．

詳細

  • HeunTは関数のHeun族に属し，量子力学およびそのアプリケーションでしばしば使われる．
  • 記号操作・数値操作の両方に適した数学関数である．
  • HeunT[q,α,γ,δ,ϵ,z]は三重Heun合流型微分方程式 を満足する．
  • HeunT関数は，制約条件 と を満足する三重合流型Heun方程式のベキ級数解 である．
  • HeunTは，特定の特殊な引数については自動的に厳密値に評価される．
  • HeunTは任意の複素パラメータについて評価できる．
  • HeunTは任意の数値精度で評価できる．
  • HeunTは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: HeunT[-0.2, 1.3, 0.12, -0.14, 4.32, -.3]

HeunT関数をプロットする：

Wolfram Language code: Plot[HeunT[-0.2, 1.3, 0.12, -0.14, 4.32, x], {x, -1, 2}]

HeunTの級数展開：

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 2}]

スコープ  (24)

数値評価  (8)

高精度で評価する：

Wolfram Language code: N[HeunT[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 1 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: HeunT[9 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.10000000000000000001]

HeunTは1つまたは複数の複素パラメータを取ることができる：

Wolfram Language code: HeunT[1.2 + I, -1.4, 0.12, 0.03, -0.2, 0.1]
Wolfram Language code: HeunT[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1]

HeunTは複素引数を取ることができる：

Wolfram Language code: HeunT[1.2, -1.4, 0.12, 0.03, -0.2, 0.1 + I]

さらに，HeunTはすべての複素数入力を取ることができる：

Wolfram Language code: HeunT[1.2 + I, -1.4 + 0.I, 0.12 - I, 0.03 + 0.123I, -0.2 - 0.2I, 0.1 + I]

HeunTを高精度で効率よく評価する：

Wolfram Language code: HeunT[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7`100]//Timing
Wolfram Language code: HeunT[1 / 2, -1 / 3, 1 / 4, 1 / 5, -1 / 6, 1 / 7 + I / 2`100]//Timing

リストと行列：

Wolfram Language code: HeunT[1.2, -1.4, 0.12, 0.03, -0.2, {0.15, 0.1 + I, I, 4}]
Wolfram Language code: HeunT[-0.2, {1.3, -0.4}, 0.12, -0.14, 4.32, -1.4]
Wolfram Language code: HeunT[1.2, -1.4, 0.12, 0.03, -0.2, (| | | | :- | :---- | | π | u | | v | (π/2) |) ]

配列の要素ごとの値を計算する：

Wolfram Language code: HeunT[.1, .1 + I, 0.12, 1, -0.32, {{.01, -1}, {.3, .2}}]

MatrixFunctionを使って行列のHeunT関数を計算することもできる：

Wolfram Language code: MatrixFunction[HeunT[.1, .1 + I, 0.12, 1, -0.32, #]&, {{.01, -1}, {.3, .2}}]

特定の値  (2)

原点におけるHeunTの値：

Wolfram Language code: HeunT[q, α, γ, δ, ϵ, 0]

HeunTを任意の引数について計算する：

Wolfram Language code: HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, 0.7 - 3.1I]

可視化  (5)

HeunT関数をプロットする：

Wolfram Language code: Plot[HeunT[4, -0.6, 0.7 , 1.18, -1.3 , z], {z, -1, 1}]

複素パラメータについてのHeunT関数の絶対値をプロットする：

Wolfram Language code: Plot[Abs[HeunT[4 + I, -0.6 - 0.3I, -0.7 , -0.18, 0.3 , z]], {z, -2, 1}]

HeunTを第2パラメータ の関数としてプロットする：

Wolfram Language code: Plot[HeunT[4, α, -0.7, -0.18, 0.3 , z] /. α -> {-2, Sqrt[20], 1 / 10}//Evaluate, {z, -1, 1}]

HeunTを と の関数としてプロットする：

Wolfram Language code: {α, γ, ϵ, δ} = {0.2 + I, -0.6 + 0.9 I, -0.7 I, 0.3  + 0.6 I};
Wolfram Language code: Plot3D[Abs[HeunT[q, α, γ, δ, ϵ, z]], {q, -20, 2}, {z, 1 / 10, 9 / 10}, ColorFunction -> Function[{q, z, HT}, Hue[HT]], PlotRange -> All]

HeunT関数族をさまざまなアクセサリパラメータ についてプロットする：

Wolfram Language code: {α, γ, δ, ϵ} = {0.8 + 0.7 I, 0.92  + 0.33I, 0.21  + 0.72 I, -0.76 - 0.81I};
Wolfram Language code: Plot[Evaluate[Table[Abs[HeunT[q, α, γ, δ, ϵ, z]], {q, -18, 3, 3}]], {z, -4, 7 / 2}, PlotStyle -> Table[{Hue[i / 10], Thickness[0.002]}, {i, 20}], PlotRange -> {0, 4}, Frame -> True, Axes -> False]

微分  (2)

HeunTの 次導関数はHeunTPrimeである：

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], z]

HeunTのより高次の導関数はHeunTPrimeを使って計算される：

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], {z, 2}]//Simplify

積分  (3)

HeunTの不定積分は初等関数やその他の特殊関数によっては表されない：

Wolfram Language code: Integrate[HeunT[q, α, γ, δ, ϵ, z], z]

HeunTの数値定積分：

Wolfram Language code: NIntegrate[HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, 0, 1 / 3}]

HeunTを含むその他の積分：

Wolfram Language code: NIntegrate[z ^ 2 HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]
Wolfram Language code: NIntegrate[Sin[Sqrt[z]] ^ 2 HeunT[12 / 10, -14 / 10, 12 / 100, 3 / 100, -2 / 10, z], {z, -1, 1 / 3}]

級数展開  (4)

原点におけるHeunTのテイラー(Taylor)展開：

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 3}]

におけるHeunTの級数展開の第3項の係数：

Wolfram Language code: SeriesCoefficient[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 3}]

の周囲のHeunTの最初の3つの近似をプロットする：

Wolfram Language code: {q, α, γ, δ, ϵ} = {-8, -9 / 10, 1 / 10, 4 / 7, 3 / 2};
Wolfram Language code: terms = Normal@Table[Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, m}], {m, 1, 4}];
Wolfram Language code: Plot[{HeunT[q, α, γ, δ, ϵ, z], terms}, {z, -3, 3}, PlotRange -> {-5, 5}, PlotLegends -> {"HeunT[q, α, γ, δ, ϵ, z]", "1st approximation", "2nd approximation", "3rd approximation", "4th approximation"}]

任意の通常の複素点におけるHeunTの級数展開：

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 1 / 2, 1}]//FullSimplify

アプリケーション  (5)

DSolveを使って三重合流型Heun微分方程式を解く：

Wolfram Language code: sol = DSolve[ y''[z] + (γ + δ z + ϵ z^2)y'[z] + (α z - q)y[z] == 0, y[z], z]

解をプロットする：

Wolfram Language code: {q, α, γ, δ, ϵ} = {4, -10, 1 / 3, 0, -1 / 3};
Wolfram Language code: Plot[y[z] /. sol /. {{C[1] -> 1, C[2] -> 0}, {C[1] -> 0, C[2] -> 1}, {C[1] -> 1 / 3, C[2] -> 1 / 3}}//Evaluate, {z, -4, 1}]

三重合流型Heun微分方程式の初期値問題を解く：

Wolfram Language code: sol = DSolveValue[{y''[z] + (γ + δ z + ϵ z^2)y'[z] + (α z - q)y[z] == 0, y[0] == 1, y'[0] == 0}, y[z], z]

さまざまなアクセサリパラメータ q について解をプロットする：

Wolfram Language code: {α, γ, δ, ϵ} = {-10, 1 / 3, 4 / 3, -1 / 3};
Wolfram Language code: Plot[Abs[sol] /. q -> {1, 2, 3, 4}//Evaluate, {z, -5 / 2, 1}]

三重合流型Heun微分方程式を直接解く：

Wolfram Language code: y[z_] := HeunT[q, α, γ, δ, ϵ, z]
Wolfram Language code: y''[z] + (γ + δ z + ϵ z^2)y'[z] + (α z - q)y[z] == 0//Simplify

1Dシュレディンガー(Schrödinger)方程式についての四次ポテンシャル：

Wolfram Language code: V[z_] := λ^2(Underoverscript[∏, i = 1, 4](z - Subscript[z, i]))

この一般ポテンシャルをHeunT関数で解く：

Wolfram Language code: {Subscript[z, 1], Subscript[z, 2], Subscript[z, 3], Subscript[z, 4]} = {1, 2, 3, 4};
Wolfram Language code: DSolve[u''[z] - V[z]u[z] == 0, u[z], z]

のとき，HeunTはエアリー関数で表すことができる：

Wolfram Language code: y[z_] = FunctionExpand[HeunT[0, -1, 0, 0, 0, z]]

結果がエアリー関数の解であることを確認する：

Wolfram Language code: y''[z] - z y[z] == 0//Simplify

特性と関係  (4)

HeunTの計算は，引数が大きいと時間がかかるかもしれない：

Wolfram Language code: Series[HeunT[q, α, γ, δ, ϵ, z], {z, 0, 2}]

HeunTは任意の有限複素 において計算できる：

Wolfram Language code: HeunT[4 + I, -1 / 2, 1 / 4, -7 / 5, 2, z] /. z -> RandomComplex[{-2 - I, 2 + I}, 5]

HeunTの導関数はHeunTPrimeである：

Wolfram Language code: D[HeunT[q, α, γ, δ, ϵ, z], z]

FunctionExpandを使ってHeunTをより簡単な関数に展開する：

Wolfram Language code: FunctionExpand[HeunT[q, 0, 1, 1, 0, z]]

考えられる問題  (1)

HeunTは大きい引数については発散する：

Wolfram Language code: AbsoluteTiming[HeunT[0.03 + I, 1.3, 1, 0.12, 4.32, 20]]

おもしろい例題  (1)

古典的な非調和振動子方程式はHeunTによって解くことができる：

Wolfram Language code: sol = DSolve[u''[z] + (Subscript[λ, 1] + Subscript[λ, 2]z^2 + Subscript[λ, 4] z^4)u[z] == 0, u[z], z]

非調和振動子の動力学のシミュレーションを行う：

Wolfram Language code: {Subscript[λ, 1], Subscript[λ, 2], Subscript[λ, 4]} = {1, 1 / 2, 1 / 4};
Wolfram Language code: Plot[{u[z] /. sol /. {C[1] -> 1, C[2] -> 1}}, {z, 0, 9 / 2}]
Wolfram Research (2020), HeunT, Wolfram言語関数， https://reference.wolfram.com/language/ref/HeunT.html.

テキスト

Wolfram Research (2020), HeunT, Wolfram言語関数， https://reference.wolfram.com/language/ref/HeunT.html.

CMS

Wolfram Language. 2020. "HeunT." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/HeunT.html.

APA

Wolfram Language. (2020). HeunT. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HeunT.html

BibTeX

@misc{reference.wolfram_2026_heunt, author="Wolfram Research", title="{HeunT}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/HeunT.html}", note=[Accessed: 26-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_heunt, organization={Wolfram Research}, title={HeunT}, year={2020}, url={https://reference.wolfram.com/language/ref/HeunT.html}, note=[Accessed: 26-June-2026]}