WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Interval[{min,max}]

min から max の区間に存在する値を表す．

Interval[{min1,max1},{min2,max2},…]

min1から max1の範囲，min2から max2の範囲等の和集合を表す．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Interval

Interval[{min,max}]

min から max の区間に存在する値を表す．

Interval[{min1,max1},{min2,max2},…]

min1から max1の範囲，min2から max2の範囲等の和集合を表す．

詳細

  • Intervalオブジェクトには四則計算やその他の操作を施すことができる．
  • Interval[{min,max}]は両端点を含む閉じた区間を表す．
  • 区間の端点を得るにはMin[interval]またはMax[interval]を使う．
  • x が機械精度または任意精度の近似数値のとき，Interval[x]は x の不確定性を反映する区間を返す．
  • 近似数値の区間に対する操作において，Wolfram言語は常に下限値に対して切り捨て処理を行い，上限値に対して切り上げ処理を行う．
  • Intervalは，幾何学領域として使うことができる．
  • IntervalはLimit等の関数により生成される．
  • EqualやLess等の関係演算子に不連続な区間を与えると，判定結果としてTrueまたはFalseが得られる．

予備知識

  • Interval[{min,max}]は，min から max までの両端を含む閉じた実数値区間を表す．複数の引数がある形式のInterval[{min1,max1},{min2,max2},…]は，min1から max1まで，min2から max2までという具合の範囲の和集合を表し，IntervalUnion[Interval[{min1,max1}],Interval[{min2,max2}],…]に等しい．区間の端点は，記号的でも実数無限大でもよく，厳密数，近似数，機械精度数あるいは絶対精度数を含む任意の実数式でもよい．
  • Intervalオブジェクトには，区間演算として知られる過程で算術演算子および関係演算子を適用することができる．Interval[{min,max}]の形の最も単純な interval のケースでは，Min[interval]およびMax[interval] が，それぞれ，min と max を返す．
  • Intervalは，そこで計算を行う一次元領域指定としても使うことができる．Limitを含む数多くの関数が，Intervalオブジェクトを含む式を返すことがある．
  • NumberLinePlotを使って数直線上でIntervalオブジェクトを可視化することができる．
  • Intervalは他の数多くのシンボルと関連がある．IntervalUnionとIntervalIntersectionは，それぞれUnionとIntersectionのInterval版である．一方，IntervalMemberQを使って値（または区間）が指定の区間に入っているかどうかを明示的に判定することができる．RegionMemberを使って指定されたIntervalについてRegionMemberFunctionを生成することができる．この結果を使って，区間の帰属判定を行うことができる．Intervalは，Range，Piecewise，MinMax，Line，InfiniteLine，HalfLineとも関係がある．

例題

すべて開く すべて閉じる

例  (2)

区間の足し算を行い，結果を表す区間を得る：

Wolfram Language code: Interval[{1, 6}] + Interval[{0, 2}]

不確定な極限が区間を与えることがある：

Wolfram Language code: Limit[Sin[x] + Sin[x ^ 2], x -> Infinity]

スコープ  (8)

二乗すると非負の区間が与えられる：

Wolfram Language code: Interval[{-2, 5}] ^ 2

区間に適用できる関数もある：

Wolfram Language code: Sin[Interval[{2.5, 5.5}]]

厳密な入力は厳密な区間結果を与える：

Wolfram Language code: Sin[Interval[{2, 7}]]
Wolfram Language code: Sin[Interval[{2, 10}]]

互いに素な区間を生成することができる：

Wolfram Language code: 1 / Interval[{-2, 5}]

区間を使って厳密な比較が行える：

Wolfram Language code: Interval[{5, 8}] > Pi

区間を含む方程式を解く：

Wolfram Language code: Solve[3x + 2 == Interval[{-2, 5}], x]

近似値は自動的に区間にされる：

Wolfram Language code: Interval[1.]

機械数は常にある種の区間に相当する：

Wolfram Language code: % - 1
Wolfram Language code: $MachineEpsilon

Intervalは幾何学領域として使うことができる：

Wolfram Language code: ℛ = Interval[{0, 1}];
Wolfram Language code: RegionQ[ℛ]
Wolfram Language code: RegionMeasure[ℛ]

一般化と拡張  (1)

Wolfram言語が機械数0.に一致するとみなす区間を求める：

Wolfram Language code: Interval[0.]

異なる精度を指定すると異なる区間が与えられる：

Wolfram Language code: Interval[0``500]

アプリケーション  (5)

初期条件に対する鋭敏な依存性を有するシステムで区間が広がるのを見てみる：

Wolfram Language code: NestList[4#(1 - #)&, Interval[0.5], 4]

機械精度の評価では，次は明確ではあるが正しくない値を与える：

Wolfram Language code: Sin[N[Pi]]

Intervalを使うと，結果は正しい値に及ぶ：

Wolfram Language code: Sin[Interval[N[Pi]]]

パラメータによって区間の境界がどのように変わるかを示す：

Wolfram Language code: Plot[With[{u = Sin[Interval[{6, x}]]}, {Min[u], Max[u]}], {x, 0, 15}]

Interval内の点について検定する：

Wolfram Language code: ℛ = Interval[{0, 1}]; gr = NumberLinePlot[ℛ]
Wolfram Language code: mf = RegionMember[ℛ]

帰属判定のために，これを点のリストに適用する：

Wolfram Language code: pts = RandomVariate[UniformDistribution[{{-0.5, 1.5}}], 100]; col = mf[pts] /. {False -> Gray, True -> Red};
Wolfram Language code: gp = Graphics[{AbsolutePointSize[1.6], Table[{col[[i]], Point[{pts[[i, 1]], 3}]}, {i, 100}]}];
Wolfram Language code: Show[gr, gp, PlotRange -> All]

{0,1}区間から始め，各ステップの各区間の中部の1/3を除くことで，カントール集合を構築する：

Wolfram Language code: cantor = {a_, b_} :> {{a, a + (b - a) / 3}, {a + (b - a)2 / 3, b}};
Wolfram Language code: CantorRegion[n_Integer ? NonNegative] := Interval@@Nest[Flatten[Map[Function[s, s /. cantor], #], 1]&, {{0, 1}}, n]

いくつかのステップ：

Wolfram Language code: CantorRegion[1]
Wolfram Language code: CantorRegion[2]
Wolfram Language code: NumberLinePlot[Table[CantorRegion[i], {i, 3}], PlotRange -> {{0, 1}, Automatic}]

領域の長さを求める：

Wolfram Language code: Table[RegionMeasure[CantorRegion[i]], {i, 5}]

FindSequenceFunctionを使って一連の長さについての式を求める：

Wolfram Language code: FindSequenceFunction[%, n]

特性と関係  (2)

MaxとMinを使って区間の端点を求める：

Wolfram Language code: Interval[{2, 4}]
Wolfram Language code: Max[%]

CenteredIntervalは実区間または複素長方形を表す：

Wolfram Language code: CenteredInterval[1, 1 / 10]
Wolfram Language code: CenteredInterval[1 + 2I, 1 / 100 + I / 100]

有界のIntervalをCenteredInterval表現に変換する：

Wolfram Language code: CenteredInterval[Interval[{1, 2}]]

変換し直す：

Wolfram Language code: Interval[Information[%, "Bounds"]]

区間の端点が二進有理数ではなければ，区間は変換によって大きくなる：

Wolfram Language code: Interval[{0, 1 / 3}]
Wolfram Language code: CenteredInterval[%]
Wolfram Language code: Interval[Information[%, "Bounds"]]
Wolfram Language code: N[%[[1]] - %%%[[1]]]

考えられる問題  (1)

区間は常に独立であるとみなされる：

Wolfram Language code: u = Interval[{-1, 1}]
Wolfram Language code: u + u ^ 2

同一区間における単一の実変数は，異なる下限の区間を与える：

Wolfram Language code: Minimize[{x + x ^ 2, -1 < x < 1}, x]
Wolfram Research (1996), Interval, Wolfram言語関数， https://reference.wolfram.com/language/ref/Interval.html （2014年に更新）.

テキスト

Wolfram Research (1996), Interval, Wolfram言語関数， https://reference.wolfram.com/language/ref/Interval.html （2014年に更新）.

CMS

Wolfram Language. 1996. "Interval." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/Interval.html.

APA

Wolfram Language. (1996). Interval. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Interval.html

BibTeX

@misc{reference.wolfram_2026_interval, author="Wolfram Research", title="{Interval}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Interval.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_interval, organization={Wolfram Research}, title={Interval}, year={2014}, url={https://reference.wolfram.com/language/ref/Interval.html}, note=[Accessed: 02-November-2026]}